source: trunk/Forms/FormScore.pas

unit FormScore;

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, StdCtrls,
  FormEx, ListViewSort, Score, DateUtils, Generics.Collections;

type

  { TFormScore }

  TFormScore = class(TFormEx)
    ButtonClose: TButton;
    ButtonClear: TButton;
    ListView1: TListView;
    ListViewSort1: TListViewSort;
    procedure ButtonClearClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    FScores: TScores;
    procedure SetScores(AValue: TScores);
    procedure FilterList(List: TObjectList<TObject>);
  public
    procedure ReloadList;
    property Scores: TScores read FScores write SetScores;
  end;


implementation

{$R *.lfm}

resourcestring
  SClearCaption = 'Clear score';
  SClearQuery = 'Do you really want to clear score history?';

{ TFormScore }

procedure TFormScore.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if Item.Index < ListViewSort1.List.Count then
  with TScore(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := DateTimeToStr(StartTime);
    Item.Data := ListViewSort1.List[Item.Index];
    Item.SubItems.Add(BoardSize);
    Item.SubItems.Add(IntToStr(Score));
    Item.SubItems.Add(IntToStr(1 shl BiggestTile));
    Item.SubItems.Add(IntToStr(Moves));
    Item.SubItems.Add(IntToStr(UsedUndos));
    Item.SubItems.Add(IntToStr(DisabledTiles));
    Item.SubItems.Add(IntToStr(UnmergeableTiles));
    Item.SubItems.Add(TimeToStr(Duration));
  end;
end;

function TFormScore.ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
var
  Score1, Score2: TScore;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    Score1 := TScore(Item1);
    Score2 := TScore(Item2);
    with ListViewSort1 do
    case Column of
      0: Result := CompareDateTime(Score1.StartTime, Score2.StartTime);
      1: Result := CompareString(Score1.BoardSize, Score2.BoardSize);
      2: Result := CompareInteger(Score1.Score, Score2.Score);
      3: Result := CompareInteger(Score1.BiggestTile, Score2.BiggestTile);
      4: Result := CompareInteger(Score1.Moves, Score2.Moves);
      5: Result := CompareInteger(Score1.UsedUndos, Score2.UsedUndos);
      6: Result := CompareInteger(Score1.DisabledTiles, Score2.DisabledTiles);
      7: Result := CompareInteger(Score1.UnmergeableTiles, Score2.UnmergeableTiles);
      8: Result := CompareDateTime(Score1.Duration, Score2.Duration);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormScore.ListViewSort1Filter(ListViewSort: TListViewSort);
begin
  if Assigned(Scores) then Scores.AssignToList(ListViewSort1.List)
    else begin
      ListViewSort1.List.Clear;
    end;
  FilterList(ListViewSort1.List);
end;

procedure TFormScore.FormShow(Sender: TObject);
begin
  ReloadList;
end;

procedure TFormScore.ButtonClearClick(Sender: TObject);
begin
  if MessageDlg(SClearCaption, SClearQuery, mtConfirmation, [mbOk, mbCancel], 0) = mrOK then begin
    FScores.Clear;
    ReloadList;
  end;
end;

procedure TFormScore.SetScores(AValue: TScores);
begin
  if FScores = AValue then Exit;
  FScores := AValue;
  ReloadList;
end;

procedure TFormScore.FilterList(List: TObjectList<TObject>);
begin
end;

procedure TFormScore.ReloadList;
begin
  ListViewSort1.Refresh;
end;

end.