source: tags/1.3.0/UCity.pas

unit UCity;

interface

uses
  Classes, SysUtils, Graphics, Generics.Collections, URegistry;

type

  { TCity }

  TCity = class
    SysName: string;
    Name: string;
    Population: Integer;
    Locked: Boolean;
    LineColors: array of TColor;
    InitialLineCount: Integer;
    PassengersCountToUnlock: Integer;
    HighestServedPassengerCount: Integer;
    HighestServedDaysCount: Integer;
    procedure LoadFromRegistry(Context: TRegistryContext);
    procedure SaveToRegistry(Context: TRegistryContext);
    constructor Create;
  end;

  { TCities }

  TCities = class(TObjectList<TCity>)
    function AddNew(SysName, Name: string; Population: Integer): TCity;
    procedure LoadFromRegistry(Context: TRegistryContext);
    procedure SaveToRegistry(Context: TRegistryContext);
  end;

const
  clDarkYellow = TColor($00dede);
  clOrange = TColor($0080ff);
  clBrown = TColor($003090);
  clCyan = TColor($FFFF00);
  clPink = TColor($ff69b4);


implementation

{ TCity }

procedure TCity.LoadFromRegistry(Context: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    CurrentContext := Context;
    Locked := ReadBoolWithDefault('Locked', Locked);
    HighestServedPassengerCount := ReadIntegerWithDefault('HighestServedPassengerCount', HighestServedPassengerCount);
    HighestServedDaysCount := ReadIntegerWithDefault('HighestServedDaysCount', HighestServedDaysCount);
  finally
    Free;
  end;
end;

procedure TCity.SaveToRegistry(Context: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    CurrentContext := Context;
    WriteBool('Locked', Locked);
    WriteInteger('HighestServedPassengerCount', HighestServedPassengerCount);
    WriteInteger('HighestServedDaysCount', HighestServedDaysCount);
  finally
    Free;
  end;
end;

constructor TCity.Create;
begin
  PassengersCountToUnlock := 500;
  InitialLineCount := 1;
  LineColors := [clBlue, clRed, clDarkYellow, clGreen,
     clPurple, clGray, clOrange, clBrown, clCyan];
end;

{ TCities }

function TCities.AddNew(SysName, Name: string; Population: Integer): TCity;
begin
  Result := TCity.Create;
  Result.SysName := SysName;
  Result.Name := Name;
  Result.Population := Population;
  Add(Result);
end;

procedure TCities.LoadFromRegistry(Context: TRegistryContext);
var
  City: TCity;
begin
  for City in Self do begin
    City.LoadFromRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\' + City.SysName));
  end;
end;

procedure TCities.SaveToRegistry(Context: TRegistryContext);
var
  City: TCity;
begin
  for City in Self do begin
    City.SaveToRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\' + City.SysName));
  end;
end;

end.