source: trunk/UProject.pas

unit UProject;

{$mode delphi}

interface

uses
  Classes, SysUtils, Contnrs, DOM, XMLRead, XMLWrite, UXMLUtils, UDriveScan,
  UPhysDrive;

type

  { TProject }

  TProject = class
  private
    FCurrentScan: TDriveScan;
    function GetCurrentScan: TDriveScan;
    function GetSectorCount: Integer;
  public
    Name: string;
    FileName: string;
    Modified: Boolean;
    Scans: TDriveScanList;
    DriveInfo: TDriveInfo;
    ScanProfile: TDriveScanProfile;
    constructor Create;
    destructor Destroy; override;
    procedure LoadFromFile(FileName: string);
    procedure SaveToFile(FileName: string);
    property SectorCount: Integer read GetSectorCount;
    property CurrentScan: TDriveScan read FCurrentScan write FCurrentScan;
  end;


implementation

resourcestring
  SWrongFileFormat = 'Wrong file format';


{ TProject }

function TProject.GetCurrentScan: TDriveScan;
begin
  if Scans.Count > 0 then Result := TDriveScan(Scans[Scans.Count - 1])
    else Result := nil;
end;

function TProject.GetSectorCount: Integer;
begin
  Result := DriveInfo.SectorCount;
end;

constructor TProject.Create;
begin
  Scans := TDriveScanList.Create;
  DriveInfo := TDriveInfo.Create;
  ScanProfile := TDriveScanProfile.Create;
end;

destructor TProject.Destroy;
begin
  FreeAndNil(ScanProfile);
  FreeAndNil(DriveInfo);
  FreeAndNil(Scans);
  inherited Destroy;
end;

procedure TProject.SaveToFile(FileName: string);
var
  NewNode: TDOMNode;
  Doc: TXMLDocument;
  RootNode: TDOMNode;
begin
  Self.FileName := FileName;
  Doc := TXMLDocument.Create;
  with Doc do try
    RootNode := CreateElement('CoolDiskProject');
    AppendChild(RootNode);
    with RootNode do begin
      WriteInteger(RootNode, 'SectorCount', DriveInfo.SectorCount);
      WriteInteger(RootNode, 'SectorSize', DriveInfo.SectorSize);
      WriteString(RootNode, 'DriveName', DriveInfo.Model);
      WriteString(RootNode, 'DrivePath', DriveInfo.Path);
      WriteInt64(RootNode, 'DriveSize', DriveInfo.Size);

      NewNode := OwnerDocument.CreateElement('ScanProfile');
      AppendChild(NewNode);
      WriteInteger(NewNode, 'SectorStart', ScanProfile.SectorStart);
      WriteInteger(NewNode, 'SectorEnd', ScanProfile.SectorEnd);
      WriteInteger(NewNode, 'WritePattern', ScanProfile.WritePattern);
      WriteInteger(NewNode, 'Mode', Integer(ScanProfile.Mode));

      NewNode := OwnerDocument.CreateElement('Scans');
      AppendChild(NewNode);
      Scans.SaveToNode(NewNode);
    end;
    ForceDirectories(ExtractFileDir(FileName));
    WriteXMLFile(Doc, FileName);
  finally
    Doc.Free;
  end;
  Modified := False;
end;

procedure TProject.LoadFromFile(FileName: string);
var
  Doc: TXMLDocument;
  RootNode: TDOMNode;
  NewNode: TDOMNode;
begin
  Modified := False;
  Self.FileName := FileName;
  ReadXMLFile(Doc, FileName);
  with Doc do try
    if Doc.DocumentElement.NodeName <> 'CoolDiskProject' then
      raise Exception.Create(SWrongFileFormat);
    RootNode := Doc.DocumentElement;
    with RootNode do begin
      DriveInfo.SectorSize := ReadInteger(RootNode, 'SectorSize', 4096);
      ScanProfile.SectorCount := DriveInfo.SectorCount;
      DriveInfo.Model := ReadString(RootNode, 'DriveName', '');
      DriveInfo.Path := ReadString(RootNode, 'DrivePath', '');
      DriveInfo.Size := ReadInt64(RootNode, 'DriveSize', 0);

      NewNode := FindNode('ScanProfile');
      if Assigned(NewNode) then begin
        ScanProfile.SectorStart := ReadInteger(NewNode, 'SectorStart', 0);
        ScanProfile.SectorEnd := ReadInteger(NewNode, 'SectorEnd', ScanProfile.SectorCount - 1);
        ScanProfile.WritePattern := ReadInteger(NewNode, 'WritePattern', 0);
        ScanProfile.Mode := TRunMode(ReadInteger(NewNode, 'Mode', 0));
      end;

      NewNode := FindNode('Scans');
      if Assigned(NewNode) then
        Scans.LoadFromNode(NewNode);
    end;
  finally
    Doc.Free;
  end;
end;


end.