source: trunk/Forms/FormAcronyms.pas@ 230

unit FormAcronyms;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Menus, ActnList, ListViewSort, Acronym, LazUTF8, Generics.Collections,
  Generics.Defaults, FormEx;

type

  { TFormAcronyms }

  TFormAcronyms = class(TFormEx)
    AAdd: TAction;
    ASelectAll: TAction;
    AModify: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    ListViewAcronyms: TListView;
    ListViewFilter1: TListViewFilter;
    ListViewSort1: TListViewSort;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    MenuItem7: TMenuItem;
    PopupMenuAcronym: TPopupMenu;
    StatusBar1: TStatusBar;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure ASelectAllExecute(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewAcronymsData(Sender: TObject; Item: TListItem);
    procedure ListViewAcronymsDblClick(Sender: TObject);
    procedure ListViewAcronymsKeyPress(Sender: TObject; var Key: char);
    procedure ListViewAcronymsResize(Sender: TObject);
    procedure ListViewAcronymsSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure ListViewFilter1Change(Sender: TObject);
    procedure ListViewSort1ColumnWidthChanged(Sender: TObject);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    FAcronyms: TAcronyms;
    MeaningCount: Integer;
    function CompareStrings(Strings1, Strings2: TStrings): Boolean;
    function AcronymComparer(constref Item1, Item2: TAcronym): Integer;
    procedure FilterList(List: TObjectList<TObject>);
    procedure SetAcronyms(AValue: TAcronyms);
    procedure UpdateAcronymsList;
  public
    AcronymDb: TAcronymDb;
    FocusAcronym: TAcronymMeaning;
    property Acronyms: TAcronyms read FAcronyms write SetAcronyms;
    procedure UpdateInterface;
  end;


implementation

{$R *.lfm}

uses
  FormAcronym;

resourcestring
  SRemoveAcronym = 'Remove acronyms';
  SRemoveAcronymQuery = 'Do you want to remove selected acronyms?';
  STotal = 'Total';
  SFiltered = 'Filtered';


{ TFormAcronyms }

procedure TFormAcronyms.ListViewAcronymsData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ListViewSort1.List.Count then
  with TAcronymMeaning(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Acronym.Name;
    Item.SubItems.Add(Name);
    Item.Data := TAcronymMeaning(ListViewSort1.List[Item.Index]);
    Item.SubItems.Add(Categories.GetString);
  end;
end;

procedure TFormAcronyms.ListViewAcronymsDblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormAcronyms.ListViewAcronymsKeyPress(Sender: TObject; var Key: char
  );
begin
  if Key = #27 then Close;
end;

procedure TFormAcronyms.ListViewAcronymsResize(Sender: TObject);
begin
  ListViewFilter1.UpdateFromListView(ListViewAcronyms);
end;

procedure TFormAcronyms.ListViewAcronymsSelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormAcronyms.FormShow(Sender: TObject);
var
  I: Integer;
begin
  UpdateAcronymsList;
  ScaleDPI.ScaleControl(ToolBar1, ScaleDPI.DesignDPI);

  // Focus line with acronym
  if Assigned(FocusAcronym) then begin
    I := 0;
    while (I < ListViewAcronyms.Items.Count) and (ListViewAcronyms.Items[I].Data <> FocusAcronym) do Inc(I);
    if I < ListViewAcronyms.Items.Count then begin
      ListViewAcronyms.ItemIndex := I;
      ListViewAcronyms.Selected.Focused := True;
    end;
    if ListViewAcronyms.Selected <> nil then
      ListViewAcronyms.Selected.MakeVisible(False);
  end;
end;

function TFormAcronyms.CompareStrings(Strings1, Strings2: TStrings): Boolean;
var
  I: Integer;
begin
  Result := Strings1.Count = Strings2.Count;
  if not Result then Exit;
  for I := 0 to Strings1.Count - 1 do
    if (Strings1[I] <> Strings2[I]) or (Strings1.Objects[I] <> Strings2.Objects[I]) then begin
      Result := False;
      Exit;
    end;
end;

procedure TFormAcronyms.AAddExecute(Sender: TObject);
var
  TempEntry: TAcronymEntry;
  Meaning: TAcronymMeaning;
  I: Integer;
  FormAcronym: TFormAcronym;
begin
  TempEntry := TAcronymEntry.Create;
  TempEntry.Name := '';
  TempEntry.Meaning := '';
  TempEntry.Description := '';
  FormAcronym := TFormAcronym.Create(Self);
  try
    FormAcronym.AcronymDb := AcronymDb;
    FormAcronym.Load(TempEntry);
    if FormAcronym.ShowModal = mrOk then begin
      FormAcronym.Save(TempEntry);
      Meaning := Acronyms.Db.AddAcronym(TempEntry.Name, TempEntry.Meaning);
      Meaning.Description := TempEntry.Description;
      Meaning.Categories.AssignFromStrings(TempEntry.Categories);

      Acronyms.Db.Update;
      UpdateAcronymsList;
      UpdateInterface;
    end;
  finally
    FreeAndNil(FormAcronym);
  end;
  TempEntry.Free;
end;

procedure TFormAcronyms.AModifyExecute(Sender: TObject);
var
  TempEntry: TAcronymEntry;
  TempCategories: TStringList;
  Meaning: TAcronymMeaning;
  I: Integer;
  FormAcronym: TFormAcronym;
begin
  if Assigned(ListViewAcronyms.Selected) then
  with TAcronymMeaning(ListViewAcronyms.Selected.Data) do begin
    TempEntry := TAcronymEntry.Create;
    TempEntry.Name := Acronym.Name;
    TempEntry.Meaning := Name;
    TempEntry.Description := Description;
    Categories.AssignToStrings(TempEntry.Categories);
    Sources.AssignToStrings(TempEntry.Sources);
    TempCategories := TStringList.Create;
    TempCategories.Assign(TempEntry.Categories);
    FormAcronym := TFormAcronym.Create(Self);
    try
      FormAcronym.AcronymDb := AcronymDb;
      FormAcronym.Load(TempEntry);
      if FormAcronym.ShowModal = mrOk then begin
        FormAcronym.Save(TempEntry);
        if (TempEntry.Name <> Acronym.Name) or
        (TempEntry.Meaning <> Name) or
        (TempEntry.Description <> Description) or
        not CompareStrings(TempEntry.Categories, TempCategories) then begin
          // TODO: Update item inplace if possible
          Acronyms.Db.RemoveMeaning(TAcronymMeaning(ListViewAcronyms.Selected.Data));
          Meaning := Acronyms.Db.AddAcronym(TempEntry.Name, TempEntry.Meaning);
          Meaning.Description := TempEntry.Description;
          Meaning.Categories.AssignFromStrings(TempEntry.Categories);

          Acronyms.Db.Update;
          UpdateAcronymsList;
          UpdateInterface;
        end;
      end;
    finally
      FreeAndNil(FormAcronym);
      FreeAndNil(TempEntry);
      FreeAndNil(TempCategories);
    end;
  end;
end;

procedure TFormAcronyms.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewAcronyms.Selected) then begin
    if MessageDlg(SRemoveAcronym, SRemoveAcronymQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      Acronyms.Db.BeginUpdate;
      for I := ListViewAcronyms.Items.Count - 1 downto 0 do
        if ListViewAcronyms.Items[I].Selected then begin
          ListViewAcronyms.Items[I].Selected := False;
          Acronyms.Db.RemoveMeaning(TAcronymMeaning(ListViewAcronyms.Items[I].Data));
        end;
      UpdateAcronymsList;
      UpdateInterface;
      Acronyms.Db.EndUpdate;
    end;
  end;
end;

procedure TFormAcronyms.ASelectAllExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ListViewAcronyms.Items.Count - 1 do
    ListViewAcronyms.Items[I].Selected := True;
end;

procedure TFormAcronyms.FormActivate(Sender: TObject);
begin
  ListViewFilter1.UpdateFromListView(ListViewAcronyms);
end;

procedure TFormAcronyms.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  FocusAcronym := nil;
  MeaningCount := 0;
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

procedure TFormAcronyms.ListViewFilter1Change(Sender: TObject);
begin
  UpdateAcronymsList;
end;

procedure TFormAcronyms.ListViewSort1ColumnWidthChanged(Sender: TObject);
begin
  ListViewFilter1.UpdateFromListView(ListViewAcronyms);
end;

function TFormAcronyms.ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TAcronymMeaning(Item1).Acronym.Name, TAcronymMeaning(Item2).Acronym.Name);
      1: Result := CompareString(TAcronymMeaning(Item1).Name, TAcronymMeaning(Item2).Name);
      2: Result := CompareString(TAcronymMeaning(Item1).Categories.GetString, TAcronymMeaning(Item2).Categories.GetString);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

function TFormAcronyms.AcronymComparer(constref Item1, Item2: TAcronym): Integer;
begin
  Result := CompareStr(TAcronym(Item1).Name, TAcronym(Item2).Name);
end;

procedure TFormAcronyms.ListViewSort1Filter(ListViewSort: TListViewSort);
begin
  Acronyms.Db.Acronyms.Sort(TComparer<TAcronym>.Construct(AcronymComparer));
  Acronyms.Db.AssignToList(ListViewSort1.List);
  MeaningCount := ListViewSort1.List.Count;
  FilterList(ListViewSort1.List);
end;

procedure TFormAcronyms.FilterList(List: TObjectList<TObject>);
var
  I: Integer;
  FoundCount: Integer;
  EnteredCount: Integer;
begin
  EnteredCount := ListViewFilter1.TextEnteredCount;
  for I := List.Count - 1 downto 0 do begin
    if List.Items[I] is TAcronymMeaning then begin
      with TAcronymMeaning(List.Items[I]) do begin
         with ListViewFilter1 do
         if Visible and (EnteredCount > 0) then begin
           FoundCount := 0;
           if Pos(UTF8LowerCase(StringGrid.Cells[0, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Acronym.Name)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[1, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Name)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[2, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Categories.GetString)) > 0 then Inc(FoundCount);
           if FoundCount <> EnteredCount then List.Delete(I);
         end;
      end;
    end else
    if TAcronymMeaning(List.Items[I]) is TAcronymMeaning then begin
      List.Delete(I);
    end;
  end;
end;

procedure TFormAcronyms.SetAcronyms(AValue: TAcronyms);
begin
  if FAcronyms = AValue then Exit;
  FAcronyms := AValue;
end;

procedure TFormAcronyms.UpdateAcronymsList;
begin
  ListViewSort1.Refresh;
  UpdateInterface;
  StatusBar1.Panels[0].Text := STotal + ': ' + IntToStr(MeaningCount);
  StatusBar1.Panels[1].Text := SFiltered + ': ' + IntToStr(ListViewAcronyms.Items.Count);
end;

procedure TFormAcronyms.UpdateInterface;
begin
  ARemove.Enabled := Assigned(FAcronyms) and Assigned(ListViewAcronyms.Selected);
  AModify.Enabled := Assigned(FAcronyms) and Assigned(ListViewAcronyms.Selected);
  AAdd.Enabled := Assigned(FAcronyms);
  ASelectAll.Enabled := True;
end;

end.