source: tools/PoConv/UFormMain.pas

unit UFormMain;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TFormMain }

  TFormMain = class(TForm)
    ButtonTxtToPo: TButton;
    ButtonPoToTxt: TButton;
    procedure ButtonPoToTxtClick(Sender: TObject);
    procedure ButtonTxtToPoClick(Sender: TObject);
  private
    procedure TxtToPo(SourceFileName, DestFileName: string);
    procedure PoToTxt(SourceFileName, DestFileName: string);
    function Escape(Text: string): string;
    function Unescape(Text: string): string;
    function Unquote(Text: string): string;
    procedure EmitPo(Lines: TStrings; Name, Value: string);
    procedure EmitTxt(Lines: TStrings; Name, Value: string);
  public

  end;

var
  FormMain: TFormMain;

implementation

{$R *.lfm}

{ TFormMain }

procedure TFormMain.ButtonTxtToPoClick(Sender: TObject);
var
  BaseDir: string;
begin
  BaseDir := '..' + DirectorySeparator + '..' + DirectorySeparator + 'trunk' + DirectorySeparator;
  TxtToPo(BaseDir + 'Language.txt', 'Language.po');
  TxtToPo(BaseDir + 'Language2.txt', 'Language2.po');
  TxtToPo(BaseDir + 'Help' + DirectorySeparator + 'help.txt', 'help.po');
end;

procedure TFormMain.ButtonPoToTxtClick(Sender: TObject);
begin
  PoToTxt('Language.po', 'Language.txt');
  PoToTxt('Language2.po', 'Language2.txt');
  PoToTxt('help.po', 'help.txt');
end;

procedure TFormMain.TxtToPo(SourceFileName, DestFileName: string);
var
  SourceLines: TStringList;
  DestLines: TStringList;
  I: Integer;
  Line: string;
  Name: string;
  Value: string;
  Index: Integer;
  NameIndex: Integer;
