source: branches/virtualcpu4/UMachine.pas

unit UMachine;

{$mode delphi}

interface

uses
  Classes, SysUtils, UCpu, syncobjs;

type
  TScreen = class
    Size: TPoint;
    MemoryBase: Integer;
    MemorySize: Integer;
    ChangedAreaFrom: Integer;
    ChangedAreaTo: Integer;
  end;

  { TMachine }

  TMachine = class
  private
    FMemorySize: Integer;
    function CpuInput(Port: TAddress): TRegister;
    procedure CpuOutput(Port: TAddress; Value: TRegister);
    function GetMemorySize: Integer;
    procedure SetMemorySize(AValue: Integer);
  public
    Memory: Pointer;
    Cpu: TCpu;
    Screen: TScreen;
    InputBuffer: string;
    OutputBuffer: string;
    LockInput: TCriticalSection;
    LockOutput: TCriticalSection;
    procedure ClearMemory;
    constructor Create;
    destructor Destroy; override;
    property MemorySize: Integer read GetMemorySize write SetMemorySize;
  end;

implementation

{ TMachine }

constructor TMachine.Create;
begin
  LockInput := TCriticalSection.Create;
  LockOutput := TCriticalSection.Create;
  Cpu := TCpu.Create;
  Cpu.OnInput := CpuInput;
  Cpu.OnOutput := CpuOutput;
  Cpu.DataSizeBase := bw32;
  Cpu.AddrSizeBase := bw32;
  Screen := TScreen.Create;
  Screen.Size := Point(320, 240);
  Screen.MemoryBase := $200;
  MemorySize := $1000000;
  Cpu.Memory := Memory;
end;

destructor TMachine.Destroy;
begin
  Screen.Free;
  Cpu.Free;
  LockInput.Free;
  LockOutput.Free;
  inherited Destroy;
end;

function TMachine.CpuInput(Port: TAddress): TRegister;
begin
  Result.Q := 0;
  case Port of
    0: begin
      LockInput.Acquire;
      while (Length(InputBuffer) = 0) and not Cpu.Terminated do begin
        LockInput.Release;
        Sleep(100);
        LockInput.Acquire;
      end;
      if Length(InputBuffer) > 0 then begin
        Result.B := Ord(InputBuffer[1]);
        Delete(InputBuffer, 1, 1);
      end else Result.B := 0;
      LockInput.Release;
    end;
    1: case Cpu.DataSize of
      bw8: Result.B := Screen.Size.X;
      bw16: Result.W := Screen.Size.X;
      bw32: Result.D := Screen.Size.X;
      bw64: Result.Q := Screen.Size.X;
    end;
    2: case Cpu.DataSize of
      bw8: Result.B := Screen.Size.Y;
      bw16: Result.W := Screen.Size.Y;
      bw32: Result.D := Screen.Size.Y;
      bw64: Result.Q := Screen.Size.Y;
    end;
    3: case Cpu.DataSize of
      bw8: Result.B := Screen.MemoryBase;
      bw16: Result.W := Screen.MemoryBase;
      bw32: Result.D := Screen.MemoryBase;
      bw64: Result.Q := Screen.MemoryBase;
    end;
  end;
end;

procedure TMachine.CpuOutput(Port: TAddress; Value: TRegister);
begin
  case Port of
    0: begin
      LockOutput.Acquire;
      OutputBuffer := OutputBuffer + Char(Value.B);
      LockOutput.Release;
    end;
    1: case Cpu.DataSize of
      bw8: Screen.Size.X := Value.B;
      bw16: Screen.Size.X := Value.W;
      bw32: Screen.Size.X := Value.D;
      bw64: Screen.Size.X := Value.Q;
    end;
    2: case Cpu.DataSize of
      bw8: Screen.Size.Y := Value.B;
      bw16: Screen.Size.Y := Value.W;
      bw32: Screen.Size.Y := Value.D;
      bw64: Screen.Size.Y := Value.Q;
    end;
    3: case Cpu.DataSize of
      bw8: Screen.MemoryBase := Value.B;
      bw16: Screen.MemoryBase := Value.W;
      bw32: Screen.MemoryBase := Value.D;
      bw64: Screen.MemoryBase := Value.Q;
    end;
    4: case Cpu.DataSize of
      bw8: Screen.ChangedAreaFrom := Value.B;
      bw16: Screen.ChangedAreaFrom := Value.W;
      bw32: Screen.ChangedAreaFrom := Value.D;
      bw64: Screen.ChangedAreaFrom := Value.Q;
    end;
    5: case Cpu.DataSize of
      bw8: Screen.ChangedAreaTo := Value.B;
      bw16: Screen.ChangedAreaTo := Value.W;
      bw32: Screen.ChangedAreaTo := Value.D;
      bw64: Screen.ChangedAreaTo := Value.Q;
    end;
  end;
end;

function TMachine.GetMemorySize: Integer;
begin
  Result := FMemorySize;
end;

procedure TMachine.SetMemorySize(AValue: Integer);
begin
  if FMemorySize = AValue then Exit;
  FMemorySize := AValue;
  Memory := ReAllocMem(Memory, FMemorySize);
end;

procedure TMachine.ClearMemory;
begin
  FillChar(Memory^, MemorySize, $ff);
end;


end.