source: branches/easy compiler/USourceGenerator.pas

unit USourceGenerator;

{$mode delphi}

interface

uses
  Classes, SysUtils, USourceCode;

type
  { TSourceGenerator }

  TSourceGenerator = class
  private
    Indent: Integer;
    function GenerateBeginEnd(BeginEnd: TCommandBeginEnd): string;
    function GenerateCommand(Command: TSourceCommand): string;
    function GenerateRef(Reference: TSourceReference): string;
    function IndentStr: string;
  public
    function Generate(SourceCode: TSourceCode): string;
  end;


implementation

{ TSourceGenerator }

function TSourceGenerator.Generate(SourceCode: TSourceCode): string;
var
  I: Integer;
begin
  Indent := 0;
  Result := '';
  if SourceCode.Variables.Count > 0 then
    Result := Result + IndentStr + 'var' + LineEnding;
  Inc(Indent);
  with SourceCode do
  for I := 0 to Variables.Count - 1 do
  with TSourceVariable(Variables[I]) do begin
    Result := Result + IndentStr + Name + ': ';
    if ValueType.Name = 'String' then
      Result := Result + 'string'
    else if ValueType.Name = 'Integer' then
      Result := Result + 'Integer'
    else if ValueType.Name = 'StringArray' then
      Result := Result + 'array of string'
    else if ValueType.Name = 'IntegerArray' then
      Result := Result + 'array of Integer'
    else raise Exception.Create('Unsupported type');
    Result := Result + ';' + LineEnding;
  end;
  Dec(Indent);
  Result := Result + GenerateBeginEnd(SourceCode.Main) + '.' + LineEnding;
end;

function TSourceGenerator.GenerateRef(Reference: TSourceReference): string;
var
  Value: TSourceValue;
begin
  Result := '';
  if Reference is TSourceReferenceConstant then begin
    Value := TSourceReferenceConstant(Reference).Constant.Value;
    if Value is TSourceValueString then
      Result := Result + '''' + TSourceValueString(Value).Value + ''''
    else
    if Value is TSourceValueInteger then
      Result := Result + IntToStr(TSourceValueInteger(Value).Value);
  end else
  if Reference is TSourceReferenceVariable then begin
    Result := Result + TSourceReferenceVariable(Reference).Variable.Name;
  end else
  if Reference is TSourceReferenceArray then begin
    Result := Result + TSourceReferenceArray(Reference).ArrayRef.Name +
      '[' + GenerateRef(TSourceReferenceArray(Reference).Index) + ']';
  end else raise Exception.Create('Unsupported parameter type');
end;

function TSourceGenerator.GenerateCommand(Command: TSourceCommand): string;
begin
  Result := '';
  if Command is TCommandFunctionCall then
  with TCommandFunctionCall(Command) do begin
    if Name = 'print' then begin
      Result := Result + IndentStr + 'Write(' + GenerateRef(TSourceReference(Parameters[0])) + ');' +
        LineEnding;
    end else
    if Name = 'println' then begin
      Result := Result + IndentStr + 'WriteLn(' + GenerateRef(TSourceReference(Parameters[0])) + ');' +
        LineEnding;
    end else
    if Name = 'assign' then begin
      if TSourceReference(Parameters[0]) is TSourceReferenceArray then
        Result := Result + IndentStr + 'SetLength(' + TSourceReferenceArray(Parameters[0]).ArrayRef.Name +
          ', ' + GenerateRef(TSourceReferenceArray(Parameters[0]).Index) + ' + 1);' + LineEnding;
      Result := Result + IndentStr + GenerateRef(TSourceReference(Parameters[0])) + ' := ' +
        GenerateRef(TSourceReference(Parameters[1])) + ';' + LineEnding;
    end else
    if Name = 'inputln' then begin
      Result := Result + IndentStr + 'ReadLn(' + GenerateRef(TSourceReference(Parameters[0])) + ');' + LineEnding;
    end else
    if Name = 'increment' then begin
      Result := Result + IndentStr + 'Inc(' + GenerateRef(TSourceReference(Parameters[0])) + ', ' +
        GenerateRef(TSourceReference(Parameters[1])) + ');' + LineEnding;
    end else
    if Name = 'decrement' then begin
      Result := Result + IndentStr + 'Dec(' + GenerateRef(TSourceReference(Parameters[0])) + ', ' +
        GenerateRef(TSourceReference(Parameters[1])) + ');' + LineEnding;
    end else
    raise Exception.Create('Unsupported instruction name.');
  end else
  if Command is TCommandBeginEnd then begin
    Result := Result + GenerateBeginEnd(TCommandBeginEnd(Command)) +
      ';' + LineEnding;
  end else
  if Command is TCommandBreak then begin
    Result := Result + IndentStr + 'Break;' + LineEnding;
  end else
  if Command is TCommandContinue then begin
    Result := Result + IndentStr + 'Continue;' + LineEnding;
  end else
  if Command is TCommandRepeat then begin
    Result := Result + IndentStr + 'repeat' + LineEnding;
    Inc(Indent);
    Result := Result + GenerateCommand(TCommandRepeat(Command).Command);
    Dec(Indent);
    Result := Result + IndentStr + 'until False;' + LineEnding;
  end else
  if Command is TCommandIfEqual then begin
    Result := Result + IndentStr + 'if ' +
      GenerateRef(TCommandIfEqual(Command).Reference1) + ' = ' +
      GenerateRef(TCommandIfEqual(Command).Reference2) + ' then ' + LineEnding;
  end else
  if Command is TCommandIfNotEqual then begin
    Result := Result + IndentStr + 'if ' +
      GenerateRef(TCommandIfNotEqual(Command).Reference1) + ' <> ' +
      GenerateRef(TCommandIfNotEqual(Command).Reference2) + ' then ' + LineEnding;
  end else
  raise Exception.Create('Unsupported instruction');
end;

function TSourceGenerator.GenerateBeginEnd(BeginEnd: TCommandBeginEnd): string;
var
  I: Integer;
begin
  Result := '';
  Result := Result + IndentStr + 'begin' + LineEnding;
  Inc(Indent);
  with BeginEnd do
  for I := 0 to Commands.Count - 1 do begin
    Result := Result + GenerateCommand(TSourceCommand(Commands[I]));
  end;
  Dec(Indent);
  Result := Result + IndentStr + 'end';
end;

function TSourceGenerator.IndentStr: string;
begin
  SetLength(Result, Indent * 2);
  if Indent > 0 then
    FillChar(Result[1], Indent * 2, ' ');
end;


end.