begin
  SourceLines := TStringList.Create;
  DestLines := TStringList.Create;
  with DestLines do begin
    Add('msgid ""');
    Add('msgstr ""');
    Add('"Content-Type: text/plain; charset=UTF-8\n"');
    Add('"X-Generator: PoConv\n"');
    Add('');
  end;

  SourceLines.LoadFromFile(SourceFileName);
  Name := '';
  NameIndex := 0;
  Value := '';
  I := 0;
  while I < SourceLines.Count do begin
    Line := SourceLines[I];
    if (Length(Line) > 0) and (Line[1] = '''') then begin
      if Name <> '' then begin
        EmitPo(DestLines, Name, Value);
        Name := '';
      end;
      DestLines.Add('#' + Copy(Line, 2, Length(Line)));
    end else
    if (Length(Line) > 0) and (Line[1] = '#') and (NameIndex = 0) then begin
      if Name <> '' then begin
        EmitPo(DestLines, Name, Value);
        Name := '';
      end;
      Index := Pos(' ', Line);
      if Index > 0 then begin
        Name := Copy(Line, 2, Index - 2);
        Value := Copy(Line, Index + 1, Length(Line));
      end else begin
        Name := Copy(Line, 2, Length(Line));
        Value := '';
      end;
    end else begin
      Value := Value + LineEnding + Line;
    end;
    Inc(I);
  end;
  if Name <> '' then begin
    EmitPo(DestLines, Name, Value);
    Name := '';
  end;
  DestLines.SaveToFile(DestFileName);
  FreeAndNil(SourceLines);
  FreeAndNil(DestLines);
end;

procedure TFormMain.PoToTxt(SourceFileName, DestFileName: string);
var
  SourceLines: TStringList;
  DestLines: TStringList;
  I: Integer;
  Line: string;
  Index: Integer;
  Name: string;
  Value: string;
  Cmd: string;
begin
  SourceLines := TStringList.Create;
  DestLines := TStringList.Create;
  SourceLines.LoadFromFile(SourceFileName);
  I := 0;
  Value := '';
  Name := '';
  while I < SourceLines.Count do begin
    Line := Trim(SourceLines[I]);
    Line := StringReplace(Line, '\n', '', [rfReplaceAll]);
    if (Length(Line) > 0) and (Line[1] = '#') then begin
      if Name <> '' then begin
        EmitTxt(DestLines, Name, Value);
        Name := '';
      end;
      DestLines.Add('''' + Copy(Line, 2, Length(Line)));
    end else begin
      if (Length(Line) > 0) and (Line[1] = '"') and (Line[Length(Line)] = '"') then begin
        Value := Value + LineEnding + Unquote(Line);
      end else begin
        Index := Pos(' ', Line);
        if Index > 0 then begin
          Cmd := Copy(Line, 1, Index - 1);
          if Cmd = 'msgid' then begin
            if Name <> '' then begin
              EmitTxt(DestLines, Name, Value);
              Name := '';
            end;
            Name := Unquote(Unescape(Copy(Line, Index + 1, Length(Line))));
          end else
          if Cmd = 'msgstr' then begin
            Value := Unquote(Copy(Line, Index + 1, Length(Line)));
          end;
        end;
      end;
    end;
    Inc(I);
  end;
  if Name <> '' then begin
    EmitTxt(DestLines, Name, Value);
    Name := '';
  end;
  DestLines.SaveToFile(DestFileName);
  FreeAndNil(SourceLines);
  FreeAndNil(DestLines);
end;

function TFormMain.Escape(Text: string): string;
begin
  Result := Text;
  Result := StringReplace(Result, '\', '\\', [rfReplaceAll]);
  Result := StringReplace(Result, '"', '\"', [rfReplaceAll]);
end;

function TFormMain.Unescape(Text: string): string;
begin
  Result := Text;
  Result := StringReplace(Result, '\\', '\', [rfReplaceAll]);
  Result := StringReplace(Result, '\"', '"', [rfReplaceAll]);
end;

function TFormMain.Unquote(Text: string): string;
begin
  Result := Text;
  if Length(Text) >= 2 then begin
    if (Text[1] = '"') and (Text[Length(Text)] = '"') then
      Result := Copy(Text, 2, Length(Text) - 2);
  end;
end;

procedure TFormMain.EmitPo(Lines: TStrings; Name, Value: string);
var
  MsgStr: string;
  Index: Integer;
  I: Integer;
  Stop: Boolean;
begin
  Lines.Add('msgid "' + Name + '"');
  I := 0;
  Stop := False;
  while not Stop do begin
    Index := Pos(LineEnding, Value);
    if Index > 0 then begin
      MsgStr := '"' + Escape(Copy(Value, 1, Index - 1)) + '\n"';
      Value := Copy(Value, Index + 1, Length(Value));
    end else begin
      MsgStr := '"' + Escape(Value) + '"';
      Value := '';
      Stop := True;
    end;
    if I = 0 then MsgStr := 'msgstr ' + MsgStr;
    Lines.Add(MsgStr);
    Inc(I);
  end;
  if I = 0 then Lines.Add('msgstr ""');
  Lines.Add('');
end;

procedure TFormMain.EmitTxt(Lines: TStrings; Name, Value: string);
var
  MsgStr: string;
  Index: Integer;
  I: Integer;
  Stop: Boolean;
begin
  I := 0;
  Stop := False;
  while not Stop do begin
    Index := Pos(LineEnding, Value);
    if Index > 0 then begin
      MsgStr := Unescape(Copy(Value, 1, Index - 1));
      Value := Copy(Value, Index + 1, Length(Value));
    end else begin
      MsgStr := Unescape(Value);
      Stop := True;
    end;
    if I = 0 then begin
      if Length(MsgStr) > 0 then MsgStr := ' ' + MsgStr;
      MsgStr := '#' + Name + MsgStr;
    end;
    Lines.Add(MsgStr);
    Inc(I);
  end;
  if I = 0 then begin
    Lines.Add('#' + Name);
  end;
end;

end.