source: branches/virtcpu varint/UMachine.pas

unit UMachine;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, UVarInt, UCpu, syncobjs;

type
  TScreen = class
    Size: TPoint;
    MemoryBase: Integer;
    MemorySize: Integer;
    ChangedAreaFrom: Integer;
    ChangedAreaTo: Integer;
  end;

  { TMachine }

  TMachine = class(TComponent)
  private
    FMemorySize: Integer;
    procedure SetMemorySize(AValue: Integer);
    function CpuInput(Port: T): T;
    procedure CpuOutput(Port: T; Value: T);
  public
    Cpu: TCpu;
    Memory: Pointer;
    Screen: TScreen;
    InputBuffer: string;
    OutputBuffer: string;
    LockInput: TCriticalSection;
    LockOutput: TCriticalSection;
    property MemorySize: Integer read FMemorySize write SetMemorySize;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;


implementation

{ TMachine }

procedure TMachine.SetMemorySize(AValue: Integer);
begin
  if FMemorySize = AValue then Exit;
  FMemorySize := AValue;
  Memory := ReAllocMem(Memory, FMemorySize);
  Cpu.Memory := Memory;
  Cpu.OnOutput := CpuOutput;
  Cpu.OnInput := CpuInput;
end;

function TMachine.CpuInput(Port: T): T;
begin
  Result := 0;
  case Integer(Port) of
    0: begin
      LockInput.Acquire;
      while (Length(InputBuffer) = 0) and not Cpu.Terminated do begin
        LockInput.Release;
        Sleep(100);
        LockInput.Acquire;
      end;
      if Length(InputBuffer) > 0 then begin
        Result := Ord(InputBuffer[1]);
        Delete(InputBuffer, 1, 1);
      end else Result := 0;
      LockInput.Release;
    end;
    1: Result := Screen.Size.X;
    2: Result := Screen.Size.Y;
    3: Result := Screen.MemoryBase;
  end;
end;

procedure TMachine.CpuOutput(Port: T; Value: T);
begin
  case Integer(Port) of
    0: begin
      LockOutput.Acquire;
      OutputBuffer := OutputBuffer + Char(Value);
      LockOutput.Release;
    end;
    1: Screen.Size.X := Value;
    2: Screen.Size.Y := Value;
    3: Screen.MemoryBase := Value;
    4: Screen.ChangedAreaFrom := Value;
    5: Screen.ChangedAreaTo := Value;
  end;
end;

constructor TMachine.Create(AOwner: TComponent);
begin
  inherited;
  LockInput := TCriticalSection.Create;
  LockOutput := TCriticalSection.Create;
  Cpu := TCpu.Create(nil);
  MemorySize := 1000;
  Screen := TScreen.Create;
  Screen.Size := Point(320, 240);
  Screen.MemoryBase := $200;
end;

destructor TMachine.Destroy;
begin
  MemorySize := 0;
  FreeAndNil(Screen);
  FreeAndNil(Cpu);
  inherited Destroy;
end;

end.