source: trunk/USubversion.pas

unit USubversion;

interface

uses
  Classes, SysUtils, Process, FileUtil, UExecute
  {$IFDEF UNIX}, baseunix{$ENDIF};

type
  TSubversionInfo = record
    Checksum: string;
    Revision: string;
    URL: string;
    Path: string;
  end;

  { TSubversion }

  TSubversion = class(TExecute)
  private
  protected
    function GetExecutable: string; override;
  public
    function GetInfo(Text: string): TSubversionInfo;
  end;

  { TSubversionAdmin }

  TSubversionAdmin = class(TExecute)
  protected
    function GetExecutable: string; override;
  public
  end;

procedure MakeFileWriteable(FileName: string);


implementation

function TSubversion.GetInfo(Text: string): TSubversionInfo;
var
  Index: Integer;
  Lines: TStringList;
  I: Integer;
  Line: string;
  Name: string;
  Value: string;
begin
  Lines := TStringList.Create;
  try
    Lines.Text := Text;
    for I := 0 to Lines.Count - 1 do begin
      Line := Trim(Lines[I]);
      Index := Pos(':', Line);
      if Index > 0 then begin
        Name := Trim(Copy(Line, 1, Index - 1));
        Value := Trim(Copy(Line, Index + 1, MaxInt));
        if Name = 'Checksum' then Result.Checksum := Value
        else if Name = 'Revision' then Result.Revision := Value
        else if Name = 'Path' then Result.Path := Value
        else if Name = 'URL' then Result.URL := Value;
      end;
    end;
  finally
    Lines.Free;
  end;
end;

{ TSubversionAdmin }

function TSubversionAdmin.GetExecutable: string;
begin
  {$IFDEF UNIX}
  Result := '/usr/bin/svnadmin';
  {$ENDIF}
  {$IFDEF WINDOWS}
  Result := 'c:\Program Files\Subversion\bin\svnadmin.exe';
  if not FileExists(Result) then
    Result := 'C:\Program Files\TortoiseSVN\bin\svnadmin.exe';
  {$ENDIF}
end;

{ TSubversion }

function TSubversion.GetExecutable: string;
begin
  {$IFDEF UNIX}
  Result := '/usr/bin/svn';
  {$ENDIF}
  {$IFDEF WINDOWS}
  Result := 'c:\Program Files\Subversion\bin\svn.exe';
  if not FileExists(Result) then
    Result := 'C:\Program Files\TortoiseSVN\bin\svn.exe';
  {$ENDIF}
end;

procedure MakeFileWriteable(FileName: string);
var
  {$IFDEF WINDOWS}
  FileAttributes: Integer;
  {$ENDIF}
  {$IFDEF UNIX}
  FileStat: stat;
  {$ENDIF}
begin
  {$IFDEF WINDOWS}
  FileAttributes := FileGetAttr(FileName);
  if (FileAttributes and faReadOnly) > 0 then
    FileSetAttr(FileName, FileAttributes xor faReadOnly);
  {$ENDIF}
  {$IFDEF UNIX}
  FileStat := default(stat);
  fpstat(FileName, FileStat);
  if (FileStat.st_mode and 200) = 0 then
    fpchmod(FileName, FileStat.st_mode or 200);
  {$ENDIF}
end;

end.