source: tools/dbc_export/DBCExport.pas

program DBCExport;

{$mode Delphi}{$H+}

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  Classes, SysUtils, CustApp,
  USqlDatabase, UDBC, Variants;

type

  { TDBCExport }
  TDBCExport = class(TCustomApplication)
  private
    procedure ParseParameters;
  protected
    procedure DoRun; override;
  public
    DBC: TDBC;
    Database: TSqlDatabase;
    DBCFileName: string;
    NewDBCFileName: string;
    ColumnTypeDefinition: string;
    LastIndexStringColumns: integer;
    IndexTable: array of integer;
    SQLquery: string;
    DisplayData: Boolean;
    constructor Create(TheOwner: TComponent); override;
    destructor Destroy; override;
    procedure WriteHelp; virtual;
    procedure ShowDBC;
    procedure LoadDBC;
    procedure SaveDBC;
    procedure ReplaceText;
    procedure CreateIndexTable(var DbRows: TDbRows);
    function GetIDbyEntry(Entry: Integer; var DBRows: TDBRows): Integer;
  end;

{ TDBCExport }

procedure TDBCExport.ParseParameters;
begin
  if HasOption('h', 'help') then begin
    WriteHelp;
    Halt;
  end;
  if HasOption('f', 'file') then begin
    DBCFileName := GetOptionValue('f', 'file');
    NewDBCFileName := Copy(DBCFileName, 1, Length(DBCFileName) -
      Length(ExtractFileExt(DBCFileName))) + '-2.dbc';
  end else begin
    WriteLn('Source DBC file not specified.');
    Halt;
  end;
  if HasOption('n', 'newfile') then begin
    NewDBCFileName := GetOptionValue('n', 'newfile');
  end;
  if HasOption('c', 'coltypedef') then begin
    ColumnTypeDefinition := GetOptionValue('c', 'coltypedef');
  end;
  if HasOption('d', 'display') then begin
    DisplayData := True;
  end;

  if HasOption('s', 'schema') then begin
    Database.Database := GetOptionValue('s', 'schema');
  end else Database.Database := 'wowpreklad';
  if HasOption('u', 'user') then begin
    Database.UserName := GetOptionValue('u', 'user');
  end else Database.UserName := 'root';
  if HasOption('p', 'password') then begin
    Database.Password := GetOptionValue('p', 'password');
  end else Database.Password := '';
  if HasOption('t', 'host') then begin
    Database.Hostname := GetOptionValue('t', 'host');
  end else Database.Hostname := 'localhost';
  if HasOption('a', 'Charset') then begin
    Database.Encoding := GetOptionValue('a', 'Charset');
  end else Database.Encoding := 'utf8';
  if HasOption('q', 'sql_query') then begin
    SQLquery := GetOptionValue('q', 'sql_query');
    SQLquery := StringReplace(SQLquery, '\ ', ' ', [rfReplaceAll]);
    SQLquery := StringReplace(SQLquery, '\`', '`', [rfReplaceAll]);
    WriteLn(SQLquery);
  end;
end;

procedure TDBCExport.DoRun;
begin
  ParseParameters;
  LoadDBC;
  ShowDBC;
  ReplaceText;
  SaveDBC;
  Terminate;   // Stop program loop
end;

constructor TDBCExport.Create(TheOwner: TComponent);
begin
  inherited Create(TheOwner);
  StopOnException := True;
  Database := TSqlDatabase.Create;
end;

destructor TDBCExport.Destroy;
begin
  Database.Destroy;
  inherited Destroy;
end;

procedure TDBCExport.WriteHelp;
begin
  WriteLn('Usage: ', ExtractFileName(ExeName), ' [options]');
  WriteLn('  -h --help        Show this help');
  WriteLn('  -u --user        Database user name, default root');
  WriteLn('  -p --password    Database password name');
  WriteLn('  -s --schema      Database schema name, default wowpreklad');
  WriteLn('  -t --host        Database host name, default localhost');
  WriteLn('  -a --Charset     Database Charset, default utf8');
  WriteLn('  -f --file        Source DBC file name');
  WriteLn('  -n --newfile     New created DBC file name');
  WriteLn('  -c --coltypedef  DBC column type definition string (usage index1:type1, index2:type2,...)');
  WriteLn('                   where 0 - uint32, 1 - sint32, 2 - float, 3 - string, 4 - byte)');
  WriteLn('  -d --display     Display DBC data');
  WriteLn('  -q --sql_query   SQL select when entry is ID first column in dbc file and text1,text2... is texts columns');
  // SELECT T.entry as entry,T.Text as text1 FROM (SELECT * FROM gametips WHERE (Complete = 1) AND ((Language = 1)) AND (User IN (459,670,602,462,1,400,638,592,624,610,769,331,131,704,2,499,641,660,578,337,304,277,208,613,768,754,590,606,26,618,739,503,601,607,585,596,765,320,547,687)) AND VersionStart <= 9947 AND VersionEnd >= 9947) AS T GROUP BY T.entry
