source: tags/1.1.0/Forms/UFormImportSources.pas

unit UFormImportSources;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, UAcronym, UJobProgressView;

type

  { TFormImportSources }

  TFormImportSources = class(TForm)
    AAdd: TAction;
    AProcess: TAction;
    ActionList1: TActionList;
    AModify: TAction;
    ARemove: TAction;
    JobProgressView1: TJobProgressView;
    ListView1: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    PopupMenuImportSource: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure AProcessExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  private
    procedure ProcessImportJob(Job: TJob);
    { private declarations }
  public
    ImportSources: TImportSources;
    procedure UpdateList;
    procedure UpdateInterface;
  end;

var
  FormImportSources: TFormImportSources;

implementation

{$R *.lfm}

uses
  UFormMain, UFormImportSource;

resourcestring
  SRemoveImportSource = 'Remove import sources';
  SRemoveImportSourceQuery = 'Do you really want to remove selected import sources?';
  SImportSourceAlreadyExists = 'Import source %s already exists!';
  SProcessSelectedSource = 'Process selected import source';


{ TFormImportSources }

procedure TFormImportSources.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ImportSources.Count then
  with TImportSource(ImportSources[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ImportSources[Item.Index];
    Item.SubItems.Add(URL);
    Item.SubItems.Add(Categories.GetString);
    Item.SubItems.Add(IntToStr(ItemCount));
    if LastImportTime <> 0 then
      Item.SubItems.Add(DateToStr(LastImportTime))
      else Item.SubItems.Add('');
    Item.Checked := Enabled;
  end;
end;

procedure TFormImportSources.ListView1DblClick(Sender: TObject);
begin
  AModify.Execute;
end;

procedure TFormImportSources.ListView1SelectItem(Sender: TObject;
  Item: TListItem; Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormImportSources.UpdateList;
begin
  ListView1.Items.Count := ImportSources.Count;
  ListView1.Refresh;
  UpdateInterface;
end;

procedure TFormImportSources.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListView1.Selected);
  AModify.Enabled := Assigned(ListView1.Selected);
end;

procedure TFormImportSources.FormShow(Sender: TObject);
begin
  UpdateList;
end;

procedure TFormImportSources.AAddExecute(Sender: TObject);
var
  NewImportSource: TImportSource;
begin
  NewImportSource := TImportSource.Create;
  NewImportSource.Sources := ImportSources;
  FormImportSource.Load(NewImportSource);
  if FormImportSource.ShowModal = mrOk then begin
    FormImportSource.Save(NewImportSource);
    if not Assigned(ImportSources.SearchByName(NewImportSource.Name)) then begin;
      ImportSources.Add(NewImportSource);
      NewImportSource := nil;
      FormMain.AcronymDb.Modified := True;
      UpdateList;
    end else ShowMessage(Format(SImportSourceAlreadyExists, [NewImportSource.Name]));
  end;
  if Assigned(NewImportSource) then NewImportSource.Free;
end;

procedure TFormImportSources.AModifyExecute(Sender: TObject);
var
  NewImportSource: TImportSource;
begin
  if Assigned(ListView1.Selected) then begin
    NewImportSource := TImportSource.Create;
    NewImportSource.Assign(ListView1.Selected.Data);
    FormImportSource.Load(NewImportSource);
    if FormImportSource.ShowModal = mrOk then begin
      FormImportSource.Save(NewImportSource);
      if (NewImportSource.Name <> TImportSource(ListView1.Selected.Data).Name) then begin
        if not Assigned(ImportSources.SearchByName(NewImportSource.Name)) then begin;
          TImportSource(ListView1.Selected.Data).Assign(NewImportSource);
          FormMain.AcronymDb.Modified := True;
          UpdateList;
        end else ShowMessage(Format(SImportSourceAlreadyExists, [NewImportSource.Name]));
      end else begin
        TImportSource(ListView1.Selected.Data).Assign(NewImportSource);
        FormMain.AcronymDb.Modified := True;
        UpdateList;
      end;
    end;
    if Assigned(NewImportSource) then NewImportSource.Free;
  end;
end;

procedure TFormImportSources.AProcessExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    FormMain.AcronymDb.AddedCount := 0;
    JobProgressView1.AddJob(SProcessSelectedSource, ProcessImportJob);
    JobProgressView1.Start;
    ShowMessage(Format(SAddedCount, [TImportSource(ListView1.Selected.Data).ItemCount, FormMain.AcronymDb.AddedCount]));
  end;
end;

procedure TFormImportSources.ProcessImportJob(Job: TJob);
begin
  TImportSource(ListView1.Selected.Data).Process;
end;

procedure TFormImportSources.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListView1.Selected) then begin
    if MessageDlg(SRemoveImportSource, SRemoveImportSourceQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      for I := ListView1.Items.Count - 1 downto 0 do
      if ListView1.Items[I].Selected then
        ImportSources.Remove(ListView1.Items[I].Data);
      UpdateList;
    end;
  end;
end;

procedure TFormImportSources.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to ToolBar1.ButtonCount - 1 do
    ToolBar1.Buttons[I].Hint := ToolBar1.Buttons[I].Caption;
end;

end.