source: branches/delphi/Forms/UFormNew.pas

unit UFormNew;

interface

uses
  Classes, SysUtils,  Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Spin, ExtCtrls, ActnList, UGame, System.Actions;

type

  { TFormNew }

  TFormNew = class(TForm)
    APlayerAdd: TAction;
    APlayerRemove: TAction;
    APlayerModify: TAction;
    ActionList1: TActionList;
    ButtonCancel: TButton;
    ButtonOk: TButton;
    ButtonPlayerAdd: TButton;
    ButtonPlayerModify: TButton;
    ButtonPlayerRemove: TButton;
    CheckBoxCity: TCheckBox;
    CheckBoxVoid: TCheckBox;
    ComboBoxGridType: TComboBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    ListView1: TListView;
    Panel1: TPanel;
    Panel2: TPanel;
    RadioGroupGrowAmount: TRadioGroup;
    RadioGroupGrowCells: TRadioGroup;
    SpinEditCityPercent: TSpinEdit;
    SpinEditMapSizeX: TSpinEdit;
    SpinEditMapSizeY: TSpinEdit;
    SpinEditVoidPercent: TSpinEdit;
    Splitter1: TSplitter;
    TrackBarSizeX: TTrackBar;
    TrackBarSizeY: TTrackBar;
    procedure APlayerAddExecute(Sender: TObject);
    procedure APlayerModifyExecute(Sender: TObject);
    procedure APlayerRemoveExecute(Sender: TObject);
    procedure CheckBoxCityChange(Sender: TObject);
    procedure CheckBoxVoidChange(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1DblClick(Sender: TObject);
    procedure ListView1KeyPress(Sender: TObject; var Key: char);
    procedure ListView1KeyUp(Sender: TObject; var Key: Word; Shift: TShiftState
      );
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
    procedure SpinEditMapSizeXChange(Sender: TObject);
    procedure SpinEditMapSizeYChange(Sender: TObject);
    procedure TrackBarSizeYChange(Sender: TObject);
    procedure TrackBarSizeXChange(Sender: TObject);
  private
    Players: TPlayers;
  public
    procedure ReloadView;
    procedure Load(Game: TGame);
    procedure Save(Game: TGame);
  end;

var
  FormNew: TFormNew;

implementation

{$R *.dfm}

uses
  UFormPlayer;

{ TFormNew }

procedure TFormNew.ListView1Data(Sender: TObject; Item: TListItem);
begin
  if (Item.Index >= 0) and (Item.Index < Players.Count) then
  with TPlayer(Players[Item.Index]) do begin
    Item.Caption := Name;
    Item.Data := Players[Item.Index];
    Item.SubItems.Add(PlayerModeText[Mode]);
    Item.SubItems.Add(IntToStr(Color));
    Item.SubItems.Add(IntToStr(StartUnits));
  end;
end;

procedure TFormNew.ListView1DblClick(Sender: TObject);
begin
  APlayerModify.Execute;
end;

procedure TFormNew.ListView1KeyPress(Sender: TObject; var Key: char);
begin
  if (Key = #13) then APlayerModify.Execute;
end;

procedure TFormNew.ListView1KeyUp(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key = 45 then APlayerAdd.Execute;
  if Key = 46 then APlayerRemove.Execute;
end;

procedure TFormNew.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  ReloadView;
end;

procedure TFormNew.SpinEditMapSizeXChange(Sender: TObject);
begin
  TrackBarSizeX.Position := SpinEditMapSizeX.Value;
end;

procedure TFormNew.SpinEditMapSizeYChange(Sender: TObject);
begin
  TrackBarSizeY.Position := SpinEditMapSizeY.Value;
end;

procedure TFormNew.TrackBarSizeYChange(Sender: TObject);
begin
  SpinEditMapSizeY.Value := TrackBarSizeY.Position;
end;

procedure TFormNew.TrackBarSizeXChange(Sender: TObject);
begin
  SpinEditMapSizeX.Value := TrackBarSizeX.Position;
end;

procedure TFormNew.ReloadView;
begin
  ListView1.Items.Count := Players.Count;
  ListView1.Refresh;
  ButtonPlayerRemove.Enabled := Assigned(ListView1.Selected);
  ButtonPlayerAdd.Enabled := Players.Count < MaxPlayerCount;
  APlayerModify.Enabled := Assigned(ListView1.Selected);
end;

procedure TFormNew.FormShow(Sender: TObject);
begin
  ReloadView;
end;

procedure TFormNew.FormCreate(Sender: TObject);
begin
  Players := TPlayers.Create;
end;

procedure TFormNew.CheckBoxCityChange(Sender: TObject);
begin
  SpinEditCityPercent.Enabled := CheckBoxCity.Checked;
end;

procedure TFormNew.CheckBoxVoidChange(Sender: TObject);
begin
  SpinEditVoidPercent.Enabled := CheckBoxVoid.Checked;
end;

procedure TFormNew.APlayerModifyExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    FormPlayer.Load(TPlayer(ListView1.Selected.Data));
    if FormPlayer.ShowModal = mrOk then begin
      FormPlayer.Save(TPlayer(ListView1.Selected.Data));
      ReloadView;
    end;
  end;
end;

procedure TFormNew.APlayerRemoveExecute(Sender: TObject);
begin
  if Assigned(ListView1.Selected) then begin
    Players.Remove(ListView1.Selected.Data);
    ReloadView;
  end;
end;

procedure TFormNew.APlayerAddExecute(Sender: TObject);
var
  NewPlayer: TPlayer;
begin
  if Players.Count <= (MaxPlayerCount - 1) then begin
    NewPlayer := TPlayer.Create;
    NewPlayer.Name := 'Player ' + IntToStr(Players.Count + 1);
    NewPlayer.Color := PlayerColors[Players.Count];
    NewPlayer.Mode := pmComputer;
    Players.Add(NewPlayer);
    ReloadView;
  end;
end;

procedure TFormNew.FormDestroy(Sender: TObject);
begin
  Players.Free;
end;

procedure TFormNew.Load(Game: TGame);
var
  I: Integer;
  NewItem: TListItem;
begin
  CheckBoxVoid.Checked := Game.VoidEnabled;
  SpinEditVoidPercent.Value := Game.VoidPercentage;
  SpinEditVoidPercent.Enabled := Game.VoidEnabled;
  for I := 0 to Players.Count - 1 do
    Players[I] := nil;
  Players.Count := Game.Players.Count;
  for I := 0 to Game.Players.Count - 1 do begin
    Players[I] := TPlayer.Create;
    TPlayer(Players[I]).Assign(TPlayer(Game.Players[I]));
  end;
  CheckBoxCity.Checked := Game.CityEnabled;
  SpinEditCityPercent.Value := Game.CityPercentage;
  SpinEditMapSizeX.Value := Game.Map.Size.X;
  SpinEditMapSizeY.Value := Game.Map.Size.Y;
  TrackBarSizeX.Position := Game.Map.Size.X;
  TrackBarSizeY.Position := Game.Map.Size.Y;
  RadioGroupGrowAmount.ItemIndex := Integer(Game.GrowAmount);
  RadioGroupGrowCells.ItemIndex := Integer(Game.GrowCells);
  ComboBoxGridType.ItemIndex := Integer(Game.MapType) - 1;
end;

procedure TFormNew.Save(Game: TGame);
var
  I: Integer;
begin
  while Game.Players.Count > Players.Count do
    Game.Players.Delete(Game.Players.Count - 1);
  while Game.Players.Count < Players.Count do
    Game.Players.Add(TPlayer.Create);
  for I := 0 to Game.Players.Count - 1 do begin
    TPlayer(Game.Players[I]).Assign(TPlayer(Players[I]));
    TPlayer(Game.Players[I]).Game := Game;
  end;
  Game.VoidEnabled := CheckBoxVoid.Checked;
  Game.VoidPercentage := SpinEditVoidPercent.Value;
  Game.CityEnabled := CheckBoxCity.Checked;
  Game.CityPercentage := SpinEditCityPercent.Value;
  Game.Map.Size := Point(SpinEditMapSizeX.Value, SpinEditMapSizeY.Value);
  Game.GrowAmount := TGrowAmount(RadioGroupGrowAmount.ItemIndex);
  Game.GrowCells := TGrowCells(RadioGroupGrowCells.ItemIndex);
  Game.MapType := TMapType(ComboBoxGridType.ItemIndex + 1);
end;

end.