source: trunk/Forms/FormPlayersStats.pas

unit FormPlayersStats;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Menus, ActnList, Game, ListViewSort, FormEx, Player;

type

  { TFormPlayersStats }

  TFormPlayersStats = class(TFormEx)
    ASpectate: TAction;
    ActionList1: TActionList;
    ListView1: TListView;
    ListViewSort1: TListViewSort;
    MenuItem1: TMenuItem;
    PopupMenu1: TPopupMenu;
    procedure ASpectateExecute(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    function ListViewSort1CompareItem(Item1, Item2: TObject): Integer;
    procedure ListViewSort1Filter(ListViewSort: TListViewSort);
  private
    FOnSpectate: TPlayerEvent;
  public
    Game: TGame;
    procedure ReloadList;
    property OnSpectate: TPlayerEvent read FOnSpectate write FOnSpectate;
  end;


implementation

{$R *.lfm}

{ TFormPlayersStats }

procedure TFormPlayersStats.ListView1Data(Sender: TObject; Item: TListItem);
begin
  with Game do
  if Item.Index < ListViewSort1.List.Count then
  with TPlayer(ListViewSort1.List[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := ListViewSort1.List[Item.Index];
    Item.SubItems.Add(PlayerModeText[Mode]);
    Item.SubItems.Add(IntToStr(TotalCells));
    Item.SubItems.Add(IntToStr(TotalDiscovered));
    Item.SubItems.Add(IntToStr(TotalCities));
    Item.SubItems.Add(IntToStr(TotalUnits));
    Item.SubItems.Add(IntToStr(TotalWinObjectiveCells));
  end;
end;

function TFormPlayersStats.ListViewSort1CompareItem(Item1, Item2: TObject
  ): Integer;
begin
  Result := 0;
  if Assigned(Item1) and Assigned(Item2) and (ListViewSort1.Order <> soNone) then begin
    with ListViewSort1 do
    case Column of
      0: Result := CompareString(TPlayer(Item1).Name, TPlayer(Item2).Name);
      1: Result := CompareString(PlayerModeText[TPlayer(Item1).Mode], PlayerModeText[TPlayer(Item2).Mode]);
      2: Result := CompareInteger(TPlayer(Item1).TotalCells, TPlayer(Item2).TotalCells);
      3: Result := CompareInteger(TPlayer(Item1).TotalDiscovered, TPlayer(Item2).TotalDiscovered);
      4: Result := CompareInteger(TPlayer(Item1).TotalCities, TPlayer(Item2).TotalCities);
      5: Result := CompareInteger(TPlayer(Item1).TotalUnits, TPlayer(Item2).TotalUnits);
      6: Result := CompareInteger(TPlayer(Item1).TotalWinObjectiveCells, TPlayer(Item2).TotalWinObjectiveCells);
    end;
    if ListViewSort1.Order = soDown then Result := -Result;
  end else Result := 0;
end;

procedure TFormPlayersStats.ListViewSort1Filter(ListViewSort: TListViewSort);
var
  I: Integer;
begin
  ListViewSort1.List.Clear;
  for I := 0 to Game.Players.Count - 1 do begin
    ListViewSort1.List.Add(Game.Players[I]);
  end;
end;

procedure TFormPlayersStats.FormShow(Sender: TObject);
begin
  ReloadList;
end;

procedure TFormPlayersStats.ASpectateExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then
    if Assigned(FOnSpectate) then
      FOnSpectate(TPlayer(ListView1.Selected.Data));
end;

procedure TFormPlayersStats.ReloadList;
begin
  ListViewSort1.Refresh;
end;

end.