source: branches/delphi/UCore.pas

unit UCore;

interface

uses
  Classes, SysUtils, ActnList, Controls, Dialogs, Forms,
  UGame, Vcl.ImgList, System.Actions;

type

  { TCore }

  TCore = class(TDataModule)
    AGameSave: TAction;
    AGameLoad: TAction;
    ASettings: TAction;
    ActionList1: TActionList;
    AExit: TAction;
    AGameEnd: TAction;
    AGameEndTurn: TAction;
    AGameNew: TAction;
    AGameRestart: TAction;
    ImageListLarge: TImageList;
    ImageListSmall: TImageList;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    procedure AExitExecute(Sender: TObject);
    procedure AGameEndExecute(Sender: TObject);
    procedure AGameEndTurnExecute(Sender: TObject);
    procedure AGameLoadExecute(Sender: TObject);
    procedure AGameNewExecute(Sender: TObject);
    procedure AGameRestartExecute(Sender: TObject);
    procedure AGameSaveExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure CoolTranslator1Translate(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    FInitialized: Boolean;
    procedure DoOnMove(CellFrom, CellTo: TCell; var CountOnce,
      CountRepeat: Integer; Update: Boolean; var Confirm: Boolean);
    procedure DoOnWin(Player: TPlayer);
  public
    Game: TGame;
    UseSingleView: Boolean;
    LastMapFileName: string;
    View: TView;
    procedure Init;
    property Initialized: Boolean read FInitialized;
  end;

var
  Core: TCore;


implementation

{$R *.dfm}

uses
  UFormMove, UFormMain, UFormNew, UFormSettings;

resourcestring
  SPlayerWins = 'Player %s wins';


{ TCore }

procedure TCore.DoOnMove(CellFrom, CellTo: TCell; var CountOnce,
  CountRepeat: Integer; Update: Boolean; var Confirm: Boolean);
begin
  if Update then FormMove.SpinEditOnce.MaxValue := CellFrom.GetAvialPower + CountOnce
    else FormMove.SpinEditOnce.MaxValue := CellFrom.GetAvialPower;
  FormMove.SpinEditOnce.Value := CountOnce;
  FormMove.TrackBarOnce.Max := FormMove.SpinEditOnce.MaxValue;
  FormMove.TrackBarOnce.Position := FormMove.SpinEditOnce.Value;
  FormMove.SpinEditRepeat.MaxValue := Game.Map.MaxPower;
  FormMove.SpinEditRepeat.Value := CountRepeat;
  FormMove.TrackBarRepeat.Max := FormMove.SpinEditRepeat.MaxValue;
  FormMove.TrackBarRepeat.Position := FormMove.SpinEditRepeat.Value;
  if FormMove.ShowModal = mrOk then begin
    CountOnce := FormMove.SpinEditOnce.Value;
    CountRepeat := FormMove.SpinEditRepeat.Value;
    Confirm := True;
  end else Confirm := False;
end;

procedure TCore.DoOnWin(Player: TPlayer);
begin
  ShowMessage(Format(SPlayerWins, [Player.Name]));
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  Game.Running := False;
  Application.Terminate;
end;

procedure TCore.AGameEndExecute(Sender: TObject);
begin
  Game.Running := False;
  FormMain.Redraw;
end;

procedure TCore.AGameEndTurnExecute(Sender: TObject);
begin
  Game.NextTurn;
  FormMain.Redraw;
  while Game.Running and (Game.CurrentPlayer.Mode <> pmHuman) do begin
    if Game.CurrentPlayer.Mode = pmComputer then
      Game.CurrentPlayer.ComputerTurn;
    Game.NextTurn;
    FormMain.Redraw;
    Application.ProcessMessages;
    Sleep(1);
  end;
end;

procedure TCore.AGameLoadExecute(Sender: TObject);
begin
  OpenDialog1.FileName := LastMapFileName;
  if OpenDialog1.Execute then begin
    Game.Map.LoadFromFile(OpenDialog1.FileName);
    LastMapFileName := OpenDialog1.FileName;
    FormMain.Redraw;
  end;
end;

procedure TCore.AGameNewExecute(Sender: TObject);
begin
  FormNew.Load(Game);
  if FormNew.ShowModal = mrOk then begin
    FormNew.Save(Game);
    Game.New;
    Game.Running := True;
    FormMain.AZoomAll.Execute;
  end;
end;

procedure TCore.AGameRestartExecute(Sender: TObject);
begin
  Game.New;
  Game.Running := True;
  FormMain.Redraw;
end;

procedure TCore.AGameSaveExecute(Sender: TObject);
begin
  SaveDialog1.FileName := ExtractFileDir(LastMapFileName);
  if SaveDialog1.Execute then begin
    Game.Map.SaveToFile(SaveDialog1.FileName);
    LastMapFileName := SaveDialog1.FileName;
  end;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
begin
  FormSettings.Load;
  if FormSettings.ShowModal = mrOk then begin
    FormSettings.Save;
  end;
end;

procedure TCore.CoolTranslator1Translate(Sender: TObject);
begin
  UGame.InitStrings;
end;

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  Game := TGame.Create;
  Game.OnMove := DoOnMove;
  Game.OnWin := DoOnWin;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(Game);
end;

procedure TCore.Init;
var
  I: Integer;
begin
  FInitialized := True;
  for I := 0 to Game.Players.Count - 1 do
    TPlayer(Game.Players[I]).View.DestRect := Rect(0, 0, FormMain.PaintBox1.Width,
      FormMain.PaintBox1.Height);
  Game.New;
  Game.Running := True;
  FormMain.AZoomAll.Execute;
end;

end.