source: trunk/Settings.pas@ 517

Last change on this file since 517 was 499, checked in by chronos, 17 months ago
  • Modified: Allow to set fractional DPI with 25% steps.
File size: 11.7 KB
Line 
1unit Settings;
2
3interface
4
5uses
6 Classes, SysUtils, FileUtil, Dialogs, LCLProc, ScreenTools, Messg, ButtonA,
7 Directories, DrawDlg, ButtonC, KeyBindings, Languages,
8 {$IFDEF DPI}Dpi.Forms, Dpi.Controls, Dpi.Graphics, Dpi.StdCtrls, System.UITypes{$ELSE}
9 Forms, Controls, Graphics, StdCtrls{$ENDIF};
10
11type
12 { TSettingsDlg }
13
14 TSettingsDlg = class(TDrawDlg)
15 ButtonFullscreen: TButtonC;
16 ButtonCustomDpi: TButtonC;
17 ButtonGammaDown: TButtonC;
18 ButtonDpiDown: TButtonC;
19 EditShortCutPrimary: TEdit;
20 EditShortCutSecondary: TEdit;
21 ListLanguages: TListBox;
22 ListKeyBindings: TListBox;
23 ButtonOk: TButtonA;
24 ButtonCancel: TButtonA;
25 ButtonReset: TButtonA;
26 ButtonGammaUp: TButtonC;
27 ButtonDpiUp: TButtonC;
28 procedure ButtonCustomDpiClick(Sender: TObject);
29 procedure ButtonDpiDownClick(Sender: TObject);
30 procedure ButtonDpiUpClick(Sender: TObject);
31 procedure ButtonFullscreenClick(Sender: TObject);
32 procedure ButtonCancelClick(Sender: TObject);
33 procedure ButtonResetClick(Sender: TObject);
34 procedure ButtonGammaDownClick(Sender: TObject);
35 procedure EditShortCutPrimaryKeyUp(Sender: TObject; var Key: Word;
36 Shift: TShiftState);
37 procedure EditShortCutSecondaryKeyUp(Sender: TObject; var Key: Word;
38 Shift: TShiftState);
39 procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
40 procedure FormCreate(Sender: TObject);
41 procedure FormDestroy(Sender: TObject);
42 procedure FormPaint(Sender: TObject);
43 procedure FormShow(Sender: TObject);
44 procedure ListKeyBindingsSelectionChange(Sender: TObject; User: Boolean);
45 procedure ButtonOkClick(Sender: TObject);
46 procedure ButtonGammaUpClick(Sender: TObject);
47 private
48 LocalGamma: Integer;
49 LocalKeyBindings: TKeyBindings;
50 CurrentKeyBinding: TKeyBinding;
51 LocalDpi: Integer;
52 procedure UpdateShortCutItem;
53 function GetLocalCustomDpiEnabled: Boolean;
54 public
55 procedure LoadData;
56 procedure SaveData;
57 end;
58
59var
60 SettingsDlg: TSettingsDlg;
61
62const
63 DpiMin = 100;
64 DpiMax = 500;
65 DpiStep = 25;
66
67
68implementation
69
70{$R *.lfm}
71
72uses
73 Start;
74
75var
76 SFullScreen, SGamma, SRestartMsg, SShortCutPrimary, SShortCutSecondary,
77 SLanguages, SKeyBindings, SCustomDpi, SDpi: string;
78
79procedure ReloadLanguages;
80begin
81 SFullScreen := Phrases.Lookup('SETTINGS', 0);
82 SGamma := Phrases.Lookup('SETTINGS', 1);
83 SRestartMsg := Phrases.Lookup('SETTINGS', 2);
84 SShortCutPrimary := Phrases.Lookup('SETTINGS', 3);
85 SShortCutSecondary := Phrases.Lookup('SETTINGS', 4);
86 SLanguages := Phrases.Lookup('SETTINGS', 5);
87 SKeyBindings := Phrases.Lookup('SETTINGS', 6);
88 SCustomDpi := Phrases.Lookup('SETTINGS', 7);
89 SDpi := Phrases.Lookup('SETTINGS', 8);
90end;
91
92{ TSettingsDlg }
93
94procedure TSettingsDlg.FormCreate(Sender: TObject);
95begin
96 Color := clBlack;
97 LocalKeyBindings := TKeyBindings.Create;
98
99 Canvas.Font.Assign(UniFont[ftNormal]);
100 Canvas.Brush.Style := TBrushStyle.bsClear;
101
102 ButtonOk.Caption := Phrases.Lookup('BTN_OK');
103 ButtonCancel.Caption := Phrases.Lookup('BTN_CANCEL');
104 ButtonReset.Caption := Phrases.Lookup('BTN_RESET');
105 InitButtons;
106end;
107
108procedure TSettingsDlg.ButtonCancelClick(Sender: TObject);
109begin
110 ModalResult := mrCancel;
111end;
112
113procedure TSettingsDlg.ButtonResetClick(Sender: TObject);
114begin
115 ListLanguages.ItemIndex := 0;
116 ButtonFullscreen.ButtonIndex := 3;
117 LocalGamma := 100;
118 ListKeyBindings.ItemIndex := -1;
119 ListKeyBindingsSelectionChange(nil, False);
120 LocalKeyBindings.ResetToDefault;
121 LocalKeyBindings.LoadToStrings(ListKeyBindings.Items);
122 Repaint;
123end;
124
125procedure TSettingsDlg.ButtonGammaDownClick(Sender: TObject);
126begin
127 if LocalGamma > 50 then
128 begin
129 Dec(LocalGamma);
130 Invalidate;
131 end;
132end;
133
134procedure TSettingsDlg.EditShortCutPrimaryKeyUp(Sender: TObject; var Key: Word;
135 Shift: TShiftState);
136begin
137 if (Sender is TEdit) and Assigned(CurrentKeyBinding) and not (Key in [16..18]) then begin
138 CurrentKeyBinding.ShortCut := Key or
139 (scShift * Integer(ssShift in Shift)) or
140 (scCtrl * Integer(ssCtrl in Shift)) or
141 (scAlt * Integer(ssAlt in Shift));
142 EditShortCutPrimary.Text := ShortCutToText(CurrentKeyBinding.ShortCut);
143 Key := 0;
144 UpdateShortCutItem;
145 end;
146end;
147
148procedure TSettingsDlg.EditShortCutSecondaryKeyUp(Sender: TObject;
149 var Key: Word; Shift: TShiftState);
150begin
151 if (Sender is TEdit) and Assigned(CurrentKeyBinding) and not (Key in [16..18]) then begin
152 CurrentKeyBinding.ShortCut2 := Key or
153 (scShift * Integer(ssShift in Shift)) or
154 (scCtrl * Integer(ssCtrl in Shift)) or
155 (scAlt * Integer(ssAlt in Shift));
156 EditShortCutSecondary.Text := ShortCutToText(CurrentKeyBinding.ShortCut2);
157 Key := 0;
158 UpdateShortCutItem;
159 end;
160end;
161
162procedure TSettingsDlg.FormClose(Sender: TObject; var CloseAction: TCloseAction
163 );
164begin
165 ListKeyBindings.ItemIndex := -1;
166end;
167
168procedure TSettingsDlg.ButtonFullscreenClick(Sender: TObject);
169begin
170 ButtonFullscreen.ButtonIndex := ButtonFullscreen.ButtonIndex xor 1;
171end;
172
173procedure TSettingsDlg.ButtonDpiDownClick(Sender: TObject);
174begin
175 Dec(LocalDpi, DpiStep);
176 if LocalDpi < DpiMin then LocalDpi := DpiMin;
177 Invalidate;
178end;
179
180procedure TSettingsDlg.ButtonCustomDpiClick(Sender: TObject);
181begin
182 ButtonCustomDpi.ButtonIndex := ButtonCustomDpi.ButtonIndex xor 1;
183end;
184
185procedure TSettingsDlg.ButtonDpiUpClick(Sender: TObject);
186begin
187 Inc(LocalDpi, DpiStep);
188 if LocalDpi > DpiMax then LocalDpi := DpiMax;
189 Invalidate;
190end;
191
192procedure TSettingsDlg.FormDestroy(Sender: TObject);
193begin
194 FreeAndNil(LocalKeyBindings);
195end;
196
197procedure TSettingsDlg.FormPaint(Sender: TObject);
198begin
199 PaintBackground(Self, 3, 3, ClientWidth - 6, ClientHeight - 6);
200 Frame(Canvas, 0, 0, ClientWidth - 1, ClientHeight - 1, 0, 0);
201 Frame(Canvas, 1, 1, ClientWidth - 2, ClientHeight - 2,
202 MainTexture.ColorBevelLight, MainTexture.ColorBevelShade);
203 Frame(Canvas, 2, 2, ClientWidth - 3, ClientHeight - 3,
204 MainTexture.ColorBevelLight, MainTexture.ColorBevelShade);
205 EditFrame(Canvas, EditShortCutPrimary.BoundsRect, MainTexture);
206 EditFrame(Canvas, EditShortCutSecondary.BoundsRect, MainTexture);
207 EditFrame(Canvas, ListLanguages.BoundsRect, MainTexture);
208 BtnFrame(Canvas, ButtonOk.BoundsRect, MainTexture);
209 BtnFrame(Canvas, ButtonCancel.BoundsRect, MainTexture);
210
211 RFrame(Canvas, ButtonFullscreen.Left - 1, ButtonFullscreen.Top - 1,
212 ButtonFullscreen.Left + 12, ButtonFullscreen.Top + 12, MainTexture.ColorBevelShade,
213 MainTexture.ColorBevelLight);
214 {$IFDEF DPI}
215 RFrame(Canvas, ButtonCustomDpi.Left - 1, ButtonCustomDpi.Top - 1,
216 ButtonCustomDpi.Left + 12, ButtonCustomDpi.Top + 12, MainTexture.ColorBevelShade,
217 MainTexture.ColorBevelLight);
218 LoweredTextOut(Canvas, -2, MainTexture, ButtonCustomDpi.Left + 32,
219 ButtonCustomDpi.Top - 4, SCustomDpi);
220 UnderlinedTitleValue(Canvas, SDpi, IntToStr(LocalDpi) + '%',
221 ButtonDpiUp.Left - 150 - 4, ButtonDpiUp.Top + 2, 150);
222 {$ENDIF}
223
224 LoweredTextOut(Canvas, -2, MainTexture, ListLanguages.Left,
225 ListLanguages.Top - 26, SLanguages);
226 LoweredTextOut(Canvas, -2, MainTexture, ListKeyBindings.Left,
227 ListKeyBindings.Top - 26, SKeyBindings);
228 LoweredTextOut(Canvas, -2, MainTexture, ButtonFullscreen.Left + 32,
229 ButtonFullscreen.Top - 4, SFullScreen);
230 UnderlinedTitleValue(Canvas, SGamma, IntToStr(LocalGamma) + '%',
231 ButtonGammaUp.Left - 150 - 4, ButtonGammaUp.Top + 2, 150);
232 LoweredTextOut(Canvas, -2, MainTexture, EditShortCutPrimary.Left,
233 EditShortCutPrimary.Top - 26, SShortCutPrimary);
234 LoweredTextOut(Canvas, -2, MainTexture, EditShortCutSecondary.Left,
235 EditShortCutSecondary.Top - 26, SShortCutSecondary);
236end;
237
238procedure TSettingsDlg.FormShow(Sender: TObject);
239begin
240 Caption := Phrases2.Lookup('ACTIONHEADER_CONFIG');
241 ReloadLanguages;
242 StartDlg.Translator.LanguageListToStrings(ListLanguages.Items);
243 ListLanguages.Font.Color := MainTexture.ColorMark;
244 ListKeyBindings.Font.Color := MainTexture.ColorMark;
245 LoadData;
246 LocalKeyBindings.LoadToStrings(ListKeyBindings.Items);
247 EditShortCutPrimary.Font.Color := MainTexture.ColorMark;
248 EditShortCutSecondary.Font.Color := MainTexture.ColorMark;
249 {$IFDEF DPI}
250 ButtonCustomDpi.Visible := True;
251 ButtonDpiDown.Visible := True;
252 ButtonDpiUp.Visible := True;
253 {$ELSE}
254 ButtonCustomDpi.Visible := False;
255 ButtonDpiDown.Visible := False;
256 ButtonDpiUp.Visible := False;
257 {$ENDIF}
258end;
259
260procedure TSettingsDlg.ListKeyBindingsSelectionChange(Sender: TObject;
261 User: Boolean);
262begin
263 if Assigned(CurrentKeyBinding) then begin
264 CurrentKeyBinding.ShortCut := TextToShortCut(EditShortCutPrimary.Text);
265 CurrentKeyBinding.ShortCut2 := TextToShortCut(EditShortCutSecondary.Text);
266 end;
267
268 if ListKeyBindings.ItemIndex >= 0 then
269 CurrentKeyBinding := LocalKeyBindings[ListKeyBindings.ItemIndex]
270 else CurrentKeyBinding := nil;
271
272 if Assigned(CurrentKeyBinding) then begin
273 if CurrentKeyBinding.ShortCut <> 0 then
274 EditShortCutPrimary.Text := ShortCutToText(CurrentKeyBinding.ShortCut)
275 else EditShortCutPrimary.Text := '';
276 EditShortCutPrimary.Enabled := True;
277 if CurrentKeyBinding.ShortCut2 <> 0 then
278 EditShortCutSecondary.Text := ShortCutToText(CurrentKeyBinding.ShortCut2)
279 else EditShortCutSecondary.Text := '';
280 EditShortCutSecondary.Enabled := True;
281 end else begin
282 EditShortCutPrimary.Text := '';
283 EditShortCutPrimary.Enabled := False;
284 EditShortCutSecondary.Text := '';
285 EditShortCutSecondary.Enabled := False;
286 end;
287end;
288
289procedure TSettingsDlg.ButtonOkClick(Sender: TObject);
290begin
291 SaveData;
292 ModalResult := mrOk;
293end;
294
295procedure TSettingsDlg.ButtonGammaUpClick(Sender: TObject);
296begin
297 if LocalGamma < 150 then begin
298 Inc(LocalGamma);
299 Invalidate;
300 end;
301end;
302
303procedure TSettingsDlg.UpdateShortCutItem;
304begin
305 if Assigned(CurrentKeyBinding) then begin
306 if CurrentKeyBinding.ShortCut > 0 then
307 LocalKeyBindings.RemoveShortCut(CurrentKeyBinding.ShortCut);
308 if CurrentKeyBinding.ShortCut2 > 0 then
309 LocalKeyBindings.RemoveShortCut(CurrentKeyBinding.ShortCut2);
310 CurrentKeyBinding.ShortCut := TextToShortCut(EditShortCutPrimary.Text);
311 CurrentKeyBinding.ShortCut2 := TextToShortCut(EditShortCutSecondary.Text);
312 LocalKeyBindings.LoadToStrings(ListKeyBindings.Items);
313 end;
314end;
315
316function TSettingsDlg.GetLocalCustomDpiEnabled: Boolean;
317begin
318 Result := (ButtonCustomDpi.ButtonIndex and 1) = 1;
319end;
320
321procedure TSettingsDlg.LoadData;
322begin
323 StartDlg.Translator.Language := StartDlg.Translator.Languages.SearchByCode(LocaleCode);
324 StartDlg.Translator.LanguageListToStrings(ListLanguages.Items, False);
325 ListLanguages.ItemIndex := ListLanguages.Items.IndexOfObject(StartDlg.Translator.Language);
326 if ListLanguages.ItemIndex = -1 then ListLanguages.ItemIndex := 0;
327 if FullScreen then ButtonFullscreen.ButtonIndex := 3
328 else ButtonFullscreen.ButtonIndex := 2;
329 LocalGamma := Gamma;
330 LocalKeyBindings.Assign(KeyBindings.KeyBindings);
331 {$IFDEF DPI}
332 if CustomDpiEnabled then ButtonCustomDpi.ButtonIndex := 3
333 else ButtonCustomDpi.ButtonIndex := 2;
334 LocalDpi := Round(CustomDpi * 100 / 96);
335 {$ENDIF}
336end;
337
338procedure TSettingsDlg.SaveData;
339var
340 NeedRestart: Boolean;
341begin
342 NeedRestart := (Gamma <> LocalGamma) or (CustomDpiEnabled <> GetLocalCustomDpiEnabled) or
343 ((GetLocalCustomDpiEnabled and (LocalDpi <> CustomDpi)));
344 if ListLanguages.ItemIndex <> -1 then begin
345 StartDlg.Translator.Language := TLanguage(ListLanguages.Items.Objects[ListLanguages.ItemIndex]);
346 LocaleCode := StartDlg.Translator.Language.Code;
347 end else begin
348 StartDlg.Translator.Language := nil;
349 LocaleCode := '';
350 end;
351 FullScreen := (ButtonFullscreen.ButtonIndex and 1) = 1;
352 Gamma := LocalGamma;
353 ScreenTools.CustomDpiEnabled := CustomDpiEnabled;
354 if NeedRestart then SimpleMessage(SRestartMsg);
355 KeyBindings.KeyBindings.Assign(LocalKeyBindings);
356 {$IFDEF DPI}
357 CustomDpiEnabled := GetLocalCustomDpiEnabled;
358 CustomDpi := Round(LocalDpi * 96 / 100);
359 {$ENDIF}
360end;
361
362end.
363
364
Note: See TracBrowser for help on using the repository browser.