source: branches/virtualcpu/UFormMain.pas

unit UFormMain;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Menus, UMachine;

type

  { TForm1 }

  TForm1 = class(TForm)
    ButtonRun: TButton;
    ListViewMemory: TListView;
    ListViewRegisters: TListView;
    procedure ButtonRunClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewMemoryData(Sender: TObject; Item: TListItem);
    procedure ListViewRegistersData(Sender: TObject; Item: TListItem);
  private
    Addr: Integer;
    procedure Example;
    procedure ShowMemory;
    procedure ShowRegisters;
    procedure AddData(Data: Integer);
    procedure AddOpcode(Opcode: TOpcode);
    procedure AddOpcode1(Opcode: TOpcode; Param1: Integer);
    procedure AddOpcode2(Opcode: TOpcode; Param1, Param2: Integer);
  public
    Machine: TMachine;
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  Machine := TMachine.Create;
end;

procedure TForm1.ButtonRunClick(Sender: TObject);
begin
  Machine.Run;
  ShowMemory;
  ShowRegisters;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Machine.Free;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  SetLength(Machine.Memory, 1000);
  Addr := 0;

  Example;
  ShowMemory;
  ShowRegisters;
end;

procedure TForm1.ListViewMemoryData(Sender: TObject; Item: TListItem);
var
  Data: string;
  I: Integer;
begin
  if (Item.Index >= 0) and (Item.Index < (Length(Machine.Memory) div 16)) then begin
    Item.Caption := IntToHex(Item.Index * 16, 8);
    Data := '';
    for I := 0 to 15 do
      Data := Data + ' ' + IntToHex(Machine.Memory[Item.Index * 16 + I], 2);
    Item.SubItems.Add(Data);
  end;
end;

procedure TForm1.ListViewRegistersData(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < Length(Machine.Registers)) then begin
    Item.Caption := IntToHex(Item.Index, 2);
    Item.SubItems.Add(IntToHex(Machine.Registers[Item.Index], 8));
  end;
end;

procedure TForm1.Example;
const
  Acc = 0;
  Source = 1;
  Dest = 2;
  Counter = 3;
  Temp = 4;
begin
  AddOpcode1(opGetDataSize, Temp);
  AddOpcode2(opSetRegSize, Source, Temp);
  AddOpcode2(opSetRegSize, Dest, Temp);
  AddOpcode2(opSetRegSize, Counter, Temp);
  AddOpcode2(opCopyConst, Temp, 1);
  AddOpcode2(opSetRegSize, Acc, Temp);

  AddOpcode2(opCopyConst, Counter, 8);
  AddOpcode2(opCopyConst, Source, $30);
  AddOpcode2(opCopyConst, Dest, $40);

  AddOpcode2(opCopyFromMem, Acc, Source);
  AddOpcode2(opCopyToMem, Acc, Dest);
  AddOpcode1(opInc, Source);
  AddOpcode1(opInc, Dest);
  AddOpcode1(opDec, Counter);
  AddOpcode2(opJumpRelNotZero, Counter, -15);
  AddOpcode(opHalt);
end;

procedure TForm1.ShowMemory;
begin
  ListViewMemory.Items.Count := Length(Machine.Memory) div 16;
  ListViewMemory.Refresh;
end;

procedure TForm1.ShowRegisters;
begin
  ListViewRegisters.Items.Count := Length(Machine.Registers);
  ListViewRegisters.Refresh;
end;

procedure TForm1.AddData(Data: Integer);
begin
  Machine.Memory[Addr] := Data;
  Inc(Addr);
end;

procedure TForm1.AddOpcode(Opcode: TOpcode);
begin
  AddData(Integer(Opcode));
end;

procedure TForm1.AddOpcode1(Opcode: TOpcode; Param1: Integer);
begin
  AddData(Integer(Opcode));
  AddData(Param1);
end;

procedure TForm1.AddOpcode2(Opcode: TOpcode; Param1, Param2: Integer);
begin
  AddData(Integer(Opcode));
  AddData(Param1);
  AddData(Param2);
end;

end.