source: branches/generator/Forms/UFormRuleItem.pas

unit UFormRuleItem;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, UGrammer;

type

  { TFormRuleItem }

  TFormRuleItem = class(TForm)
    ButtonCancel: TButton;
    ButtonOk: TButton;
    CheckBoxLookupTable: TCheckBox;
    CheckBoxAnyExcept: TCheckBox;
    CheckBoxEscapedString: TCheckBox;
    CheckBoxOptional: TCheckBox;
    CheckBoxRepetitive: TCheckBox;
    ComboBoxLookupTableAction: TComboBox;
    ComboBoxType: TComboBox;
    EditTerminal: TEdit;
    EditTerminalFrom: TEdit;
    EditTerminalTo: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    LabelNonTerminal: TLabel;
    LabelTerminal: TLabel;
    LabelTerminal1: TLabel;
    LabelTerminal2: TLabel;
    ListBoxNonTerminals: TListBox;
    ListBoxLookupTable: TListBox;
    PageControl1: TPageControl;
    TabSheetTerminalRange: TTabSheet;
    TabSheetTerminal: TTabSheet;
    TabSheetNonTerminal: TTabSheet;
    TabSheetSubItems: TTabSheet;
    procedure CheckBoxLookupTableChange(Sender: TObject);
    procedure ComboBoxTypeChange(Sender: TObject);
    procedure EditTerminalKeyPress(Sender: TObject; var Key: char);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    FormRuleItems: TForm;
    procedure ReloadNonTerminals(Grammer: TGrammer);
    procedure ReloadLookupTables(Grammer: TGrammer);
  public
    RuleItem: TRuleItem;
    procedure UpdateInterface;
    procedure LoadData(RuleItem: TRuleItem);
    procedure SaveData(RuleItem: TRuleItem);
  end;

var
  FormRuleItem: TFormRuleItem;


implementation

uses
  UCore, UFormRuleItems;

{$R *.lfm}

{ TFormRuleItem }

procedure TFormRuleItem.ComboBoxTypeChange(Sender: TObject);
begin
  RuleItem.RuleItemType := TRuleItemType(ComboBoxType.ItemIndex);
  UpdateInterface;
end;

procedure TFormRuleItem.CheckBoxLookupTableChange(Sender: TObject);
begin
  UpdateInterface;
end;

procedure TFormRuleItem.EditTerminalKeyPress(Sender: TObject; var Key: char);
begin
  if Key = #13 then ButtonOk.Click;
end;

procedure TFormRuleItem.FormClose(Sender: TObject; var CloseAction: TCloseAction
  );
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormRuleItem.FormCreate(Sender: TObject);
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  FormRuleItems := TFormRuleItems.Create(nil);
  FormRuleItems.ManualDock(TabSheetSubItems);
  FormRuleItems.Align := alClient;
  FormRuleItems.Show;
end;

procedure TFormRuleItem.FormDestroy(Sender: TObject);
begin
  FreeAndNil(FormRuleItems);
end;

procedure TFormRuleItem.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  case RuleItem.RuleItemType of
    ritTerminal: EditTerminal.SetFocus;
    ritNonTerminal: ListBoxNonTerminals.SetFocus;
    ritSubItems: TFormRuleItems(FormRuleItems).ListView1.SetFocus;
    ritTerminalRange: EditTerminalFrom.SetFocus;
  end;
end;


procedure TFormRuleItem.ReloadNonTerminals(Grammer: TGrammer);
var
  Rule: TRule;
begin
  ListBoxNonTerminals.Items.Clear;
  for Rule in Grammer.Rules do begin
    ListBoxNonTerminals.Items.AddObject(Rule.Name, Rule);
  end;
  ListBoxNonTerminals.Sorted := True;
end;

procedure TFormRuleItem.ReloadLookupTables(Grammer: TGrammer);
var
  Item: TLookupTable;
begin
  ListBoxLookupTable.Items.Clear;
  for Item in Grammer.LookupTables do begin
    ListBoxLookupTable.Items.AddObject(Item.Name, Item);
  end;
  ListBoxLookupTable.Sorted := True;
