source: tags/1.3.1/Forms/UFormCategories.pas

unit UFormCategories;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UAcronym;

type

  { TFormCategories }

  TFormCategories = class(TForm)
    AAdd: TAction;
    ASelectAll: TAction;
    ARemove: TAction;
    AModify: TAction;
    ActionList1: TActionList;
    ListViewCategories: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    PopupMenuCategory: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure ASelectAllExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewCategoriesData(Sender: TObject; Item: TListItem);
    procedure ListViewCategoriesDblClick(Sender: TObject);
    procedure ListViewCategoriesKeyPress(Sender: TObject; var Key: char);
    procedure ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  private
    { private declarations }
  public
    Categories: TAcronymCategories;
    procedure UpdateList;
    procedure UpdateInterface;
  end;

var
  FormCategories: TFormCategories;

implementation

{$R *.lfm}

uses
  UCore;

resourcestring
  SCategory = 'Category';
  SCategoryQuery = 'Enter name of category';
  SRemoveCategory = 'Remove categories';
  SRemoveCategoryQuery = 'Do you really want to remove selected categories?';
  SCategoryAlreadyExists = 'Category %s already exists!';

{ TFormCategories }

procedure TFormCategories.FormShow(Sender: TObject);
begin
  UpdateList;
  Core.ScaleDPI1.ScaleControl(ToolBar1, Core.ScaleDPI1.DesignDPI);
end;

procedure TFormCategories.AAddExecute(Sender: TObject);
var
  S: string;
begin
  S := InputBox(SCategory, SCategoryQuery, '');
  if S <> '' then begin
    if not Assigned(Core.AcronymDb.Categories.SearchByName(S)) then begin;
      TAcronymCategory(Core.AcronymDb.Categories[Core.AcronymDb.Categories.Add(TAcronymCategory.Create)]).Name := S;
      Core.AcronymDb.Modified := True;
      UpdateList;
    end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
  end;
end;

procedure TFormCategories.AModifyExecute(Sender: TObject);
var
  S: string;
begin
  if Assigned(ListViewCategories.Selected) then begin
    S := InputBox(SCategory, SCategoryQuery, ListViewCategories.Selected.Caption);
    if S <> ListViewCategories.Selected.Caption then begin
      if not Assigned(Core.AcronymDb.Categories.SearchByName(S)) then begin;
        TAcronymCategory(ListViewCategories.Selected.Data).Name := S;
        Core.AcronymDb.Modified := True;
        UpdateList;
      end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
    end;
  end;
end;

procedure TFormCategories.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewCategories.Selected) then begin
    if MessageDlg(SRemoveCategory, SRemoveCategoryQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      for I := ListViewCategories.Items.Count - 1 downto 0 do
      if ListViewCategories.Items[I].Selected then
        Categories.Remove(ListViewCategories.Items[I].Data);
      UpdateList;
    end;
  end;
end;

procedure TFormCategories.ASelectAllExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ListViewCategories.Items.Count - 1 do
    ListViewCategories.Items[I].Selected := True;
end;

procedure TFormCategories.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  Core.CoolTranslator1.TranslateComponentRecursive(Self);
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

procedure TFormCategories.ListViewCategoriesData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < Core.AcronymDb.Categories.Count then
  with TAcronymCategory(Core.AcronymDb.Categories[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := Core.AcronymDb.Categories[Item.Index];
    Item.SubItems.Add(IntToStr(AcronymMeanings.Count));
  end;
end;

procedure TFormCategories.ListViewCategoriesDblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormCategories.ListViewCategoriesKeyPress(Sender: TObject;
  var Key: char);
begin
  if Key = #27 then Close;
end;

procedure TFormCategories.ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormCategories.UpdateList;
begin
  ListViewCategories.Items.Count := Core.AcronymDb.Categories.Count;
  ListViewCategories.Refresh;
  UpdateInterface;
end;

procedure TFormCategories.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListViewCategories.Selected);
  AModify.Enabled := Assigned(ListViewCategories.Selected);
end;

end.