source: branches/CpuSingleSize/Forms/FormCpu.pas

unit FormCpu;

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, StdCtrls,
  ExtCtrls, Cpu;

type

  { TFormCpu }

  TFormCpu = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    LabelTicks: TLabel;
    ListViewMemory: TListView;
    ListViewRegs: TListView;
    Timer1: TTimer;
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormShow(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure ListViewMemoryData(Sender: TObject; Item: TListItem);
    procedure ListViewRegsData(Sender: TObject; Item: TListItem);
  public
    Cpu: TCpu;
  end;

const
  DataPerLine = 16;


implementation

{$R *.lfm}

{ TFormCpu }

procedure TFormCpu.ListViewMemoryData(Sender: TObject; Item: TListItem);
var
  Line: string;
  I: Integer;
begin
  if Item.Index * DataPerLine < Length(Cpu.Memory) then begin
    Item.Caption := IntToHex(Item.Index * DataPerLine, 8);
    Line := '';
    for I := 0 to DataPerLine - 1 do
      Line := Line + IntToHex(Cpu.Memory[Item.Index * DataPerLine + I], 4) + ' ';
    Item.SubItems.Add(Line);
  end;
end;

procedure TFormCpu.ListViewRegsData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < Length(Cpu.R) + 2 then begin
    if Item.Index = 0 then begin
      Item.Caption := 'IP';
      Item.SubItems.Add(IntToHex(Cpu.InstructionPointer, 8));
    end else
    if Item.Index = 1 then begin
      Item.Caption := 'SP';
      Item.SubItems.Add(IntToHex(Cpu.StackPointer, 8));
    end else begin
      Item.Caption := 'R' + IntToStr(Item.Index - 2);
      Item.SubItems.Add(IntToHex(Cpu.R[Item.Index - 2], 8));
    end;
  end;
end;

procedure TFormCpu.Timer1Timer(Sender: TObject);
begin
  ListViewMemory.Items.Count := Length(Cpu.Memory) div DataPerLine;
  ListViewMemory.Refresh;
  ListViewRegs.Items.Count := Length(Cpu.R) + 2;
  ListViewRegs.Refresh;
  LabelTicks.Caption := 'Ticks: ' + IntToStr(Cpu.Ticks);
end;

procedure TFormCpu.FormShow(Sender: TObject);
begin
  Timer1.Enabled := True;
end;

procedure TFormCpu.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  Timer1.Enabled := False;
end;

end.