source: branches/ByteArray/Forms/FormStorage.pas

unit FormStorage;

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, Storage,
  Device;

type

  { TFormStorage }

  TFormStorage = class(TFormDevice)
    ListView1: TListView;
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
  protected
    function GetDevice: TDevice; override;
    procedure SetDevice(AValue: TDevice); override;
  public
    Storage: TStorage;
    procedure Reload;
  end;


implementation

{$R *.lfm}

const
  ItemsPerLine = 16;

{ TFormStorage }

procedure TFormStorage.ListView1Data(Sender: TObject; Item: TListItem);
var
  Line: string;
  I: Integer;
  Text: string;
  One: Byte;
begin
  if Item.Index < Storage.Size div ItemsPerLine then begin
    Line := '';
    Text := '';
    for I := 0 to ItemsPerLine - 1 do begin
      One := Storage.ReadByte(Item.Index * ItemsPerLine + I);
      Line := Line + IntToHex(One, 2) + ' ';
      if One >= 32 then Text := Text + Char(One)
        else Text := Text + ' ';
    end;
    Item.Caption := IntToHex(Item.Index * ItemsPerLine, 8);
    Item.SubItems.Add(Line);
    Item.SubItems.Add(Text);
  end;
end;

procedure TFormStorage.FormShow(Sender: TObject);
begin
  Reload;
end;

function TFormStorage.GetDevice: TDevice;
begin
  Result := Storage;
end;

procedure TFormStorage.SetDevice(AValue: TDevice);
begin
  if AValue is TStorage then
    Storage := TStorage(AValue);
end;

procedure TFormStorage.Reload;
begin
  ListView1.Items.Count := Storage.Size div ItemsPerLine;
  ListView1.Refresh;
end;

end.