source: tags/1.2.0/Forms/UFormImportSources.pas

unit UFormImportSources;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UAcronym, UJobProgressView, UListViewSort, SpecializedList,
  LazUTF8;

type

  { TFormImportSources }

  TFormImportSources = class(TForm)
    AAdd: TAction;
    AEnable: TAction;
    ADisable: TAction;
    AProcess: TAction;
    ActionList1: TActionList;
    AModify: TAction;
    ARemove: TAction;
    JobProgressView1: TJobProgressView;
    ListView1: TListView;
    ListViewFilter1: TListViewFilter;
    ListViewSort1: TListViewSort;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    PopupMenuImportSource: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure ADisableExecute(Sender: TObject);
    procedure AEnableExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure AProcessExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Change(Sender: TObject; Item: TListItem;
      Change: TItemChange);
    procedure ListView1Click(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1Resize(Sender: TObject);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure ListViewFilter1Change(Sender: TObject);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    procedure ProcessImportJob(Job: TJob);
    procedure FilterList(List: TListObject);
  public
    ImportSources: TImportSources;
    procedure UpdateList;
    procedure UpdateInterface;
  end;

var
  FormImportSources: TFormImportSources;

implementation

{$R *.lfm}

uses
  UFormMain, UFormImportSource;

resourcestring
  SRemoveImportSource = 'Remove import sources';
  SRemoveImportSourceQuery = 'Do you really want to remove selected import sources?';
  SImportSourceAlreadyExists = 'Import source %s already exists!';
  SProcessSelectedSource = 'Process selected import source';


{ TFormImportSources }

procedure TFormImportSources.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ListViewSort1.List.Count then
  with TImportSource(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ListViewSort1.List[Item.Index];
    Item.SubItems.Add(URL);
    Item.SubItems.Add(Categories.GetString);
    Item.SubItems.Add(IntToStr(ItemCount));
    if LastImportTime <> 0 then
      Item.SubItems.Add(DateToStr(LastImportTime))
      else Item.SubItems.Add('');
    Item.Checked := Enabled;
  end;
end;

procedure TFormImportSources.ListView1DblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormImportSources.ListView1Resize(Sender: TObject);
begin
  ListViewFilter1.UpdateFromListView(ListView1);
end;

procedure TFormImportSources.ListView1SelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormImportSources.ListViewFilter1Change(Sender: TObject);
begin
  UpdateList;
end;

function TFormImportSources.ListViewSort1CompareItem(Item1, Item2: TObject
  ): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TImportSource(Item1).Name, TImportSource(Item2).Name);
      1: Result := CompareString(TImportSource(Item1).URL, TImportSource(Item2).URL);
      2: Result := CompareString(TImportSource(Item1).Categories.GetString, TImportSource(Item2).Categories.GetString);
      3: Result := CompareInteger(TImportSource(Item1).ItemCount, TImportSource(Item2).ItemCount);
      4: Result := CompareTime(TImportSource(Item1).LastImportTime, TImportSource(Item2).LastImportTime);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormImportSources.ListViewSort1Filter(ListViewSort: TListViewSort);
begin
  ImportSources.AssignToList(ListViewSort1.List);
  FilterList(ListViewSort1.List);
end;

procedure TFormImportSources.UpdateList;
begin
  ListViewSort1.Refresh;
  UpdateInterface;
end;

procedure TFormImportSources.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListView1.Selected);
  AModify.Enabled := Assigned(ListView1.Selected);
end;

procedure TFormImportSources.FormShow(Sender: TObject);
begin
  UpdateList;
end;

procedure TFormImportSources.ListView1Change(Sender: TObject; Item: TListItem;
  Change: TItemChange);
begin
  if Assigned(Item) and (Change = ctState) then begin
    TImportSource(Item.Data).Enabled := Item.Checked;
  end;
end;

procedure TFormImportSources.ListView1Click(Sender: TObject);
begin

end;

procedure TFormImportSources.AAddExecute(Sender: TObject);
var
  NewImportSource: TImportSource;
begin
  NewImportSource := TImportSource.Create;
  NewImportSource.Sources := ImportSources;
  FormImportSource.Load(NewImportSource);
  if FormImportSource.ShowModal = mrOk then begin
    FormImportSource.Save(NewImportSource);
    if not Assigned(ImportSources.SearchByName(NewImportSource.Name)) then begin;
      ImportSources.Add(NewImportSource);
      NewImportSource := nil;
      FormMain.AcronymDb.Modified := True;
      UpdateList;
    end else ShowMessage(Format(SImportSourceAlreadyExists, [NewImportSource.Name]));
  end;
  if Assigned(NewImportSource) then NewImportSource.Free;
