source: tags/1.3.1/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, UAcronym, UCoolTranslator, UPersistentForm,
  UJobProgressView, UScaleDPI, Forms, Controls, ExtCtrls, Menus, LazFileUtils,
  URegistry, Registry;

type

  { TCore }

  TCore = class(TDataModule)
    CoolTranslator1: TCoolTranslator;
    ImageList1: TImageList;
    ImageListLarge: TImageList;
    JobProgressView1: TJobProgressView;
    MenuItem1: TMenuItem;
    MenuItem19: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem26: TMenuItem;
    MenuItem27: TMenuItem;
    MenuItem28: TMenuItem;
    MenuItem3: TMenuItem;
    PersistentForm1: TPersistentForm;
    PopupMenuTrayIcon: TPopupMenu;
    ScaleDPI1: TScaleDPI;
    TrayIcon1: TTrayIcon;
    procedure CoolTranslator1Translate(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure TrayIcon1Click(Sender: TObject);
  private
    FAlwaysOnTop: Boolean;
    StoredDimension: TControlDimension;
    procedure SetAlwaysOnTop(AValue: Boolean);
    function FindFirstNonOption: string;
  public
    AcronymDb: TAcronymDb;
    StartOnLogon: Boolean;
    StartMinimizedToTray: Boolean;
    InitializeStarted: Boolean;
    InitializeFinished: Boolean;
    procedure Initialize;
    procedure LoadConfig;
    procedure SaveConfig;
    procedure ScaleDPI;
    property AlwaysOnTop: Boolean read FAlwaysOnTop write SetAlwaysOnTop;
  end;

var
  Core: TCore;

const
  DefaultRegKey = '\Software\Chronosoft\Acronym Decoder';


implementation

uses
  UFormMain;

const
  ExampleFile = 'Example acronyms.adp';


{$R *.lfm}

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  AcronymDb := TAcronymDb.Create;
  InitializeStarted := False;
  InitializeFinished := False;
  StoredDimension := TControlDimension.Create;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(StoredDimension);
  FreeAndNil(AcronymDb);
end;

procedure TCore.TrayIcon1Click(Sender: TObject);
begin
  if not FormMain.Visible then FormMain.AShow.Execute
    else FormMain.Hide;
end;

procedure TCore.CoolTranslator1Translate(Sender: TObject);
begin
  UAcronym.Translate;
end;

procedure TCore.SetAlwaysOnTop(AValue: Boolean);
begin
  if FAlwaysOnTop = AValue then Exit;
  FAlwaysOnTop := AValue;
  if FAlwaysOnTop then FormMain.FormStyle := fsSystemStayOnTop
    else FormMain.FormStyle := fsNormal;
end;

procedure TCore.Initialize;
var
  FileNameOption: string;
begin
  if not InitializeStarted then begin
    InitializeStarted := True;
    LoadConfig;

    {$IFDEF 0}
    if Application.HasOption('h', 'help') then begin
      WriteLn('AcronymDecoder <project file>');
      WriteLn('  -t    --tray   Start minimized in system tray');
      WriteLn('  -h    --help  Show this help');
      Application.Terminate;
      Exit;
    end;
    {$ENDIF}

    if Application.HasOption('t', 'tray') then begin
      FormMain.Visible := False;
    end;

    FileNameOption := FindFirstNonOption;
    if FileNameOption <> '' then begin
      // Open file specified as command line parameter
      AcronymDB.LoadFromFile(FileNameOption);
      FormMain.LastOpenedList1.AddItem(FileNameOption);
    end else
    if (FormMain.LastOpenedList1.Items.Count > 0) and FileExists(FormMain.LastOpenedList1.Items[0]) then begin
      // Open last opened file
      AcronymDB.LoadFromFile(FormMain.LastOpenedList1.Items[0])
    end else begin
      // Open default database with examples if no item is in recent openned history
      FileNameOption := ExtractFileDir(Application.ExeName) + DirectorySeparator + ExampleFile;
      {$IFDEF Linux}
      // If installed in Linux system then use installation directory for po files
      if Application.ExeName = '/usr/bin/' + ExtractFileNameOnly(Application.ExeName) then
        FileNameOption := '/usr/share/' + ExtractFileNameOnly(Application.ExeName) + '/Examples/' + ExampleFile;
      {$ENDIF}
      FormMain.ProjectOpen(FileNameOption);
    end;

    //ImageList1.Assign(ImageListLarge);

    ScaleDPI;
    FormMain.UpdateAcronymsList;
    FormMain.ListViewFilter1.UpdateFromListView(FormMain.ListViewAcronyms);
    InitializeFinished := True;
  end;
end;

procedure TCore.LoadConfig;
begin
  FormMain.LoadConfig;

  with TRegistryEx.Create do
  try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(DefaultRegKey, True);
    ScaleDPI1.DPI := Point(ReadIntegerWithDefault('DPIX', 96), ReadIntegerWithDefault('DPIY', 96));
    ScaleDPI1.AutoDetect := ReadBoolWithDefault('DPIAuto', True);
  finally
    Free;
  end;
end;

procedure TCore.SaveConfig;
begin
  FormMain.SaveConfig;

  with TRegistryEx.Create do
  try
    RootKey := HKEY_CURRENT_USER;
    OpenKey(DefaultRegKey, True);
    WriteInteger('DPIX', ScaleDPI1.DPI.X);
    WriteInteger('DPIY', ScaleDPI1.DPI.Y);
    WriteBool('DPIAuto', ScaleDPI1.AutoDetect);
  finally
    Free;
  end;
end;

procedure TCore.ScaleDPI;
begin
  // TODO: Transparent image scaling not working properly under linux Gtk2
  // Also screen DPI is not correctly detected under linux Gtk2
  {$IFDEF WINDOWS}
  Core.ScaleDPI1.ScaleImageList(ImageList1, Core.ScaleDPI1.DesignDPI);
  Core.ScaleDPI1.ScaleControl(FormMain.ToolBar1, Core.ScaleDPI1.DesignDPI);
  {$ENDIF}
end;

function TCore.FindFirstNonOption: string;
var
  S: string;
  I: Integer;
begin
  Result := '';
  for I := 1 to Application.ParamCount do begin
    S := Application.Params[I];
    if S[1] = Application.OptionChar then Continue;
    Result := S;
    Break;
  end;
end;



end.