source: trunk/Forms/UFormImportFormat.pas

unit UFormImportFormat;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Menus, ActnList, UAcronym;

type

  { TFormImportFormat }

  TFormImportFormat = class(TForm)
    AAdd: TAction;
    AMoveUp: TAction;
    AMoveDown: TAction;
    AModify: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    ButtonOk: TButton;
    ButtonCancel: TButton;
    ComboBoxType: TComboBox;
    EditBlockEnd: TEdit;
    EditBlockStart: TEdit;
    EditName: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label8: TLabel;
    Label9: TLabel;
    ListViewItemRules: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    PopupMenu1: TPopupMenu;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure AMoveDownExecute(Sender: TObject);
    procedure AMoveUpExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewItemRulesData(Sender: TObject; Item: TListItem);
  private
    { private declarations }
  public
    ImportFormat: TImportFormat;
    procedure Load(ImportFormat: TImportFormat);
    procedure Save(ImportFormat: TImportFormat);
    procedure ReloadList;
  end;

var
  FormImportFormat: TFormImportFormat;
  YesNoString: array[Boolean] of string;


implementation

uses
  UCore, UFormImportPattern;

{$R *.lfm}

resourcestring
  SRemoveImportPattern = 'Remove import pattern';
  SRemoveImportPatternQuery = 'Do you really want to remove selected import patterns?';
  SYes = 'Yes';
  SNo = 'No';


{ TFormImportFormat }

procedure TFormImportFormat.AAddExecute(Sender: TObject);
var
  NewImportPattern: TImportPattern;
begin
  FormImportPattern := TFormImportPattern.Create(Self);
  try
    NewImportPattern := TImportPattern.Create;
    FormImportPattern.Load(NewImportPattern);
    if FormImportPattern.ShowModal = mrOk then begin
      FormImportPattern.Save(NewImportPattern);
      ImportFormat.ItemPatterns.Add(NewImportPattern);
      NewImportPattern := nil;
      ReloadList;
    end;
    if Assigned(NewImportPattern) then NewImportPattern.Free;
  finally
    FreeAndNil(FormImportPattern);
  end;
end;

procedure TFormImportFormat.AModifyExecute(Sender: TObject);
var
  NewImportPattern: TImportPattern;
begin
  FormImportPattern := TFormImportPattern.Create(Self);
  try
    if Assigned(ListViewItemRules.Selected) then begin
      NewImportPattern := TImportPattern.Create;
      NewImportPattern.Assign(ListViewItemRules.Selected.Data);
      FormImportPattern.Load(NewImportPattern);
      if FormImportPattern.ShowModal = mrOk then begin
        FormImportPattern.Save(NewImportPattern);
        TImportPattern(ListViewItemRules.Selected.Data).Assign(NewImportPattern);
        ReloadList;
      end;
      if Assigned(NewImportPattern) then NewImportPattern.Free;
    end;
  finally
    FreeAndNil(FormImportPattern);
  end;
end;

procedure TFormImportFormat.AMoveDownExecute(Sender: TObject);
begin
  if ListViewItemRules.Selected.Index < (ImportFormat.ItemPatterns.Count - 1) then
  with ImportFormat do
    ItemPatterns.Exchange(ListViewItemRules.Selected.Index,
      ListViewItemRules.Selected.Index + 1);
  ReloadList;
end;

procedure TFormImportFormat.AMoveUpExecute(Sender: TObject);
begin
  if ListViewItemRules.Selected.Index > 0 then
  with ImportFormat do
    ItemPatterns.Exchange(ListViewItemRules.Selected.Index,
      ListViewItemRules.Selected.Index - 1);
  ReloadList;
end;

procedure TFormImportFormat.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewItemRules.Selected) then begin
    if MessageDlg(SRemoveImportPattern, SRemoveImportPatternQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      for I := ListViewItemRules.Items.Count - 1 downto 0 do
      if ListViewItemRules.Items[I].Selected then
        ImportFormat.ItemPatterns.Remove(ListViewItemRules.Items[I].Data);
      ReloadList;
    end;
  end;
end;

procedure TFormImportFormat.FormClose(Sender: TObject;
  var CloseAction: TCloseAction);
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormImportFormat.FormCreate(Sender: TObject);
begin
  Core.Translator.TranslateComponentRecursive(Self);
  Core.ThemeManager.UseTheme(Self);
  YesNoString[False] := SNo;
  YesNoString[True] := SYes;
end;

procedure TFormImportFormat.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  ReloadList;
end;

procedure TFormImportFormat.ListViewItemRulesData(Sender: TObject;
  Item: TListItem);
begin
  if Item.Index < ImportFormat.ItemPatterns.Count then
  with TImportPattern(ImportFormat.ItemPatterns[Item.Index]) do begin
    Item.Caption := StartString;
    Item.SubItems.Add(EndString);
    Item.SubItems.Add(ImportPatternFlagString[Flag]);
    Item.SubItems.Add(ImportVariableString[Variable]);
    Item.SubItems.Add(YesNoString[Repetition]);
    Item.Data := ImportFormat.ItemPatterns[Item.Index];
  end;
end;

procedure TFormImportFormat.Load(ImportFormat: TImportFormat);
begin
  ComboBoxType.ItemIndex := Integer(ImportFormat.Kind);
  Self.ImportFormat := ImportFormat;
  EditName.Text := ImportFormat.Name;
  EditBlockStart.Text := ImportFormat.Block.StartString;
  EditBlockEnd.Text := ImportFormat.Block.EndString;
  ReloadList;
end;

procedure TFormImportFormat.Save(ImportFormat: TImportFormat);
begin
  ImportFormat.Kind := TImportFormatKind(ComboBoxType.ItemIndex);
  ImportFormat.Name := EditName.Text;
  ImportFormat.Block.StartString := EditBlockStart.Text;
  ImportFormat.Block.EndString := EditBlockEnd.Text;
end;

procedure TFormImportFormat.ReloadList;
begin
  ListViewItemRules.Items.Count := ImportFormat.ItemPatterns.Count;
  ListViewItemRules.Refresh;
end;

end.