source: tags/1.0.0/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Classes, SysUtils, UTheme, UPersistentForm, UApplicationInfo, UTranslator,
  URegistry, UGame, ActnList, Forms, Controls;

type

  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    AUndo: TAction;
    ASettings: TAction;
    ActionList1: TActionList;
    AExit: TAction;
    ANew: TAction;
    ApplicationInfo1: TApplicationInfo;
    PersistentForm1: TPersistentForm;
    ThemeManager1: TThemeManager;
    Translator1: TTranslator;
    procedure AAboutExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure ANewExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AUndoExecute(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    procedure GameChange(Sender: TObject);
  public
    Game: TGame;
    procedure UpdateInterface;
    procedure LoadConfig;
    procedure SaveConfig;
  end;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  UFormMain, UFormSettings, UFormAbout, UFormNew;

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  {$IFDEF Linux}
  // If installed in Linux system then use installation directory for po files
  if Application.ExeName = '/usr/bin/Game2048' then
    Translator1.POFilesFolder := '/usr/share/Game2048/languages';
  {$ENDIF}

  Randomize;
  Game := TGame.Create;
  Game.Board.Size := Point(4, 4);
  Game.OnChange := GameChange;
  LoadConfig;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
begin
  FormSettings := TFormSettings.Create(nil);
  try
    FormSettings.ShowModal;
  finally
    FreeAndNil(FormSettings);
  end;
end;

procedure TCore.AUndoExecute(Sender: TObject);
begin
  Game.Undo;
end;

procedure TCore.AAboutExecute(Sender: TObject);
begin
  FormAbout := TFormAbout.Create(nil);
  try
    FormAbout.ApplicationInfo := Core.ApplicationInfo1;
    FormAbout.ShowModal;
  finally
    FreeAndNil(FormAbout);
  end;
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  FormMain.Close;
end;

procedure TCore.ANewExecute(Sender: TObject);
begin
  FormNew := TFormNew.Create(nil);
  try
    FormNew.Load(Core.Game);
    if FormNew.ShowModal = mrOk then begin
      FormNew.Save(Core.Game);
      Game.New;
    end;
  finally
    FreeAndNil(FormNew);
  end;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  SaveConfig;
  FreeAndNil(Game);
end;

procedure TCore.GameChange(Sender: TObject);
begin
  FormMain.Redraw;
  UpdateInterface;
end;

procedure TCore.UpdateInterface;
begin
  AUndo.Enabled := Game.CanUndo;;
end;

procedure TCore.LoadConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if ValueExists('LanguageCode') then
      Translator1.Language := Translator1.Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''))
      else Translator1.Language := Translator1.Languages.SearchByCode('');
  finally
    Free;
  end;
  Game.LoadFromRegistry(ApplicationInfo1.GetRegistryContext);
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := ApplicationInfo1.GetRegistryContext;

    if Assigned(Translator1.Language) and (Translator1.Language.Code <> '') then
      WriteString('LanguageCode', Translator1.Language.Code)
      else DeleteValue('LanguageCode');
  finally
    Free;
  end;
  Game.SaveToRegistry(ApplicationInfo1.GetRegistryContext);
end;

end.