source: branches/generator/Forms/UFormLookupTables.pas

unit UFormLookupTables;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UListViewSort, UGrammer;

type

  { TFormLookupTables }

  TFormLookupTables = class(TForm)
    AAdd: TAction;
    ActionList1: TActionList;
    AModify: TAction;
    ARemove: TAction;
    CoolBar1: TCoolBar;
    ListView1: TListView;
    ListViewSort1: TListViewSort;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    PopupMenu1: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1KeyPress(Sender: TObject; var Key: char);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private

  public
    LookupTables: TLookupTables;
    procedure ReloadList;
    procedure UpdateInterface;
  end;

var
  FormLookupTables: TFormLookupTables;


implementation

uses
  UFormLookupTable, UCore;

{$R *.lfm}

{ TFormLookupTables }

procedure TFormLookupTables.AAddExecute(Sender: TObject);
var
  NewItem: TLookupTable;
begin
  NewItem := TLookupTable.Create;
  NewItem.Grammer := LookupTables.Grammer;
  FormLookupTable := TFormLookupTable.Create(nil);
  FormLookupTable.LoadData(NewItem);
  if FormLookupTable.ShowModal = mrOk then begin
    FormLookupTable.SaveData(NewItem);
    LookupTables.Add(NewItem);
    ReloadList;
  end else FreeAndNil(NewItem);
  FreeAndNil(FormLookupTable);
end;

procedure TFormLookupTables.AModifyExecute(Sender: TObject);
var
  Item: TLookupTable;
  FormItem: TFormLookupTable;
begin
  if Assigned(ListView1.Selected) then begin
    Item := TLookupTable(ListView1.Selected.Data);
    FormItem := TFormLookupTable.Create(nil);
    FormItem.LoadData(Item);
    if FormItem.ShowModal = mrOk then begin
      FormItem.SaveData(Item);
      ReloadList;
    end;
    FreeAndNil(FormItem);
  end;
end;

procedure TFormLookupTables.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if MessageDlg('Remove item(s)', 'Do you want to remove selected item(s)?',
    mtConfirmation, mbYesNo, 0) = mrYes then
  for I := ListView1.Items.Count - 1 downto 0 do
  if ListView1.Items[I].Selected then begin
    LookupTables.Grammer.Modified := True;
    LookupTables.Remove(TLookupTable(ListView1.Items[I].Data));
  end;
  ReloadList;
end;

procedure TFormLookupTables.FormClose(Sender: TObject;
  var CloseAction: TCloseAction);
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormLookupTables.FormCreate(Sender: TObject);
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  LookupTables := nil;
end;

procedure TFormLookupTables.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  ReloadList;
  UpdateInterface;
end;

procedure TFormLookupTables.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < ListViewSort1.List.Count) then
  with TLookupTable(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ListViewSort1.List[Item.Index];
  end;
end;

procedure TFormLookupTables.ListView1DblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormLookupTables.ListView1KeyPress(Sender: TObject; var Key: char);
begin
  if Key = #13 then AModify.Execute;
end;

procedure TFormLookupTables.ListView1SelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

function TFormLookupTables.ListViewSort1CompareItem(Item1, Item2: TObject
  ): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TLookupTable(Item1).Name, TLookupTable(Item2).Name);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormLookupTables.ListViewSort1Filter(ListViewSort: TListViewSort);
var
  I: Integer;
begin
  if Assigned(LookupTables) then begin
    ListViewSort1.List.Count := LookupTables.Count;
    for I := 0 to LookupTables.Count - 1 do
      ListViewSort1.List[I] := LookupTables[I];
  end else ListViewSort1.List.Count := 0;
end;

procedure TFormLookupTables.ReloadList;
begin
  ListViewSort1.Refresh;
  ListView1.Refresh;
end;

procedure TFormLookupTables.UpdateInterface;
begin
  AAdd.Enabled := Assigned(LookupTables);
  AModify.Enabled := Assigned(LookupTables) and Assigned(ListView1.Selected);
  ARemove.Enabled := Assigned(LookupTables) and Assigned(ListView1.Selected);
end;

end.