source: tags/1.3.0/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Classes, SysUtils, UTheme, UPersistentForm, UApplicationInfo, UTranslator,
  URegistry, UGame, ActnList, Forms, Controls, Dialogs;

type

  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    AComputer: TAction;
    AHistory: TAction;
    AHelp: TAction;
    AUndo: TAction;
    ASettings: TAction;
    ActionList1: TActionList;
    AExit: TAction;
    ANew: TAction;
    ApplicationInfo1: TApplicationInfo;
    PersistentForm1: TPersistentForm;
    ThemeManager1: TThemeManager;
    Translator1: TTranslator;
    procedure AAboutExecute(Sender: TObject);
    procedure AComputerExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure AHelpExecute(Sender: TObject);
    procedure AHistoryExecute(Sender: TObject);
    procedure ANewExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AUndoExecute(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure Translator1Translate(Sender: TObject);
  private
    procedure GameChange(Sender: TObject);
    procedure GamePaint(Sender: TObject);
    procedure GameWin(Sender: TObject);
    procedure GameWinSync;
    procedure GameOver(Sender: TObject);
    procedure GameOverSync;
  public
    Game: TGame;
    procedure UpdateInterface;
    procedure LoadConfig;
    procedure SaveConfig;
  end;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  UFormMain, UFormSettings, UFormAbout, UFormNew, UFormHelp, UFormComputer,
  UFormHistory;

resourcestring
  SGameOverCaption = 'Lost';
  SGameOverMessage = 'Game over!';
  SWinCaption = 'Win';
  SWinMessage = 'You reached %s and won! You can continue to play to get higher score.';

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  {$IFDEF Linux}
  // If installed in Linux system then use installation directory for po files
  if Application.ExeName = '/usr/bin/Game2048' then
    Translator1.POFilesFolder := '/usr/share/Game2048/languages';
  {$ENDIF}

  Randomize;
  Game := TGame.Create;
  Game.Board.Size := Point(4, 4);
  Game.OnChange := GameChange;
  Game.OnPaint := GamePaint;
  Game.OnWin := GameWin;
  Game.OnGameOver := GameOver;
  LoadConfig;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
begin
  FormSettings := TFormSettings.Create(nil);
  try
    if FormSettings.ShowModal = mrOk then begin
      FormMain.Redraw;
      FormMain.UpdateInterface;
      UpdateInterface;
    end;
  finally
    FreeAndNil(FormSettings);
  end;
end;

procedure TCore.AUndoExecute(Sender: TObject);
begin
  Game.Undo;
end;

procedure TCore.AAboutExecute(Sender: TObject);
begin
  FormAbout := TFormAbout.Create(nil);
  try
    FormAbout.ApplicationInfo := Core.ApplicationInfo1;
    FormAbout.ShowModal;
  finally
    FreeAndNil(FormAbout);
  end;
end;

procedure TCore.AComputerExecute(Sender: TObject);
begin
  FormComputer := TFormComputer.Create(nil);
  try
    FormComputer.ShowModal;
  finally
    FreeAndNil(FormComputer);
  end;
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  FormMain.Close;
end;

procedure TCore.AHelpExecute(Sender: TObject);
begin
  FormHelp := TFormHelp.Create(nil);
  try
    FormHelp.ShowModal;
  finally
    FreeAndNil(FormHelp);
  end;
end;

procedure TCore.AHistoryExecute(Sender: TObject);
begin
  FormHistory := TFormHistory.Create(nil);
  try
    FormHistory.ShowModal;
  finally
    FreeAndNil(FormHistory);
  end;
end;

procedure TCore.ANewExecute(Sender: TObject);
begin
  FormNew := TFormNew.Create(nil);
  try
    FormNew.Load(Core.Game);
    if FormNew.ShowModal = mrOk then begin
      FormNew.Save(Core.Game);
      Game.New;
      UpdateInterface;
      FormMain.UpdateInterface;
    end;
  finally
    FreeAndNil(FormNew);
  end;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  SaveConfig;
  FreeAndNil(Game);
end;

procedure TCore.Translator1Translate(Sender: TObject);
begin
  UGame.Translate;
end;

procedure TCore.GameChange(Sender: TObject);
begin
  UpdateInterface;
end;

procedure TCore.GamePaint(Sender: TObject);
begin
  if Assigned(FormMain) then FormMain.Redraw;
end;

procedure TCore.GameWin(Sender: TObject);
begin
  TThread.Synchronize(FormMain.MoveThread, GameWinSync);
end;

procedure TCore.GameWinSync;
begin
  MessageDlg(SWinCaption, Format(SWinMessage, [Game.GetTileSkinValue(Game.WinTileValue)]), mtInformation, [mbOk], 0);
end;

procedure TCore.GameOver(Sender: TObject);
begin
  TThread.Synchronize(FormMain.MoveThread, GameOverSync);
end;

procedure TCore.GameOverSync;
begin
  MessageDlg(SGameOverCaption, SGameOverMessage, mtInformation, [mbOK], 0);
end;

procedure TCore.UpdateInterface;
begin
  AUndo.Enabled := Game.CanUndo;
  AHistory.Enabled := Game.RecordHistory;
  {$IFDEF DEBUG}
  AComputer.Enabled := True;
  AComputer.Visible := True;
  {$ELSE}
  AComputer.Enabled := False;
  AComputer.Visible := False;
  {$ENDIF}
end;

procedure TCore.LoadConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if ValueExists('LanguageCode') then
      Translator1.Language := Translator1.Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''))
      else Translator1.Language := Translator1.Languages.SearchByCode('');
    ThemeManager1.Theme := ThemeManager1.Themes.FindByName(ReadStringWithDefault('Theme', 'System'));
  finally
    Free;
  end;
  Game.LoadFromRegistry(ApplicationInfo1.GetRegistryContext);
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if Assigned(Translator1.Language) and (Translator1.Language.Code <> '') then
      WriteString('LanguageCode', Translator1.Language.Code)
      else DeleteValue('LanguageCode');
    WriteString('Theme', ThemeManager1.Theme.Name);
  finally
    Free;
  end;
  Game.SaveToRegistry(ApplicationInfo1.GetRegistryContext);
end;

end.