source: tags/1.4.0/Forms/UFormImport.pas

unit UFormImport;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  UAcronym;

type

  { TFormImport }

  TFormImport = class(TForm)
    ButtonLoadFromFile: TButton;
    ButtonProcess: TButton;
    ComboBoxDataFormat: TComboBox;
    Label1: TLabel;
    Memo1: TMemo;
    OpenDialog1: TOpenDialog;
    procedure ButtonProcessClick(Sender: TObject);
    procedure ButtonLoadFromFileClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    procedure ImportMediaWiki;
    procedure ImportCSV;
  public
    { public declarations }
  end;

var
  FormImport: TFormImport;

implementation

{$R *.lfm}

uses
  UCore;

resourcestring
  SImportedNewAcronyms = 'Imported %d new acronyms.';


{ TFormImport }

procedure TFormImport.ButtonProcessClick(Sender: TObject);
begin
  if ComboBoxDataFormat.ItemIndex = 0 then ImportCSV;
  if ComboBoxDataFormat.ItemIndex = 1 then ImportMediaWiki;
end;

procedure TFormImport.ButtonLoadFromFileClick(Sender: TObject);
begin
  if ComboBoxDataFormat.ItemIndex = 0 then OpenDialog1.DefaultExt := '.csv';
  if ComboBoxDataFormat.ItemIndex = 1 then OpenDialog1.DefaultExt := '.txt';
  if OpenDialog1.Execute then
    Memo1.Lines.LoadFromFile(OpenDialog1.FileName);
end;

procedure TFormImport.FormCreate(Sender: TObject);
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
end;

procedure TFormImport.ImportMediaWiki;
var
  I: Integer;
  Line: string;
  AcronymName: string;
  AcronymMeaning: string;
  AddedCount: Integer;
  Acronym: TAcronym;
  Meaning: TAcronymMeaning;
begin
  AddedCount := 0;
  for I := 0 to Memo1.Lines.Count - 1 do begin
    Line := Trim(Memo1.Lines[I]);
    if Copy(Line, 1, 1) = ';' then begin
      if Pos(':', Line) > 0 then begin
        AcronymName := Trim(Copy(Line, 2, Pos(':', Line) - 2));
        Line := Copy(Line, Pos(':', Line), Length(Line));
      end else AcronymName := Trim(Copy(Line, 2, Length(Line)));
    end;
    if Copy(Line, 1, 1) = ':' then begin
      AcronymMeaning := Trim(Copy(Line, 2, Length(Line)));
      if (AcronymName <> '') and (AcronymMeaning <> '') then begin
        Acronym := Core.AcronymDb.Acronyms.SearchByName(AcronymName);
        if not Assigned(Acronym) then begin
          Acronym := TAcronym.Create;
          Acronym.Name := AcronymName;
          Core.AcronymDb.Acronyms.Add(Acronym);
        end;
        Meaning := Acronym.Meanings.SearchByName(AcronymMeaning);
        if not Assigned(Meaning) then begin
          Meaning := TAcronymMeaning.Create;
          Meaning.Name := AcronymMeaning;
          Meaning.Acronym := Acronym;
          Acronym.Meanings.Add(Meaning);
          Inc(AddedCount)
        end;
      end;
    end;
  end;
  if AddedCount > 0 then Core.AcronymDb.Modified := True;
  ShowMessage(Format(SImportedNewAcronyms, [AddedCount]));
end;

procedure TFormImport.ImportCSV;
var
  I: Integer;
  Line: string;
  Columns: TStringList;
  Acronym: TAcronym;
  Meaning: TAcronymMeaning;
  AcronymName: string;
  AcronymMeaning: string;
  AcronymDescription: string;
  AddedCount: Integer;
begin
  AddedCount := 0;
  Columns := TStringList.Create;
  Columns.StrictDelimiter := True;
  for I := 0 to Memo1.Lines.Count - 1 do begin
    Line := Trim(Memo1.Lines[I]);
    Columns.DelimitedText := Line;
    if Columns.Count > 0 then AcronymName := Trim(Columns[0])
      else AcronymName := '';
    if Columns.Count > 1 then AcronymMeaning := Trim(Columns[1])
      else AcronymMeaning := '';
    if Columns.Count > 2 then AcronymDescription := Trim(Columns[2])
      else AcronymDescription := '';
    if (AcronymName <> '') and (AcronymDescription <> '') then begin
      Acronym := Core.AcronymDb.Acronyms.SearchByName(AcronymName);
      if not Assigned(Acronym) then begin
        Acronym := TAcronym.Create;
        Acronym.Name := AcronymName;
        Core.AcronymDb.Acronyms.Add(Acronym);
      end;
      Meaning := Acronym.Meanings.SearchByName(AcronymDescription);
      if not Assigned(Meaning) then begin
        Meaning := TAcronymMeaning.Create;
        Meaning.Name := AcronymMeaning;
        Meaning.Description := AcronymDescription;
        Meaning.Acronym := Acronym;
        Acronym.Meanings.Add(Meaning);
        Inc(AddedCount)
      end;
    end;
  end;
  Columns.Free;
  if AddedCount > 0 then Core.AcronymDb.Modified := True;
  ShowMessage(Format(SImportedNewAcronyms, [AddedCount]));
end;

end.