source: trunk/Modules/System/ModuleSystem.pas

unit ModuleSystem;

interface

uses
  Classes, SysUtils, ModularSystem, Generics;

type

  { TModuleSystem }

  TModuleSystem = class(TModule)
  private
    procedure ModuleChange(Sender: TObject; Module: TModule);
  public
    constructor Create(Owner: TComponent); override;
    destructor Destroy; override;
    procedure Start; override;
    procedure Stop; override;
    procedure Install; override;
    procedure Uninstall; override;
    procedure Upgrade; override;
    procedure UpdateModuleList;
  end;


implementation

uses
  Core, SqlDatabase;

{ TModuleSystem }

procedure TModuleSystem.ModuleChange(Sender: TObject; Module: TModule);
var
  DbRows: TDbRows;
  Data: TDictionaryStringString;
begin
  try
    DbRows := TDbRows.Create;
    Data := TDictionaryStringString.Create;
    if Module.Installed then Data.Add('Installed', '1')
      else Data.Add('Installed', '0');
    Core.Core.CommonDatabase.Update('SystemModule', Data, 'Name="' + Module.Identification + '"');
  finally
    Data.Free;
    DbRows.Free;
  end;
end;

constructor TModuleSystem.Create(Owner: TComponent);
begin
  inherited Create(Owner);
  Identification := 'System';
  Title := 'Base modular system';
  Version := '1.0';
  License := 'GNU/LGPL v3';
  Author := 'Chronosoft';
end;

destructor TModuleSystem.Destroy;
begin
  inherited;
end;

procedure TModuleSystem.Start;
var
  DbRows: TDbRows;
  I: Integer;
  Module: TModule;
begin
  try
    DbRows := TDbRows.Create;
    Core.Core.CommonDatabase.Select(DbRows, 'SystemModule', '`Name`, `Installed`');
    for I := 0 to DbRows.Count - 1 do
    with DbRows[I] do begin
      Module := Manager.FindModuleByName(Items['Name']);
      if Assigned(Module) then
        if Items['Installed'] = '1' then Module.SetInstalledState(True)
          else Module.SetInstalledState(False);
    end;
  finally
    DbRows.Free;
  end;
  Manager.OnModuleChange := ModuleChange;
  inherited;
end;

procedure TModuleSystem.Stop;
begin
  BeforeStop;
  Manager.OnModuleChange := nil;
  AfterStop;
end;

procedure TModuleSystem.Install;
var
  DbRows: TDbRows;
begin
  try
    DbRows := TDbRows.Create;
    Core.Core.CommonDatabase.Query(DbRows,
      'CREATE TABLE IF NOT EXISTS `SystemModule` (' +
      '  `Id` int(11) NOT NULL AUTO_INCREMENT,' +
      '  `Name` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  `Title` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  `Creator` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  `Version` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  `License` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  `Installed` int(11) NOT NULL,' +
      '  `Description` text COLLATE utf8_czech_ci NOT NULL,' +
      '  `Dependencies` varchar(255) COLLATE utf8_czech_ci NOT NULL,' +
      '  PRIMARY KEY (`Id`)' +
      ') ENGINE=InnoDB  DEFAULT CHARSET=utf8 COLLATE=utf8_czech_ci AUTO_INCREMENT=1 ;');
  finally
    DbRows.Free;
  end;
  UpdateModuleList;
  inherited;
end;

procedure TModuleSystem.Uninstall;
var
  DbRows: TDbRows;
begin
  inherited;
  try
    DbRows := TDbRows.Create;
    Core.Core.CommonDatabase.Query(DbRows, 'DROP TABLE IF EXISTS `SystemModule`');
  finally
    DbRows.Free;
  end;
end;

procedure TModuleSystem.Upgrade;
begin
  inherited;
end;

procedure TModuleSystem.UpdateModuleList;
var
  DbRows: TDbRows;
  I: Integer;
  Index: Integer;
  Data: TDictionaryStringString;
begin
  try
    DbRows := TDbRows.Create;
    Data := TDictionaryStringString.Create;

    Core.Core.CommonDatabase.Select(DbRows, 'SystemModule', 'Name');

    for I := 0 to Manager.Modules.Count - 1 do
    with TModule(Manager.Modules[I]) do begin
      Data.Clear;
      Data.Add('Name', Identification);
      Data.Add('Version', Version);
      Data.Add('License', License);
      Data.Add('Creator', Author);
      Data.Add('Description', Description.Text);
      Data.Add('Title', Title);
      Data.Add('Dependencies', Dependencies.Text);
      if Installed then Data.Add('Installed', '1')
        else Data.Add('Installed', '0');

      Index := 0;
      while (Index < DbRows.Count) and (DbRows[Index].Items['Name'] <> Identification) do Inc(Index);
      if Index >= DbRows.Count then Core.Core.CommonDatabase.Insert('SystemModule', Data)
        else Core.Core.CommonDatabase.Update('SystemModule', Data, 'Name="' + Identification + '"');
    end;
  finally
    Data.Free;
    DbRows.Free;
  end;
end;

end.