source: trunk/Forms/UFormImportSource.pas

unit UFormImportSource;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ActnList, Menus, ExtCtrls, UAcronym, LCLIntf;

type

  { TFormImportSource }

  TFormImportSource = class(TForm)
    ACategoryAdd: TAction;
    ACategoryRemove: TAction;
    ActionList1: TActionList;
    Bevel1: TBevel;
    Button1: TButton;
    Button2: TButton;
    ButtonShowFormat: TButton;
    ButtonOk: TButton;
    ButtonCancel: TButton;
    ButtonOpenURL: TButton;
    CheckBoxEnabled: TCheckBox;
    ComboBox1: TComboBox;
    EditUserName: TEdit;
    EditName: TEdit;
    EditURL: TEdit;
    EditPassword: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label6: TLabel;
    ListBox1: TListBox;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    PopupMenuCategory: TPopupMenu;
    procedure ACategoryAddExecute(Sender: TObject);
    procedure ACategoryRemoveExecute(Sender: TObject);
    procedure ButtonOpenURLClick(Sender: TObject);
    procedure ButtonShowFormatClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { private declarations }
  public
    procedure UpdateInterface;
    procedure Load(ImportSource: TImportSource);
    procedure Save(ImportSource: TImportSource);
  end;

var
  FormImportSource: TFormImportSource;

implementation

{$R *.lfm}

uses
  UCore, UFormImportFormat, UFormCategorySelect;

{ TFormImportSource }

procedure TFormImportSource.ButtonShowFormatClick(Sender: TObject);
var
  NewImportFormat: TImportFormat;
begin
  if ComboBox1.ItemIndex <> -1 then begin
    NewImportFormat := TImportFormat.Create;
    NewImportFormat.Assign(TImportFormat(ComboBox1.Items.Objects[ComboBox1.ItemIndex]));
    FormImportFormat := TFormImportFormat.Create(Self);
    try
      FormImportFormat.Load(NewImportFormat);
      if FormImportFormat.ShowModal = mrOk then begin
        FormImportFormat.Save(NewImportFormat);
        TImportFormat(ComboBox1.Items.Objects[ComboBox1.ItemIndex]).Assign(NewImportFormat);
        Core.AcronymDb.Modified := True;
        ComboBox1.Items.Strings[ComboBox1.ItemIndex] := NewImportFormat.Name;
      end;
      if Assigned(NewImportFormat) then NewImportFormat.Free;
    finally
      FreeAndNil(FormImportFormat);
    end;
  end;
end;

procedure TFormImportSource.FormClose(Sender: TObject;
  var CloseAction: TCloseAction);
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormImportSource.FormCreate(Sender: TObject);
begin
  Core.Translator.TranslateComponentRecursive(Self);
  Core.ThemeManager.UseTheme(Self);
end;

procedure TFormImportSource.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  UpdateInterface;
end;

procedure TFormImportSource.UpdateInterface;
begin
  ACategoryRemove.Enabled := ListBox1.ItemIndex <> -1;
end;

procedure TFormImportSource.ACategoryAddExecute(Sender: TObject);
var
  I: Integer;
begin
  FormCategorySelect := TFormCategorySelect.Create(Self);
  try
    FormCategorySelect.Load(ListBox1.Items);
    if FormCategorySelect.ShowModal = mrOk then begin
      for I := 0 to FormCategorySelect.ListBox1.Count - 1 do
        if FormCategorySelect.ListBox1.Selected[I] then begin
          ListBox1.Items.AddObject(FormCategorySelect.ListBox1.Items[I], FormCategorySelect.ListBox1.Items.Objects[I]);
        end;
    end;
  finally
    FreeAndNil(FormCategorySelect);
  end;
end;

procedure TFormImportSource.ACategoryRemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if MessageDlg(SRemoveCategory, SRemoveCategoryQuery,
  TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
    for I := ListBox1.Items.Count - 1 downto 0 do
    if ListBox1.Selected[I] then
      ListBox1.Items.Delete(I);
    UpdateInterface;
  end;
end;

procedure TFormImportSource.ButtonOpenURLClick(Sender: TObject);
begin
  OpenURL(EditURL.Text);
end;

procedure TFormImportSource.Load(ImportSource: TImportSource);
var
  I: Integer;
begin
  EditName.Text := ImportSource.Name;
  EditURL.Text := ImportSource.URL;
  while ComboBox1.Items.Count > Core.AcronymDb.ImportFormats.Count do
    ComboBox1.Items.Delete(ComboBox1.Items.Count - 1);
  while ComboBox1.Items.Count < Core.AcronymDb.ImportFormats.Count do
    ComboBox1.Items.Add('');
  for I := 0 to Core.AcronymDb.ImportFormats.Count - 1 do begin
    ComboBox1.Items[I] := TImportFormat(Core.AcronymDb.ImportFormats[I]).Name;
    ComboBox1.Items.Objects[I] := Core.AcronymDb.ImportFormats[I];
  end;
  ComboBox1.ItemIndex := ComboBox1.Items.IndexOfObject(ImportSource.Format);
  if (ComboBox1.ItemIndex = -1) and (ComboBox1.Items.Count > 0) then
    ComboBox1.ItemIndex := 0;
  CheckBoxEnabled.Checked := ImportSource.Enabled;
  ImportSource.Categories.AssignToStrings(ListBox1.Items);
  EditUserName.Text := ImportSource.UserName;
  EditPassword.Text := ImportSource.Password;
end;

procedure TFormImportSource.Save(ImportSource: TImportSource);
begin
  ImportSource.Name := EditName.Text;
  ImportSource.URL := EditURL.Text;
  ImportSource.Format := TImportFormat(ComboBox1.Items.Objects[ComboBox1.ItemIndex]);
  ImportSource.Enabled := CheckBoxEnabled.Checked;
  ImportSource.Categories.AssignFromStrings(ListBox1.Items);
  ImportSource.UserName := EditUserName.Text;
  ImportSource.Password := EditPassword.Text;
end;

end.