end;

procedure TDBCExport.ShowDBC;
var
  X, Y: Integer;
  Text: string;
begin
  with DBC do begin
      // Display DBC data
      if DisplayData then
      for Y := 0 to Length(Cells) - 1 do begin
        Text := '';
        for X := 0 to Length(Cells[Y]) - 1 do
         if VarIsStr(Cells[Y, X]) then Text := Text + '"' + Cells[Y, X] + '", '
          else Text := Text + IntToStr(Cells[Y, X]) + ', ';
        WriteLn(Text);
      end;
  end;
end;

procedure TDBCExport.LoadDBC;
var
  I: Integer;
begin
  DBC := TDBC.Create;
  with DBC do begin
    if FileExists(DBCFileName) then begin
      LoadFromFile(DBCFileName);

      // Load strings for string columns
      for I := 1 to Length(ColumnTypeDefinition) do
        if ColumnTypeDefinition[I] = 's' then begin
          LoadColumnStrings(I - 1);
          LastIndexStringColumns := I;
        end;
    end else WriteLn('File ' + DBCFileName + ' not exists.');
  end;
end;

procedure TDBCExport.SaveDBC;
begin
  with DBC do begin
    if FileExists(DBCFileName) then
      if not DirectoryExists(ExtractFileDir(NewDBCFileName)) then
        mkdir(ExtractFileDir(NewDBCFileName));
      SaveToFile(NewDBCFileName);
    Free;
  end;
end;

// Function get data from database and replace text in DBC
procedure TDBCExport.ReplaceText;
var
  DBRows : TDbRows;
  Text: string;
  X, Y, I, Entry: Integer;
  IndexRowData: Integer;
begin
  with DBC do begin
    if (SQLquery <> '') then begin
      Database.Connect;
      DBRows := Database.Query(SQLquery);

      CreateIndexTable(DBRows);

      for Y := 0 to Length(DBC.Cells) - 1 do begin
        Entry := Cells[Y, 0];
        if (Length(IndexTable) > Entry) then
          IndexRowData := IndexTable[entry]
        else IndexRowData := 0;

        I := 1;
        if (IndexRowData <> 0) then begin
          for X := 1 to Length(ColumnTypeDefinition) do begin
            if ColumnTypeDefinition[X] = 's' then begin
              Text := DBRows.Data[IndexRowData - 1].Values['Text' + IntToStr(I)];
              SetString(Y, X - 1, Text);
              I := I + 1;
              if (LastIndexStringColumns = X) then Break;
            end;
          end;
        end;
      end;
      DBRows.Destroy;
    end;
  end;
end;

// Create table index = entry, value = Index-1 DBRows, notfound = 0
procedure TDBCExport.CreateIndexTable(var DbRows: TDbRows);
var
  I: Integer;
  Count, Entry: Integer;
begin
  try
    Count := DBRows.Count;
    for I := 1 to Count do begin
      Entry := StrToInt(DBRows.Data[I - 1].Values['Entry']);

      if (I = 127) then SetLength(IndexTable, Entry + 1);

      if (Length(IndexTable) - 1 < Entry) then
         SetLength(IndexTable, Entry + 1);

       IndexTable[Entry] := I;
    end;
  except
  end;
end;

function TDBCExport.GetIDbyEntry(Entry: Integer; var DBRows: TDBRows): Integer;
var
  I: Integer;
begin
  try
    for I := 0 to DBRows.Count - 1 do begin
      if (StrToInt(DBRows.Data[i].Values['Entry']) = Entry) then begin
        Result := I;
        Exit;
      end;
    end;
  except
  end;
  Result := -1;
end;

var
  Application: TDBCExport;

{$IFDEF WINDOWS}{$R DBCExport.rc}{$ENDIF}

{$R DBCExport.res}

begin
  Application := TDBCExport.Create(nil);
  Application.Run;
  Application.Free;
end.