source: tags/1.4.0/Forms/UFormAcronyms.pas

unit UFormAcronyms;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Menus, ActnList, UListViewSort, UAcronym, LazUTF8, SpecializedList;

type

  { TFormAcronyms }

  TFormAcronyms = class(TForm)
    AAdd: TAction;
    ASelectAll: TAction;
    AModify: TAction;
    ARemove: TAction;
    ActionList1: TActionList;
    ListViewAcronyms: TListView;
    ListViewFilter1: TListViewFilter;
    ListViewSort1: TListViewSort;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    MenuItem7: TMenuItem;
    PopupMenuAcronym: TPopupMenu;
    StatusBar1: TStatusBar;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure ASelectAllExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewAcronymsData(Sender: TObject; Item: TListItem);
    procedure ListViewAcronymsDblClick(Sender: TObject);
    procedure ListViewAcronymsKeyPress(Sender: TObject; var Key: char);
    procedure ListViewAcronymsResize(Sender: TObject);
    procedure ListViewAcronymsSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure ListViewFilter1Change(Sender: TObject);
    procedure ListViewSort1ColumnWidthChanged(Sender: TObject);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    MeaningCount: Integer;
    procedure FilterList(List: TListObject);
    procedure UpdateAcronymsList;
  public
    FocusAcronym: TAcronymMeaning;
    procedure UpdateInterface;
  end;

var
  FormAcronyms: TFormAcronyms;

implementation

{$R *.lfm}

uses
  UCore, UFormMain, UFormAcronym;

resourcestring
  SRemoveAcronym = 'Remove acronyms';
  SRemoveAcronymQuery = 'Do you want to remove selected acronyms?';
  STotal = 'Total';
  SFiltered = 'Filtered';


{ TFormAcronyms }

procedure TFormAcronyms.ListViewAcronymsData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ListViewSort1.List.Count then
  with TAcronymMeaning(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Acronym.Name;
    Item.SubItems.Add(Name);
    Item.Data := TAcronymMeaning(ListViewSort1.List[Item.Index]);
    Item.SubItems.Add(Categories.GetString);
  end;
end;

procedure TFormAcronyms.ListViewAcronymsDblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormAcronyms.ListViewAcronymsKeyPress(Sender: TObject; var Key: char
  );
begin
  if Key = #27 then Close;
end;

procedure TFormAcronyms.ListViewAcronymsResize(Sender: TObject);
begin
  //ListViewFilter1.UpdateFromListView(ListViewAcronyms);
end;

procedure TFormAcronyms.ListViewAcronymsSelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormAcronyms.FormShow(Sender: TObject);
var
  I: Integer;
begin
  Core.PersistentForm1.Load(Self);
  ListViewFilter1.UpdateFromListView(ListViewAcronyms);
  UpdateAcronymsList;
  Core.ScaleDPI1.ScaleControl(ToolBar1, Core.ScaleDPI1.DesignDPI);

  // Focus line with acronym
  if Assigned(FocusAcronym) then begin
    I := 0;
    while (I < ListViewAcronyms.Items.Count) and (ListViewAcronyms.Items[I].Data <> FocusAcronym) do Inc(I);
    if I < ListViewAcronyms.Items.Count then begin
      ListViewAcronyms.ItemIndex := I;
      ListViewAcronyms.Selected.Focused := True;
    end;
    if ListViewAcronyms.Selected <> nil then
      ListViewAcronyms.Selected.MakeVisible(False);
  end;
end;

procedure TFormAcronyms.AAddExecute(Sender: TObject);
var
  TempEntry: TAcronymEntry;
  Meaning: TAcronymMeaning;
  I: Integer;
begin
  TempEntry := TAcronymEntry.Create;
  TempEntry.Name := '';
  TempEntry.Meaning := '';
  TempEntry.Description := '';
  FormAcronym := TFormAcronym.Create(Self);
  try
    FormAcronym.Load(TempEntry);
    if FormAcronym.ShowModal = mrOk then begin
      FormAcronym.Save(TempEntry);
      Meaning := Core.AcronymDb.AddAcronym(TempEntry.Name, TempEntry.Meaning);
      Meaning.Description := TempEntry.Description;
      Meaning.Categories.AssignFromStrings(TempEntry.Categories);

      // Update reverse references
      for I := 0 to Meaning.Categories.Count - 1 do
        if TAcronymCategory(Meaning.Categories.Items[I]).AcronymMeanings.IndexOf(Meaning) = -1 then
          TAcronymCategory(Meaning.Categories.Items[I]).AcronymMeanings.Add(Meaning);

      Core.AcronymDb.Update;
      UpdateAcronymsList;
      UpdateInterface;
    end;
  finally
    FreeAndNil(FormAcronym);
  end;
  TempEntry.Free;
end;

procedure TFormAcronyms.AModifyExecute(Sender: TObject);
var
  TempEntry: TAcronymEntry;
  TempCategories: TStringList;
  Meaning: TAcronymMeaning;
  I: Integer;
begin
  if Assigned(ListViewAcronyms.Selected) then
  with TAcronymMeaning(ListViewAcronyms.Selected.Data) do begin
    TempEntry := TAcronymEntry.Create;
    TempEntry.Name := Acronym.Name;
    TempEntry.Meaning := Name;
    TempEntry.Description := Description;
    Categories.AssignToStrings(TempEntry.Categories);
    Sources.AssignToStrings(TempEntry.Sources);
    TempCategories := TStringList.Create;
    TempCategories.Assign(TempEntry.Categories);
    FormAcronym := TFormAcronym.Create(Self);
    try
      FormAcronym.Load(TempEntry);
      if FormAcronym.ShowModal = mrOk then begin
        FormAcronym.Save(TempEntry);
        if (TempEntry.Name <> Acronym.Name) or
        (TempEntry.Meaning <> Name) or
        (TempEntry.Description <> Description) or
        not FormMain.CompareStrings(TempEntry.Categories, TempCategories) then begin
          // TODO: Update item inplace if possible
          Core.AcronymDb.RemoveMeaning(TAcronymMeaning(ListViewAcronyms.Selected.Data));
          Meaning := Core.AcronymDb.AddAcronym(TempEntry.Name, TempEntry.Meaning);
          Meaning.Description := TempEntry.Description;
          Meaning.Categories.AssignFromStrings(TempEntry.Categories);

          // Update reverse references
          for I := 0 to Meaning.Categories.Count - 1 do
            if TAcronymCategory(Meaning.Categories.Items[I]).AcronymMeanings.IndexOf(Meaning) = -1 then
              TAcronymCategory(Meaning.Categories.Items[I]).AcronymMeanings.Add(Meaning);
          Core.AcronymDb.Update;
          UpdateAcronymsList;
          UpdateInterface;
        end;
      end;
    finally
      FreeAndNil(FormAcronym);
      FreeAndNil(TempEntry);
      FreeAndNil(TempCategories);
    end;
  end;
end;

procedure TFormAcronyms.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewAcronyms.Selected) then begin
    if MessageDlg(SRemoveAcronym, SRemoveAcronymQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      Core.AcronymDb.BeginUpdate;
      for I := ListViewAcronyms.Items.Count - 1 downto 0 do
        if ListViewAcronyms.Items[I].Selected then begin
          ListViewAcronyms.Items[I].Selected := False;
          Core.AcronymDb.RemoveMeaning(TAcronymMeaning(ListViewAcronyms.Items[I].Data));
        end;
      UpdateAcronymsList;
      UpdateInterface;
      Core.AcronymDb.EndUpdate;
    end;
  end;
end;

procedure TFormAcronyms.ASelectAllExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ListViewAcronyms.Items.Count - 1 do
    ListViewAcronyms.Items[I].Selected := True;
end;

procedure TFormAcronyms.FormClose(Sender: TObject; var CloseAction: TCloseAction
  );
begin
  Core.PersistentForm1.Save(Self);
end;

procedure TFormAcronyms.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  FocusAcronym := nil;
  MeaningCount := 0;
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

procedure TFormAcronyms.ListViewFilter1Change(Sender: TObject);
begin
  UpdateAcronymsList;
end;

procedure TFormAcronyms.ListViewSort1ColumnWidthChanged(Sender: TObject);
begin
  ListViewFilter1.UpdateFromListView(ListViewAcronyms);
end;

function TFormAcronyms.ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TAcronymMeaning(Item1).Acronym.Name, TAcronymMeaning(Item2).Acronym.Name);
      1: Result := CompareString(TAcronymMeaning(Item1).Name, TAcronymMeaning(Item2).Name);
      2: Result := CompareString(TAcronymMeaning(Item1).Categories.GetString, TAcronymMeaning(Item2).Categories.GetString);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormAcronyms.ListViewSort1Filter(ListViewSort: TListViewSort);
