source: tags/1.0.0/Forms/UFormCategories.pas

unit UFormCategories;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  StdCtrls, ActnList, Menus, UAcronym;

type

  { TFormCategories }

  TFormCategories = class(TForm)
    AAdd: TAction;
    ARemove: TAction;
    AModify: TAction;
    ActionList1: TActionList;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    ListViewCategories: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    PopupMenuCategory: TPopupMenu;
    procedure AAddExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure ARemoveExecute(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListViewCategoriesData(Sender: TObject; Item: TListItem);
    procedure ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  private
    { private declarations }
  public
    Categories: TAcronymCategories;
    procedure UpdateList;
    procedure UpdateInterface;
  end;

var
  FormCategories: TFormCategories;

implementation

{$R *.lfm}

uses
  UFormMain;

resourcestring
  SCategory = 'Category';
  SCategoryQuery = 'Enter name of category';
  SRemoveCategory = 'Remove categories';
  SRemoveCategoryQuery = 'Do you really want to remove selected categories?';
  SCategoryAlreadyExists = 'Category %s already exists!';

{ TFormCategories }

procedure TFormCategories.FormShow(Sender: TObject);
begin
  UpdateList;
end;

procedure TFormCategories.AAddExecute(Sender: TObject);
var
  S: string;
begin
  S := InputBox(SCategory, SCategoryQuery, '');
  if S <> '' then begin
    if not Assigned(FormMain.AcronymDb.Categories.SearchByName(S)) then begin;
      TAcronymCategory(FormMain.AcronymDb.Categories[FormMain.AcronymDb.Categories.Add(TAcronymCategory.Create)]).Name := S;
      FormMain.AcronymDb.Modified := True;
      UpdateList;
    end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
  end;
end;

procedure TFormCategories.AModifyExecute(Sender: TObject);
var
  S: string;
begin
  if Assigned(ListViewCategories.Selected) then begin
    S := InputBox(SCategory, SCategoryQuery, ListViewCategories.Selected.Caption);
    if S <> ListViewCategories.Selected.Caption then begin
      if not Assigned(FormMain.AcronymDb.Categories.SearchByName(S)) then begin;
        TAcronymCategory(ListViewCategories.Selected.Data).Name := S;
        FormMain.AcronymDb.Modified := True;
        UpdateList;
      end else ShowMessage(Format(SCategoryAlreadyExists, [S]));
    end;
  end;
end;

procedure TFormCategories.ARemoveExecute(Sender: TObject);
var
  I: Integer;
begin
  if Assigned(ListViewCategories.Selected) then begin
    if MessageDlg(SRemoveCategory, SRemoveCategoryQuery,
    TMsgDlgType.mtConfirmation, [mbCancel, mbOk], 0) = mrOk then begin
      for I := ListViewCategories.Items.Count - 1 downto 0 do
      if ListViewCategories.Items[I].Selected then
        Categories.Remove(ListViewCategories.Items[I].Data);
      UpdateList;
    end;
  end;
end;

procedure TFormCategories.ListViewCategoriesData(Sender: TObject; Item: TListItem);
begin
  if Item.Index < FormMain.AcronymDb.Categories.Count then
  with TAcronymCategory(FormMain.AcronymDb.Categories[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := FormMain.AcronymDb.Categories[Item.Index];
    Item.SubItems.Add(IntToStr(AcronymMeanings.Count));
  end;
end;

procedure TFormCategories.ListViewCategoriesSelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormCategories.UpdateList;
begin
  ListViewCategories.Items.Count := FormMain.AcronymDb.Categories.Count;
  ListViewCategories.Refresh;
  UpdateInterface;
end;

procedure TFormCategories.UpdateInterface;
begin
  ARemove.Enabled := Assigned(ListViewCategories.Selected);
  AModify.Enabled := Assigned(ListViewCategories.Selected);
end;

end.