source: branches/virtualcpu4/UInstructionReader.pas

unit UInstructionReader;

{$mode delphi}

interface

uses
  Classes, SysUtils, UCpu;

type

  { TInstructionReader }

  TInstructionReader = class
  protected
  public
    Cpu: TCpu;
    IP: Integer;
    Prefix: Boolean;
    DataSize: TBitWidth;
    DataSizeBase: TBitWidth;
    AddrSize: TBitWidth;
    AddrSizeBase: TBitWidth;
    procedure Init;
    function Read8: Byte; inline;
    function Read16: Word; inline;
    function Read32: DWord; inline;
    function Read64: QWord; inline;
    function ReadAddress: TAddress; inline;
    function ReadAddressSigned: TAddressSigned; inline;
    function ReadData: QWord;
  end;

implementation

{ TInstructionReader }

procedure TInstructionReader.Init;
begin
  DataSizeBase := Cpu.DataSizeBase;
  DataSize := DataSizeBase;
  AddrSizeBase := Cpu.AddrSizeBase;
  AddrSize := AddrSizeBase;
  IP := 0;
  Prefix := False;
end;

function TInstructionReader.Read8: Byte;
begin
  Result := PByte(Cpu.Memory + IP)^;
  Inc(IP);
end;

function TInstructionReader.Read16: Word;
begin
  Result := PWord(Cpu.Memory + IP)^;
  Inc(IP, SizeOf(Word));
end;

function TInstructionReader.Read32: DWord;
begin
  Result := PDWord(Cpu.Memory + IP)^;
  Inc(IP, SizeOf(DWord));
end;

function TInstructionReader.Read64: QWord;
begin
  Result := PQWord(Cpu.Memory + IP)^;
  Inc(IP, SizeOf(QWord));
end;

function TInstructionReader.ReadAddress: TAddress;
begin
  case AddrSize of
    bw8: Result := Read8;
    bw16: Result := Read16;
    bw32: Result := Read32;
    bw64: Result := Read64;
  end;
end;

function TInstructionReader.ReadAddressSigned: TAddressSigned;
begin
  case AddrSize of
    bw8: Result := ShortInt(Read8);
    bw16: Result := SmallInt(Read16);
    bw32: Result := Integer(Read32);
    bw64: Result := Int64(Read64);
  end;
end;

function TInstructionReader.ReadData: QWord;
begin
  case DataSize of
    bw8: Result := Read8;
    bw16: Result := Read16;
    bw32: Result := Read32;
    bw64: Result := Read64;
  end;
end;

end.