source: branches/CpuSingleSize/Disassembler.pas

unit Disassembler;

interface

uses
  Classes, SysUtils, Cpu, Instructions, StrUtils, Memory;

type

  { TDisassembler }

  TDisassembler = class
    InstructionSet: TInstructionSet;
    Memory: TMemory;
    procedure Disassemble(Lines: TStrings);
    procedure SaveToFile(FileName: string);
    constructor Create;
    destructor Destroy; override;
  end;


implementation

procedure TDisassembler.Disassemble(Lines: TStrings);
var
  I: Integer;
  J: Integer;
  Value: TInteger;
  Instruction: TInstruction;
  InstructionInfo: TInstructionInfo;
  Line: string;
  InstText: string;
  InstBytes: string;
begin
  Memory.Position := 0;
  while Memory.Position < Memory.Size do begin
    Line := IntToHex(Memory.Position, 8) + ' ';
    Value := Memory.Read;
    InstBytes := IntToHex(Value, 2) + ' ';
    InstText := '';
    if (Value >= 0) and (Value <= Integer(High(TInstruction))) then begin
      Instruction := TInstruction(Value);
      InstructionInfo := InstructionSet.SearchInstruction(Instruction);
      if Assigned(InstructionInfo) then begin
        InstText := InstructionInfo.Name;
        for J := 0 to Length(InstructionInfo.Params) - 1 do begin
          Value := Memory.Read;
          InstBytes := InstBytes + IntToHex(Value, 2) + ' ';
          if J > 0 then
            InstText := InstText + ', ' else
            InstText := InstText + ' ';
          if InstructionInfo.Params[J] = ptNumber then begin
            InstText := InstText + IntToHex(Value, 8);
          end else
          if InstructionInfo.Params[J] = ptReg then begin
            InstText := InstText + 'R' + IntToStr(Value);
          end else
          if InstructionInfo.Params[J] = ptRegIndirect then begin
            InstText := InstText + '(R' + IntToStr(Value) + ')';
          end else
          if InstructionInfo.Params[J] = ptRegIndirectIndex then begin
            InstText := InstText + '(R' + IntToStr(Value);
            Value := Memory.Read;
            InstBytes := InstBytes + IntToHex(Value, 2) + ' ';
            InstText := InstText + ' + ' + IntToStr(Value) + ')';
          end else
          if InstructionInfo.Params[J] = ptRegIndirectGroup then begin
            InstText := InstText + '(R' + IntToStr(Value);
            Value := Memory.Read;
            InstBytes := InstBytes + IntToHex(Value, 2) + ' ';
            InstText := InstText + ': R' + IntToStr(Value) + ')';
          end;
        end;
        InstBytes := InstBytes + DupeString(' ', 13 - Length(InstBytes));
      end;
    end;
    Line := Line + InstBytes + InstText;
    Lines.Add(Line);
  end;
end;

procedure TDisassembler.SaveToFile(FileName: string);
var
  Lines: TStringList;
begin
  Lines := TStringList.Create;
  Disassemble(Lines);
  Lines.SaveToFile(FileName);
  Lines.Free;
end;

constructor TDisassembler.Create;
begin
  InstructionSet := TInstructionSet.Create;
end;

destructor TDisassembler.Destroy;
begin
  FreeAndNil(InstructionSet);
  inherited;
end;


end.