begin
  Core.AcronymDb.Acronyms.Sort(AcronymComparer);
  Core.AcronymDb.AssignToList(ListViewSort1.List);
  MeaningCount := ListViewSort1.List.Count;
  FilterList(ListViewSort1.List);
end;

procedure TFormAcronyms.FilterList(List: TListObject);
var
  I: Integer;
  FoundCount: Integer;
  EnteredCount: Integer;
begin
  EnteredCount := ListViewFilter1.TextEnteredCount;
  for I := List.Count - 1 downto 0 do begin
    if List.Items[I] is TAcronymMeaning then begin
      with TAcronymMeaning(List.Items[I]) do begin
         with ListViewFilter1 do
         if Visible and (EnteredCount > 0) then begin
           FoundCount := 0;
           if Pos(UTF8LowerCase(StringGrid.Cells[0, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Acronym.Name)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[1, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Name)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[2, 0]),
             UTF8LowerCase(TAcronymMeaning(List.Items[I]).Categories.GetString)) > 0 then Inc(FoundCount);
           if FoundCount <> EnteredCount then List.Delete(I);
         end;
      end;
    end else
    if TAcronymMeaning(List.Items[I]) is TAcronymMeaning then begin
      List.Delete(I);
    end;
  end;
end;

procedure TFormAcronyms.UpdateAcronymsList;
begin
  ListViewSort1.Refresh;
  UpdateInterface;
  StatusBar1.Panels[0].Text := STotal + ': ' + IntToStr(MeaningCount);
  StatusBar1.Panels[1].Text := SFiltered + ': ' + IntToStr(ListViewAcronyms.Items.Count);
end;

procedure TFormAcronyms.UpdateInterface;
begin
  ARemove.Enabled := Assigned(Core.AcronymDb) and Assigned(ListViewAcronyms.Selected);
  AModify.Enabled := Assigned(Core.AcronymDb) and Assigned(ListViewAcronyms.Selected);
  AAdd.Enabled := Assigned(Core.AcronymDb);
  ASelectAll.Enabled := True;
end;

end.