source: trunk/Forms/FormCharts.pas

unit FormCharts;

interface

uses
  Classes, SysUtils, FileUtil, TAGraph, TASeries, Forms, Controls, Graphics,
  Dialogs, StdCtrls, FormEx, Game;

type

  { TFormCharts }

  TFormCharts = class(TFormEx)
    ButtonClose: TButton;
    Chart1: TChart;
    ComboBox1: TComboBox;
    procedure ButtonCloseClick(Sender: TObject);
    procedure ComboBox1Change(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    FGame: TGame;
  public
    procedure Redraw;
    procedure Translate;
    property Game: TGame read FGame write FGame;
  end;


implementation

{$R *.lfm}

uses
  Player;

resourcestring
  SOccupiedCells = 'Occupied cells';
  SMilitaryPower = 'Military power';
  SDiscoveredCells = 'Discovered cells';
  SCitiesCount = 'Cities count';
  SWinObjectiveCells = 'Win objective cells';

{ TFormCharts }

procedure TFormCharts.ComboBox1Change(Sender: TObject);
begin
  Redraw;
end;

procedure TFormCharts.ButtonCloseClick(Sender: TObject);
begin
  Close;
end;

procedure TFormCharts.FormShow(Sender: TObject);
begin
  Translate;
  if (ComboBox1.ItemIndex = -1) and (ComboBox1.Items.Count > 0) then
    ComboBox1.ItemIndex := 0;
  Chart1.BackColor := ThemeManager.ActualTheme.ColorWindow;
  Redraw;
end;

procedure TFormCharts.Redraw;
var
  I: Integer;
  X: Integer;
  NewSeries: TLineSeries;
begin
  Chart1.Series.Clear;
  for I := 0 to Game.Players.Count - 1 do
  with Game.Players[I] do begin
    NewSeries := TLineSeries.Create(nil);
    NewSeries.LinePen.Color := Color;
    NewSeries.LinePen.Width := Scale96ToScreen(1);
    for X := 0 to TurnStats.Count - 1 do begin
      if ComboBox1.ItemIndex = 0 then NewSeries.AddXY(X, TurnStats[X].OccupiedCells)
      else if ComboBox1.ItemIndex = 1 then NewSeries.AddXY(X, TurnStats[X].Units)
      else if ComboBox1.ItemIndex = 2 then NewSeries.AddXY(X, TurnStats[X].DiscoveredCells)
      else if ComboBox1.ItemIndex = 3 then NewSeries.AddXY(X, TurnStats[X].Cities)
      else if ComboBox1.ItemIndex = 4 then NewSeries.AddXY(X, TurnStats[X].WinObjectiveCells);
    end;
    Chart1.AddSeries(NewSeries);
  end;
end;

procedure TFormCharts.Translate;
var
  LastIndex: Integer;
begin
  TFormEx.Translator.TranslateComponentRecursive(Self);
  with ComboBox1 do begin
    LastIndex := ItemIndex;
    Clear;
    Items.Add(SOccupiedCells);
    Items.Add(SMilitaryPower);
    Items.Add(SDiscoveredCells);
    Items.Add(SCitiesCount);
    Items.Add(SWinObjectiveCells);
    ItemIndex := LastIndex;
  end;
end;

end.