end;

procedure TFormImportSources.ADisableExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := ListView1.Items.Count - 1 downto 0 do
  if ListView1.Items[I].Selected then
    TImportSource(ListView1.Items[I].Data).Enabled := False;
  UpdateList;
end;

procedure TFormImportSources.AEnableExecute(Sender: TObject);
var
  I: Integer;
begin
  for I := ListView1.Items.Count - 1 downto 0 do
  if ListView1.Items[I].Selected then
    TImportSource(ListView1.Items[I].Data).Enabled := True;
  UpdateList;
end;

procedure TFormImportSources.AModifyExecute(Sender: TObject);
var
  NewImportSource: TImportSource;
begin
  if Assigned(ListView1.Selected) then begin
    NewImportSource := TImportSource.Create;
    NewImportSource.Assign(ListView1.Selected.Data);
    FormImportSource.Load(NewImportSource);
    if FormImportSource.ShowModal = mrOk then begin
      FormImportSource.Save(NewImportSource);
      if (NewImportSource.Name <> TImportSource(ListView1.Selected.Data).Name) then begin
        if not Assigned(ImportSources.SearchByName(NewImportSource.Name)) then begin;
          TImportSource(ListView1.Selected.Data).Assign(NewImportSource);
          FormMain.AcronymDb.Modified := True;
          UpdateList;
        end else ShowMessage(Format(SImportSourceAlreadyExists, [NewImportSource.Name]));
      end else begin
        TImportSource(ListView1.Selected.Data).Assign(NewImportSource);
        FormMain.AcronymDb.Modified := True;
        UpdateList;
      end;
    end;
    if Assigned(NewImportSource) then NewImportSource.Free;
  end;
end;

procedure TFormImportSources.AProcessExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    FormMain.AcronymDb.AddedCount := 0;
    JobProgressView1.AddJob(SProcessSelectedSource, ProcessImportJob);
    JobProgressView1.Start;
    ShowMessage(Format(SAddedCount, [TImportSource(ListView1.Selected.Data).ItemCount, FormMain.AcronymDb.AddedCount]));
  end;
end;

procedure TFormImportSources.ProcessImportJob(Job: TJob);
begin
  TImportSource(ListView1.Selected.Data).Process;
end;

procedure TFormImportSources.FilterList(List: TListObject);
var
  I: Integer;
  FoundCount: Integer;
  EnteredCount: Integer;
begin
  EnteredCount := ListViewFilter1.TextEnteredCount;
  for I := List.Count - 1 downto 0 do begin
    if List.Items[I] is TImportSource then begin
      with TImportSource(List.Items[I]) do begin
         with ListViewFilter1 do
         if Visible and (EnteredCount > 0) then begin
           FoundCount := 0;
           if Pos(UTF8LowerCase(StringGrid.Cells[0, 0]),
             UTF8LowerCase(TImportSource(List.Items[I]).Name)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[1, 0]),
             UTF8LowerCase(TImportSource(List.Items[I]).URL)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[2, 0]),
             UTF8LowerCase(TImportSource(List.Items[I]).Categories.GetString)) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[3, 0]),
             UTF8LowerCase(IntToStr(TImportSource(List.Items[I]).ItemCount))) > 0 then Inc(FoundCount);
           if Pos(UTF8LowerCase(StringGrid.Cells[4, 0]),
             UTF8LowerCase(DateTimeToStr(TImportSource(List.Items[I]).LastImportTime))) > 0 then Inc(FoundCount);
           if FoundCount <> EnteredCount then List.Delete(I);
         end;
      end;
    end else
    if TImportSource(List.Items[I]) is TImportSource then begin
      List.Delete(I);
    end;
  end;
end;

procedure TFormImportSources.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListView1.Selected) then begin
    if MessageDlg(SRemoveImportSource, SRemoveImportSourceQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      for I := ListView1.Items.Count - 1 downto 0 do
      if ListView1.Items[I].Selected then
        ImportSources.Remove(ListView1.Items[I].Data);
      UpdateList;
    end;
  end;
end;

procedure TFormImportSources.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

end.