source: branches/virtcpu varint/UDisassembler.pas

unit UDisassembler;

{$mode delphi}

interface

uses
  Classes, SysUtils, fgl, UCpu, UInstructionReader, Math, UOpcode, UVarInt;

type
  TDisassemblerLine = class
    Address: Integer;
    Opcode: string;
    Instruction: string;
  end;

  { TDisassembler }

  TDisassembler = class(TInstructionReader)
  private
    OpcodeDefs: TOpcodeDefs;
    procedure ProcessParam(Param: TOpcodeParam; Line: TDisassemblerLine; Separator: string = '');
  public
    Output: TFPGObjectList<TDisassemblerLine>;
    procedure Process;
    constructor Create;
    destructor Destroy; override;
  end;


implementation

{ TDisassembler }

procedure TDisassembler.ProcessParam(Param: TOpcodeParam; Line: TDisassemblerLine; Separator: string = '');
var
  Reg: TVarUInt;
  Data: TVarUInt;
  Address: TVarUInt;
  AddressRel: TVarInt;
begin
  case Param of
    prReg: begin
      Reg := Read;
      Line.Opcode := Line.Opcode + ' ' + IntToHex(Integer(Reg), 2);
      Line.Instruction := Line.Instruction + Separator + ' R' + IntToStr(Integer(Reg));
    end;
    prData: begin
      Data := Read;
      Line.Opcode := Line.Opcode + ' ' + IntToHex(Integer(Data), 8);
      Line.Instruction := Line.Instruction + Separator + ' ' + IntToHexEx(QWord(Data), -1, '$');
    end;
    prAddr: begin
      Address := Read;
      Line.Opcode := Line.Opcode + ' ' + IntToHex(Integer(Address), 8);
      Line.Instruction := Line.Instruction + Separator + ' ' + IntToHexEx(QWord(Address), -1, '$');
    end;
    prAddrRel: begin
      AddressRel := ReadSigned;
      Line.Opcode := Line.Opcode + ' ' + IntToHexEx(Int64(AddressRel), 8);
      Line.Instruction := Line.Instruction + Separator + ' ' + IntToHexEx(Int64(AddressRel), -1, '$');
    end;
  end;
end;

procedure TDisassembler.Process;
var
  Opcode: TVarUInt;
  Line: TDisassemblerLine;
  MemorySize: Integer;
  OpcodeDef: TOpcodeDef;
begin
  Init;
  Output.Clear;

  MemorySize := MemSize(Cpu.Memory);
  while IP < MemorySize do begin
    Opcode := Read;
    if Opcode <= Integer(High(TOpcode)) then begin
      OpcodeDef := OpcodeDefs.SearchByOpcode(TOpcode(Integer(Opcode)));
      Line := TDisassemblerLine.Create;
      Line.Address := IP - 1;
      Line.Opcode := IntToHex(Integer(Opcode), 2);
      Line.Instruction := OpcodeDef.Name;
      ProcessParam(OpcodeDef.Param1, Line);
      ProcessParam(OpcodeDef.Param2, Line, ',');
      ProcessParam(OpcodeDef.Param3, Line, ',');
      ProcessParam(OpcodeDef.Param4, Line, ',');
      Output.Add(Line);
    end else begin
      {Line := TDisassemblerLine.Create;
      Line.Address := IP;
      Line.Opcode := IntToHex(Opcode, 2);
      Line.Instruction := '';
      Output.Add(Line);
      }
    end;
  end;
end;

constructor TDisassembler.Create;
begin
  OpcodeDefs := TOpcodeDefs.Create;
  Output := TFPGObjectList<TDisassemblerLine>.Create;
end;

destructor TDisassembler.Destroy;
begin
  FreeAndNil(Output);
  FreeAndNil(OpcodeDefs);
  inherited Destroy;
end;


end.