source: branches/ByteArray/Forms/FormMemory.pas

unit FormMemory;

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ComCtrls, ExtCtrls,
  Menus, IntMemory, FormEx;

type

  { TFormMemory }

  TFormMemory = class(TFormEx)
    ListViewMemory: TListView;
    MainMenu1: TMainMenu;
    MenuItem1: TMenuItem;
    MenuItemClear: TMenuItem;
    Timer1: TTimer;
    procedure FormShow(Sender: TObject);
    procedure ListViewMemoryData(Sender: TObject; Item: TListItem);
    procedure MenuItemClearClick(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  public
    Memory: TMemory;
    procedure Reload;
  end;

const
  ItemsPerLine = 16;


implementation

{$R *.lfm}

procedure TFormMemory.Reload;
begin
  ListViewMemory.Items.Count := Memory.Size div ItemsPerLine;
  ListViewMemory.Refresh;
end;

procedure TFormMemory.ListViewMemoryData(Sender: TObject; Item: TListItem);
var
  Line: string;
  I: Integer;
  Text: string;
  One: Byte;
begin
  if Item.Index < Memory.Size div ItemsPerLine then begin
    Line := '';
    Text := '';
    for I := 0 to ItemsPerLine - 1 do begin
      One := Memory.Read(Item.Index * ItemsPerLine + I, 1);
      Line := Line + IntToHex(One, 2) + ' ';
      if One >= 32 then Text := Text + Char(One)
        else Text := Text + ' ';
    end;
    Item.Caption := IntToHex(Item.Index * ItemsPerLine, 8);
    Item.SubItems.Add(Line);
    Item.SubItems.Add(Text);
  end;
end;

procedure TFormMemory.MenuItemClearClick(Sender: TObject);
begin
  Memory.FillZero;
  Reload;
end;

procedure TFormMemory.FormShow(Sender: TObject);
begin
  Reload;
end;

procedure TFormMemory.Timer1Timer(Sender: TObject);
begin
  if Visible then Reload;
end;

end.