source: trunk/Forms/FormGameSystem.pas

unit FormGameSystem;

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, GameSystem, FormList, FormEx;

type

  { TFormGameSystem }

  TFormGameSystem = class(TFormEx)
    ButtonCancel: TButton;
    ButtonOk: TButton;
    ButtonSave: TButton;
    ButtonLoad: TButton;
    CheckBoxEmptyCellsNeutral: TCheckBox;
    CheckBoxUnitsMoveImmediately: TCheckBox;
    CheckBoxUnitsSplitMerge: TCheckBox;
    ComboBoxPreferredGridType: TComboBox;
    Label5: TLabel;
    OpenDialog1: TOpenDialog;
    PageControl1: TPageControl;
    SaveDialog1: TSaveDialog;
    ScrollBoxGeneral: TScrollBox;
    TabSheetBuildings: TTabSheet;
    TabSheetNations: TTabSheet;
    TabSheetGeneral: TTabSheet;
    TabSheetUnits: TTabSheet;
    procedure ButtonLoadClick(Sender: TObject);
    procedure ButtonSaveClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FGameSystem: TGameSystem;
    FormUnitKinds: TFormList;
    FormNations: TFormList;
    FormBuildingKinds: TFormList;
    procedure SetGameSystem(AValue: TGameSystem);
    procedure Translate;
  public
    property GameSystem: TGameSystem read FGameSystem write SetGameSystem;
    procedure LoadData(GameSystem: TGameSystem);
    procedure SaveData(GameSystem: TGameSystem);
  end;


implementation

{$R *.lfm}

uses
  MapType, ItemList, Core;

resourcestring
  SFileDialogFilter = 'xTactics game system (.xts)|*.xts|All files|*.*';


{ TFormGameSystem }

procedure TFormGameSystem.ButtonLoadClick(Sender: TObject);
begin
  OpenDialog1.Filter := SFileDialogFilter;
  OpenDialog1.InitialDir := ExtractFileDir(GameSystem.FileName);
  OpenDialog1.FileName := ExtractFileName(GameSystem.FileName);
  if OpenDialog1.Execute then begin
    GameSystem.LoadFromFile(OpenDialog1.FileName);
    LoadData(GameSystem);
  end;
end;

procedure TFormGameSystem.ButtonSaveClick(Sender: TObject);
begin
  SaveDialog1.Filter := SFileDialogFilter;
  SaveDialog1.InitialDir := ExtractFileDir(GameSystem.FileName);
  SaveDialog1.FileName := ExtractFileName(GameSystem.FileName);
  SaveDialog1.DefaultExt := GameSystemExt;
  if SaveDialog1.Execute then begin
    GameSystem.SaveToFile(SaveDialog1.FileName);
  end;
end;

procedure TFormGameSystem.FormCreate(Sender: TObject);
begin
  FormUnitKinds := TFormList.Create(nil);
  FormUnitKinds.ManualDock(TabSheetUnits, nil, alClient);
  FormUnitKinds.Align := alClient;
  FormUnitKinds.Visible := True;
  FormUnitKinds.Images := Core.Core.ImageListSmall;
  FormNations := TFormList.Create(nil);
  FormNations.ManualDock(TabSheetNations, nil, alClient);
  FormNations.Align := alClient;
  FormNations.Visible := True;
  FormNations.Images := Core.Core.ImageListSmall;
  FormBuildingKinds := TFormList.Create(nil);
  FormBuildingKinds.ManualDock(TabSheetBuildings, nil, alClient);
  FormBuildingKinds.Align := alClient;
  FormBuildingKinds.Visible := True;
  FormBuildingKinds.Images := Core.Core.ImageListSmall;
  Translate;
end;

procedure TFormGameSystem.FormDestroy(Sender: TObject);
begin
  GameSystem := nil;
  FreeAndNil(FormNations);
  FreeAndNil(FormUnitKinds);
  FreeAndNil(FormBuildingKinds);
end;

procedure TFormGameSystem.SetGameSystem(AValue: TGameSystem);
begin
  if FGameSystem = AValue then Exit;
  if Assigned(FGameSystem) then begin
    FormUnitKinds.List := nil;
    FormNations.List := nil;
    FormBuildingKinds.List := nil;
  end;
  FGameSystem := AValue;
  if Assigned(FGameSystem) then begin
    FormUnitKinds.List := GameSystem.UnitKinds.BaseItemList;
    FormNations.List := GameSystem.Nations.BaseItemList;
    FormBuildingKinds.List := GameSystem.BuildingKinds.BaseItemList;
  end;
end;

procedure TFormGameSystem.Translate;
var
  LastIndex: Integer;
begin
  with ComboBoxPreferredGridType do begin
    LastIndex := ItemIndex;
    Clear;
    Items.AddObject(SGridTypeNone, TObject(mtNone));
    Items.AddObject(SGridTypeHexagonVertical, TObject(mtHexagonVertical));
    Items.AddObject(SGridTypeHexagonHorizontal, TObject(mtHexagonHorizontal));
    Items.AddObject(SGridTypeSquare, TObject(mtSquare));
    Items.AddObject(SGridTypeTriangle, TObject(mtTriangle));
    Items.AddObject(SGridTypeRandom, TObject(mtRandom));
    Items.AddObject(SGridTypeIsometric, TObject(mtIsometric));
    ItemIndex := LastIndex;
  end;
end;

procedure TFormGameSystem.LoadData(GameSystem: TGameSystem);
begin
  Self.GameSystem := GameSystem;
  CheckBoxEmptyCellsNeutral.Checked := GameSystem.EmptyCellsNeutral;
  CheckBoxUnitsSplitMerge.Checked := GameSystem.UnitsSplitMerge;
  CheckBoxUnitsMoveImmediately.Checked := GameSystem.UnitsMoveImmediately;
  ComboBoxPreferredGridType.ItemIndex := Integer(GameSystem.PreferedMapType);
  FormNations.UpdateList;
  FormNations.UpdateInterface;
  FormUnitKinds.UpdateList;
  FormUnitKinds.UpdateInterface;
  FormBuildingKinds.UpdateList;
  FormBuildingKinds.UpdateInterface;
  Caption := ExtractFileName(Self.GameSystem.FileName) + ' - ' + SGameSystem;
end;

procedure TFormGameSystem.SaveData(GameSystem: TGameSystem);
begin
  GameSystem.EmptyCellsNeutral := CheckBoxEmptyCellsNeutral.Checked;
  GameSystem.UnitsSplitMerge := CheckBoxUnitsSplitMerge.Checked;
  GameSystem.UnitsMoveImmediately := CheckBoxUnitsMoveImmediately.Checked;
  GameSystem.PreferedMapType := TMapType(ComboBoxPreferredGridType.ItemIndex);
end;

end.