source: trunk/Forms/FormExport.pas

unit FormExport;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  JobProgressView, FormEx, Acronym;

type

  { TFormExport }

  TFormExport = class(TFormEx)
    ButtonProcess: TButton;
    ButtonSaveToFile: TButton;
    ComboBoxDataFormat: TComboBox;
    JobProgressView1: TJobProgressView;
    Label1: TLabel;
    Memo1: TMemo;
    SaveDialog1: TSaveDialog;
    procedure ButtonProcessClick(Sender: TObject);
    procedure ButtonSaveToFileClick(Sender: TObject);
  private
    ItemCount: Integer;
    Content: string;
    procedure JobExportCSV(Job: TJob);
    procedure JobExportMediaWiki(Job: TJob);
    procedure JobExportMediaWikiTable(Job: TJob);
  public
    AcronymDb: TAcronymDb;
  end;


implementation

{$R *.lfm}

resourcestring
  SExportedAcronyms = 'Exported %d acronyms';
  SExporting = 'Exporting';

{ TFormExport }

procedure TFormExport.ButtonSaveToFileClick(Sender: TObject);
begin
  if ComboBoxDataFormat.ItemIndex = 0 then SaveDialog1.DefaultExt := '.csv';
  if ComboBoxDataFormat.ItemIndex = 1 then SaveDialog1.DefaultExt := '.txt';
  if ComboBoxDataFormat.ItemIndex = 2 then SaveDialog1.DefaultExt := '.txt';
  if SaveDialog1.Execute then begin
    Memo1.Lines.SaveToFile(SaveDialog1.FileName);
  end;
end;

procedure TFormExport.JobExportCSV(Job: TJob);
var
  I: Integer;
  J: Integer;
begin
  Job.Progress.Max := AcronymDb.Acronyms.Count;
  ItemCount := 0;
  Content := '';
  for I := 0 to AcronymDb.Acronyms.Count - 1 do
  with AcronymDb.Acronyms[I] do begin
    for J := 0 to Meanings.Count - 1 do
    with Meanings[J] do begin
      Content := Content + '"' + Acronym.Name + '","' + Name + '","' + Description + '","' + Categories.GetString + '"' + LineEnding;
      Inc(ItemCount);
    end;
    Job.Progress.Increment;
    if Job.Terminate then Break;
  end;
end;

procedure TFormExport.JobExportMediaWiki(Job: TJob);
var
  I: Integer;
  J: Integer;
begin
  Job.Progress.Max := AcronymDb.Acronyms.Count;
  ItemCount := 0;
  Content := '';
  for I := 0 to AcronymDb.Acronyms.Count - 1 do
  with AcronymDb.Acronyms[I] do begin
    Content := Content + '; ' + Name + LineEnding;
    for J := 0 to Meanings.Count - 1 do
    with Meanings[J] do begin
      Content := Content + ': ' + Name + LineEnding;
      Inc(ItemCount);
    end;
    Job.Progress.Increment;
    if Job.Terminate then Break;
  end;
end;

procedure TFormExport.JobExportMediaWikiTable(Job: TJob);
var
  I: Integer;
  J: Integer;
begin
  Job.Progress.Max := AcronymDb.Acronyms.Count;
  ItemCount := 0;
  Content := '{| class="wikitable sortable"' + LineEnding +
    '! Name !! Meaning !! Description !! Categories' + LineEnding;
  for I := 0 to AcronymDb.Acronyms.Count - 1 do
  with AcronymDb.Acronyms[I] do begin
    for J := 0 to Meanings.Count - 1 do
    with Meanings[J] do begin
      Content := Content + '|-' + LineEnding +
        '| ' + Acronym.Name + LineEnding + '| ' + Name + LineEnding +
        '| ' + Description + LineEnding + '| ' + Categories.GetString + LineEnding;
      Inc(ItemCount);
    end;
    Job.Progress.Increment;
    if Job.Terminate then Break;
  end;
  Content := Content + '|}' + LineEnding;
end;

procedure TFormExport.ButtonProcessClick(Sender: TObject);
begin
  if ComboBoxDataFormat.ItemIndex = 0 then
    JobProgressView1.AddJob(SExporting, JobExportCSV);
  if ComboBoxDataFormat.ItemIndex = 1 then
    JobProgressView1.AddJob(SExporting, JobExportMediaWiki);
  if ComboBoxDataFormat.ItemIndex = 2 then
    JobProgressView1.AddJob(SExporting, JobExportMediaWikiTable);
  JobProgressView1.Start;
  Memo1.Lines.Text := Content;
  ShowMessage(Format(SExportedAcronyms, [ItemCount]));
end;

end.