source: branches/bigint/Disassembler.pas

unit Disassembler;

interface

uses
  Classes, SysUtils, Cpu, Instructions, StrUtils, IntMemory, Int;

type

  { TDisassembler }

  TDisassembler = class
    InstructionSet: TInstructionSet;
    Memory: TIntMemory;
    procedure Disassemble(Lines: TStrings);
    procedure SaveToFile(FileName: string);
    constructor Create;
    destructor Destroy; override;
  end;


implementation

procedure TDisassembler.Disassemble(Lines: TStrings);
var
  I: Integer;
  Value: TInt;
  Instruction: TInstruction;
  InstructionInfo: TInstructionInfo;
  Line: string;
  InstText: string;
  InstBytes: string;
begin
  Memory.Position := 0;
  while Memory.Position < Memory.Size do begin
    Line := IntToHex(Memory.Position, 8) + ' ';
    Value := Memory.ReadPos;
    InstBytes := IntToHex(Value, 2) + ' ';
    InstText := '';
    if (Value >= 0) and (Value <= Integer(High(TInstruction))) then begin
      Instruction := TInstruction(Value);
      InstructionInfo := InstructionSet.SearchInstruction(Instruction);
      if Assigned(InstructionInfo) then begin
        InstText := InstructionInfo.Name;
        for I := 0 to Length(InstructionInfo.Params) - 1 do begin
          Value := Memory.ReadPos;
          InstBytes := InstBytes + IntToHex(Value, 2) + ' ';
          if I > 0 then
            InstText := InstText + ', ' else
            InstText := InstText + ' ';
          if InstructionInfo.Params[I] = ptNumber then begin
            InstText := InstText + IntToHex(Value, 8);
          end else
          if InstructionInfo.Params[I] = ptIndirect then begin
            InstText := InstText + '(' + IntToStr(Value) + ')';
          end else
          if InstructionInfo.Params[I] = ptIndirect2 then begin
            InstText := InstText + '((' + IntToStr(Value) + '))';
          end else raise Exception.Create('Unsupported instruction parameter type');
        end;
        InstBytes := InstBytes + DupeString(' ', 13 - Length(InstBytes));
      end;
    end;
    Line := Line + InstBytes + InstText;
    Lines.Add(Line);
  end;
end;

procedure TDisassembler.SaveToFile(FileName: string);
var
  Lines: TStringList;
begin
  Lines := TStringList.Create;
  Disassemble(Lines);
  Lines.SaveToFile(FileName);
  Lines.Free;
end;

constructor TDisassembler.Create;
begin
  InstructionSet := TInstructionSet.Create;
end;

destructor TDisassembler.Destroy;
begin
  FreeAndNil(InstructionSet);
  inherited;
end;

end.