source: branches/generator/Forms/UFormRules.pas

unit UFormRules;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs,
  ComCtrls, ActnList, Menus, UGrammer, UListViewSort;

type

  { TFormRules }

  TFormRules = class(TForm)
    AAdd: TAction;
    AModify: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    CoolBar1: TCoolBar;
    ListView1: TListView;
    ListViewSort1: TListViewSort;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    PopupMenu1: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1KeyPress(Sender: TObject; var Key: char);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    { private declarations }
  public
    Rules: TRules;
    procedure UpdateInterface;
    procedure ReloadList;
  end;

var
  FormRules: TFormRules;


implementation

{$R *.lfm}

uses
  UFormRule, UCore;

const
  BooleanText: array[Boolean] of string = ('No', 'Yes');

{ TFormRules }

procedure TFormRules.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  ReloadList;
  UpdateInterface;
end;

procedure TFormRules.AAddExecute(Sender: TObject);
var
  NewRule: TRule;
begin
  NewRule := TRule.Create;
  NewRule.Grammer := Rules.Grammer;
  FormRule := TFormRule.Create(nil);
  FormRule.LoadData(NewRule);
  if FormRule.ShowModal = mrOk then begin
    FormRule.SaveData(NewRule);
    Rules.Add(NewRule);
    ReloadList;
  end else FreeAndNil(NewRule);
  FreeAndNil(FormRule);
end;

procedure TFormRules.AModifyExecute(Sender: TObject);
var
  Rule: TRule;
  FormRule: TFormRule;
begin
  if Assigned(ListView1.Selected) then begin
    Rule := TRule(ListView1.Selected.Data);
    FormRule := TFormRule.Create(nil);
    FormRule.LoadData(Rule);
    if FormRule.ShowModal = mrOk then begin
      FormRule.SaveData(Rule);
      ReloadList;
    end;
    FreeAndNil(FormRule);
  end;
end;

procedure TFormRules.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if MessageDlg('Remove item(s)', 'Do you want to remove selected item(s)?',
    mtConfirmation, mbYesNo, 0) = mrYes then
  for I := ListView1.Items.Count - 1 downto 0 do
  if ListView1.Items[I].Selected then begin
    Rules.Grammer.Modified := True;
    Rules.Remove(TRule(ListView1.Items[I].Data));
  end;
  ReloadList;
end;

procedure TFormRules.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormRules.FormCreate(Sender: TObject);
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  Rules := nil;
end;

procedure TFormRules.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < ListViewSort1.List.Count) then
  with TRule(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ListViewSort1.List[Item.Index];
    Item.SubItems.Add(BooleanText[CreateSourceNode]);
    Item.SubItems.Add(Items.GetString);
    Item.SubItems.Add(IntToStr(Items.GetCharLength));
    Item.SubItems.Add(RuleLevelText[Level]);
  end;
end;

procedure TFormRules.ListView1DblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormRules.ListView1KeyPress(Sender: TObject; var Key: char);
begin
  if Key = #13 then AModify.Execute;
end;

procedure TFormRules.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

function TFormRules.ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TRule(Item1).Name, TRule(Item2).Name);
      1: Result := CompareString(BooleanText[TRule(Item1).CreateSourceNode], BooleanText[TRule(Item2).CreateSourceNode]);
      2: Result := CompareString(TRule(Item1).GetString, TRule(Item2).GetString);
      3: Result := CompareInteger(TRule(Item1).Items.GetCharLength,
        TRule(Item2).Items.GetCharLength);
      4: Result := CompareString(RuleLevelText[TRule(Item1).Level],
        RuleLevelText[TRule(Item2).Level]);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormRules.ListViewSort1Filter(ListViewSort: TListViewSort);
var
  I: Integer;
begin
  if Assigned(Rules) then begin
    ListViewSort1.List.Count := Rules.Count;
    for I := 0 to Rules.Count - 1 do
      ListViewSort1.List[I] := Rules[I];
    //FilterList(ListViewSort1.List);
  end else ListViewSort1.List.Count := 0;
end;

procedure TFormRules.UpdateInterface;
begin
  AAdd.Enabled := Assigned(Rules);
  AModify.Enabled := Assigned(Rules) and Assigned(ListView1.Selected);
  ARemove.Enabled := Assigned(Rules) and Assigned(ListView1.Selected);
end;

procedure TFormRules.ReloadList;
begin
  ListViewSort1.Refresh;
  ListView1.Refresh;
end;

end.