source: tags/1.4.0/Forms/UFormCategories.pas

unit UFormCategories;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UAcronym, UListViewSort;

type

  { TFormCategories }

  TFormCategories = class(TForm)
    AAdd: TAction;
    AEnable: TAction;
    ADisable: TAction;
    ASelectAll: TAction;
    ARemove: TAction;
    AModify: TAction;
    ActionList1: TActionList;
    ListViewCategories: TListView;
    ListViewSort1: TListViewSort;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    MenuItem7: TMenuItem;
    PopupMenuCategory: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure ADisableExecute(Sender: TObject);
    procedure AEnableExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure ASelectAllExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewCategoriesChange(Sender: TObject; Item: TListItem;
      Change: TItemChange);
    procedure ListViewCategoriesData(Sender: TObject; Item: TListItem);
    procedure ListViewCategoriesDblClick(Sender: TObject);
    procedure ListViewCategoriesKeyPress(Sender: TObject; var Key: char);
    procedure ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    { private declarations }
  public
    Categories: TAcronymCategories;
    procedure UpdateList;
    procedure UpdateInterface;
  end;

var
  FormCategories: TFormCategories;

implementation

{$R *.lfm}

uses
  UCore;

resourcestring
  SCategory = 'Category';
  SCategoryQuery = 'Enter name of category';
  SRemoveCategory = 'Remove categories';
  SRemoveCategoryQuery = 'Do you really want to remove selected categories?';
  SCategoryAlreadyExists = 'Category %s already exists!';

{ TFormCategories }

procedure TFormCategories.FormShow(Sender: TObject);
begin
  Core.PersistentForm1.Load(Self);
  UpdateList;
  Core.ScaleDPI1.ScaleControl(ToolBar1, Core.ScaleDPI1.DesignDPI);
end;

procedure TFormCategories.ListViewCategoriesChange(Sender: TObject;
  Item: TListItem; Change: TItemChange);
begin
  if Assigned(Item) and (Change = ctState) then begin
    TAcronymCategory(Item.Data).Enabled := Item.Checked;
    Core.AcronymDb.Modified := True;
  end;
end;

procedure TFormCategories.AAddExecute(Sender: TObject);
var
  S: string;
begin
  S := InputBox(SCategory, SCategoryQuery, '');
  if S <> '' then begin
    if not Assigned(Core.AcronymDb.Categories.SearchByName(S)) then begin;
      TAcronymCategory(Core.AcronymDb.Categories[Core.AcronymDb.Categories.Add(TAcronymCategory.Create)]).Name := S;
      Core.AcronymDb.Modified := True;
      Core.AcronymDb.Update;
      UpdateList;
    end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
  end;
end;

procedure TFormCategories.ADisableExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := ListViewCategories.Items.Count - 1 downto 0 do
  if ListViewCategories.Items[I].Selected then begin
    TAcronymCategory(ListViewCategories.Items[I].Data).Enabled := False;
    Core.AcronymDb.Modified := True;
  end;
  UpdateList;
end;

procedure TFormCategories.AEnableExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := ListViewCategories.Items.Count - 1 downto 0 do
  if ListViewCategories.Items[I].Selected then begin
    TAcronymCategory(ListViewCategories.Items[I].Data).Enabled := True;
    Core.AcronymDb.Modified := True;
  end;
  UpdateList;
end;

procedure TFormCategories.AModifyExecute(Sender: TObject);
var
  S: string;
begin
  if Assigned(ListViewCategories.Selected) then begin
    S := InputBox(SCategory, SCategoryQuery, ListViewCategories.Selected.Caption);
    if S <> ListViewCategories.Selected.Caption then begin
      if not Assigned(Core.AcronymDb.Categories.SearchByName(S)) then begin;
        TAcronymCategory(ListViewCategories.Selected.Data).Name := S;
        Core.AcronymDb.Modified := True;
        Core.AcronymDb.Update;
        UpdateList;
      end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
    end;
  end;
end;

procedure TFormCategories.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewCategories.Selected) then begin
    if MessageDlg(SRemoveCategory, SRemoveCategoryQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      Categories.Db.BeginUpdate;
      for I := ListViewCategories.Items.Count - 1 downto 0 do
      if ListViewCategories.Items[I].Selected then
        Categories.Remove(ListViewCategories.Items[I].Data);
      Categories.Db.EndUpdate;
      UpdateList;
    end;
  end;
end;

procedure TFormCategories.ASelectAllExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ListViewCategories.Items.Count - 1 do
    ListViewCategories.Items[I].Selected := True;
end;

procedure TFormCategories.FormClose(Sender: TObject;
  var CloseAction: TCloseAction);
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormCategories.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

procedure TFormCategories.ListViewCategoriesData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ListViewSort1.List.Count then
  with TAcronymCategory(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ListViewSort1.List[Item.Index];
    Item.SubItems.Add(IntToStr(AcronymMeanings.Count));
    Item.Checked := Enabled;
  end;
end;

procedure TFormCategories.ListViewCategoriesDblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormCategories.ListViewCategoriesKeyPress(Sender: TObject;
  var Key: char);
begin
  if Key = #27 then Close;
end;

procedure TFormCategories.ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

function TFormCategories.ListViewSort1CompareItem(Item1, Item2: TObject
  ): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TAcronymCategory(Item1).Name, TAcronymCategory(Item2).Name);
      1: Result := CompareInteger(TAcronymCategory(Item1).AcronymMeanings.Count, TAcronymCategory(Item2).AcronymMeanings.Count);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormCategories.ListViewSort1Filter(ListViewSort: TListViewSort);
begin
  Core.AcronymDb.Categories.AssignToList(ListViewSort1.List);
end;

procedure TFormCategories.UpdateList;
begin
  ListViewSort1.Refresh;
  ListViewCategories.Items.Count := Core.AcronymDb.Categories.Count;
  ListViewCategories.Refresh;
  UpdateInterface;
end;

procedure TFormCategories.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListViewCategories.Selected);
  AModify.Enabled := Assigned(ListViewCategories.Selected);
end;

end.