source: trunk/View.pas

unit View;

interface

uses
  Classes, SysUtils, Items, DOM;

type
  { TView }

  TView = class(TItem)
  private
    FDestRect: TRect;
    FSourceRect: TRect;
    FZoom: Double;
    procedure SetDestRect(AValue: TRect);
    procedure SetSourceRect(AValue: TRect);
    procedure SetZoom(AValue: Double);
  public
    procedure Assign(Source: TItem); override;
    function PointDestToSrc(Pos: TPoint): TPoint;
    function PointSrcToDest(Pos: TPoint): TPoint;
    constructor Create;
    procedure LoadFromXmlNode(Node: TDOMNode); override;
    procedure SaveToXmlNode(Node: TDOMNode); override;
    property SourceRect: TRect read FSourceRect write SetSourceRect;
    property DestRect: TRect read FDestRect write SetDestRect;
    property Zoom: Double read FZoom write SetZoom;
  end;


implementation

uses
  Geometric, XML;

resourcestring
  SZeroZoomNotAlowed = 'Zero zoom not allowed';

{ TView }

procedure TView.SetDestRect(AValue: TRect);
var
  Diff: TPoint;
begin
  if RectEquals(FDestRect, AValue) then Exit;
  Diff := Point(Trunc((DestRect.Right - DestRect.Left) / Zoom - (AValue.Right - AValue.Left) / Zoom) div 2,
    Trunc((DestRect.Bottom - DestRect.Top) / Zoom - (AValue.Bottom - AValue.Top) / Zoom) div 2);
  FDestRect := AValue;
  FSourceRect := Bounds(FSourceRect.Left + Diff.X, FSourceRect.Top + Diff.Y,
    Trunc((DestRect.Right - DestRect.Left) / Zoom),
    Trunc((DestRect.Bottom - DestRect.Top) / Zoom));
end;

procedure TView.SetSourceRect(AValue: TRect);
var
  ZX: Double;
  ZY: Double;
begin
  if RectEquals(FSourceRect, AValue) then Exit;
  FSourceRect := AValue;
  if ((FSourceRect.Right - FSourceRect.Left) <> 0) and
  ((FSourceRect.Bottom - FSourceRect.Top) <> 0) then begin
    ZX := (FDestRect.Right - FDestRect.Left) / (FSourceRect.Right - FSourceRect.Left);
    ZY := (FDestRect.Bottom - FDestRect.Top) / (FSourceRect.Bottom - FSourceRect.Top);
    if ZX > ZY then
      Zoom := ZY
      else Zoom := ZX;
  end else Zoom := 1;
end;

procedure TView.SetZoom(AValue: Double);
begin
  if FZoom = AValue then Exit;
  if AValue = 0 then
    raise Exception.Create(SZeroZoomNotAlowed);
  FZoom := AValue;
  FSourceRect := Bounds(Trunc(FSourceRect.Left + (FSourceRect.Right - FSourceRect.Left) div 2 - (DestRect.Right - DestRect.Left) / Zoom / 2),
    Trunc(FSourceRect.Top +  (FSourceRect.Bottom - FSourceRect.Top) div 2 - (FDestRect.Bottom - DestRect.Top) / Zoom / 2),
    Trunc((DestRect.Right - DestRect.Left) / Zoom),
    Trunc((DestRect.Bottom - DestRect.Top) / Zoom));
end;

procedure TView.Assign(Source: TItem);
begin
  if Source is TView then begin
    FDestRect := TView(Source).FDestRect;
    FSourceRect := TView(Source).FSourceRect;
    FZoom := TView(Source).FZoom;
  end;
end;

function TView.PointDestToSrc(Pos: TPoint): TPoint;
begin
  Result := Point(Trunc(Pos.X / FZoom + FSourceRect.Left),
    Trunc(Pos.Y / FZoom + FSourceRect.Top));
end;

function TView.PointSrcToDest(Pos: TPoint): TPoint;
begin
  Result := Point(Trunc((Pos.X - FSourceRect.Left) * FZoom),
    Trunc((Pos.Y - FSourceRect.Top) * FZoom));
end;

constructor TView.Create;
begin
  Zoom := 1;
end;

procedure TView.LoadFromXmlNode(Node: TDOMNode);
begin
  inherited;
  FZoom := ReadDouble(Node, 'Zoom', 0);
  FSourceRect.Left := ReadInteger(Node, 'SourceRectLeft', 0);
  FSourceRect.Top := ReadInteger(Node, 'SourceRectTop', 0);
  FSourceRect.Right := ReadInteger(Node, 'SourceRectRight', 0);
  FSourceRect.Bottom := ReadInteger(Node, 'SourceRectBottom', 0);
  FDestRect.Left := ReadInteger(Node, 'DestRectLeft', 0);
  FDestRect.Top := ReadInteger(Node, 'DestRectTop', 0);
  FDestRect.Right := ReadInteger(Node, 'DestRectRight', 0);
  FDestRect.Bottom := ReadInteger(Node, 'DestRectBottom', 0);
end;

procedure TView.SaveToXmlNode(Node: TDOMNode);
begin
  inherited;
  WriteDouble(Node, 'Zoom', FZoom);
  WriteInteger(Node, 'SourceRectLeft', FSourceRect.Left);
  WriteInteger(Node, 'SourceRectTop', FSourceRect.Top);
  WriteInteger(Node, 'SourceRectRight', FSourceRect.Right);
  WriteInteger(Node, 'SourceRectBottom', FSourceRect.Bottom);
  WriteInteger(Node, 'DestRectLeft', FDestRect.Left);
  WriteInteger(Node, 'DestRectTop', FDestRect.Top);
  WriteInteger(Node, 'DestRectRight', FDestRect.Right);
  WriteInteger(Node, 'DestRectBottom', FDestRect.Bottom);
end;

end.