end;

procedure TFormRuleItem.UpdateInterface;
begin
  PageControl1.PageIndex := Integer(RuleItem.RuleItemType);
  EditTerminal.Visible := RuleItem.RuleItemType = ritTerminal;
  LabelTerminal.Visible := RuleItem.RuleItemType = ritTerminal;
  ListBoxNonTerminals.Visible := RuleItem.RuleItemType = ritNonTerminal;
  LabelNonTerminal.Visible := RuleItem.RuleItemType = ritNonTerminal;
  CheckBoxOptional.Enabled := RuleItem.ParentRule.Items.RuleType = rtAnd;
  CheckBoxRepetitive.Enabled := RuleItem.ParentRule.Items.RuleType = rtAnd;
  CheckBoxEscapedString.Enabled := (RuleItem.RuleItemType = ritTerminal) or
    (RuleItem.RuleItemType = ritTerminalRange);
  ListBoxLookupTable.Enabled := CheckBoxLookupTable.Checked;
  ComboBoxLookupTableAction.Enabled := CheckBoxLookupTable.Checked;
end;

procedure TFormRuleItem.LoadData(RuleItem: TRuleItem);
begin
  Self.RuleItem := RuleItem;
  ReloadNonTerminals(RuleItem.Grammer);
  ComboBoxType.ItemIndex := Integer(RuleItem.RuleItemType);
  ListBoxNonTerminals.ItemIndex := ListBoxNonTerminals.Items.IndexOfObject(RuleItem.NonTerminal);
  EditTerminal.Text := RuleItem.Terminal;
  EditTerminalFrom.Text := RuleItem.TerminalFrom;
  EditTerminalTo.Text := RuleItem.TerminalTo;
  CheckBoxOptional.Checked := RuleItem.Optional;
  CheckBoxRepetitive.Checked := RuleItem.Repetitive;
  CheckBoxAnyExcept.Checked := RuleItem.AnyExcept;
  TFormRuleItems(FormRuleItems).LoadData(RuleItem.SubItems);
  CheckBoxEscapedString.Checked := RuleItem.EscapedStrings;
  // Lookup table
  CheckBoxLookupTable.Checked := RuleItem.LookupTableUsed;
  ReloadLookupTables(RuleItem.Grammer);
  ComboBoxLookupTableAction.ItemIndex := Integer(RuleItem.LookupTableAction);
  ListBoxLookupTable.ItemIndex := ListBoxLookupTable.Items.IndexOfObject(RuleItem.LookupTable);
  UpdateInterface;
end;

procedure TFormRuleItem.SaveData(RuleItem: TRuleItem);
begin
  RuleItem.Grammer.Modified := True;
  TFormRuleItems(FormRuleItems).SaveData(RuleItem.SubItems);
  RuleItem.RuleItemType := TRuleItemType(ComboBoxType.ItemIndex);
  RuleItem.Terminal := EditTerminal.Text;
  RuleItem.TerminalFrom := EditTerminalFrom.Text;
  RuleItem.TerminalTo := EditTerminalTo.Text;
  if ListBoxNonTerminals.ItemIndex <> -1 then
    RuleItem.NonTerminal := TRule(ListBoxNonTerminals.Items.Objects[ListBoxNonTerminals.ItemIndex])
    else RuleItem.NonTerminal := nil;
  RuleItem.Optional := CheckBoxOptional.Checked;
  RuleItem.Repetitive := CheckBoxRepetitive.Checked;
  RuleItem.AnyExcept := CheckBoxAnyExcept.Checked;
  RuleItem.EscapedStrings := CheckBoxEscapedString.Checked;
  // Lookup table
  RuleItem.LookupTableUsed := CheckBoxLookupTable.Checked;
  RuleItem.LookupTableAction := TLookupTableAction(ComboBoxLookupTableAction.ItemIndex);
  if ListBoxLookupTable.ItemIndex <> -1 then
    RuleItem.LookupTable := TLookupTable(ListBoxLookupTable.Items.Objects[ListBoxLookupTable.ItemIndex])
    else RuleItem.LookupTable := nil;
end;

end.