source: trunk/Memory.pas

unit Memory;

interface

uses
  Classes, SysUtils, Generics.Collections;

type

  { TMemory }

  TMemory = class
  private
    function GetSize: Integer; virtual;
    procedure SetSize(AValue: Integer); virtual;
  public
    Position: Integer;
    function Read(Address: Word): Byte; virtual;
    procedure Write(Address: Word; Data: Byte); virtual;
    function ReadByte: Byte;
    function ReadWord: Word;
    procedure LoadFromFile(FileName: string); virtual;
    destructor Destroy; override;
    property Size: Integer read GetSize write SetSize;
  end;

  { TMemoryData }

  TMemoryData = class(TMemory)
    DataPtr: PByte;
    function GetSize: Integer; override;
    procedure SetSize(AValue: Integer); override;
    function Read(Address: Word): Byte; override;
    procedure Write(Address: Word; Data: Byte); override;
    procedure LoadFromFile(FileName: string); override;
  end;

  { TMemoryMappedArea }

  TMemoryMappedArea = class
    Base: Word;
    Memory: TMemory;
    function InRange(Address: Word): Boolean;
  end;

  { TMemoryMappedAreas }

  TMemoryMappedAreas = class(TObjectList<TMemoryMappedArea>)
    function AddNew(Base: Word; Memory: TMemory): TMemoryMappedArea;
  end;

 { TMemoryMapped }

  TMemoryMapped = class(TMemory)
  private
    FSize: Integer;
  public
    Areas: TMemoryMappedAreas;
    function GetSize: Integer; override;
    procedure SetSize(AValue: Integer); override;
    function Read(Address: Word): Byte; override;
    procedure Write(Address: Word; Data: Byte); override;
    constructor Create;
    destructor Destroy; override;
  end;


implementation

{ TMemoryMappedAreas }

function TMemoryMappedAreas.AddNew(Base: Word; Memory: TMemory): TMemoryMappedArea;
begin
  Result := TMemoryMappedArea.Create;
  Result.Base := Base;
  Result.Memory := Memory;
  Add(Result);
end;

{ TMemoryMappedArea }

function TMemoryMappedArea.InRange(Address: Word): Boolean;
begin
  Result := (Address >= Base) and (Address < (Base + Memory.Size));
end;

{ TMemoryMapped }

function TMemoryMapped.GetSize: Integer;
begin
  Result := FSize;
end;

procedure TMemoryMapped.SetSize(AValue: Integer);
begin
  FSize := AValue;
end;

function TMemoryMapped.Read(Address: Word): Byte;
var
  I: Integer;
begin
  for I := 0 to Areas.Count - 1 do
    if Areas[I].InRange(Address) then begin
      Result := Areas[I].Memory.Read(Address - Areas[I].Base);
      Break;
    end;
end;

procedure TMemoryMapped.Write(Address: Word; Data: Byte);
var
  I: Integer;
begin
  for I := 0 to Areas.Count - 1 do
    if Areas[I].InRange(Address) then begin
      Areas[I].Memory.Write(Address - Areas[I].Base, Data);
      Break;
    end;
end;

constructor TMemoryMapped.Create;
begin
  inherited;
  Areas := TMemoryMappedAreas.Create;
end;

destructor TMemoryMapped.Destroy;
begin
  FreeAndNil(Areas);
  inherited;
end;

{ TMemoryData }

function TMemoryData.GetSize: Integer;
begin
  Result := MemSize(DataPtr);
end;

procedure TMemoryData.SetSize(AValue: Integer);
begin
  ReAllocMem(DataPtr, AValue);
end;

function TMemoryData.Read(Address: Word): Byte;
begin
  Result := PByte(DataPtr + Address)^;
end;

procedure TMemoryData.Write(Address: Word; Data: Byte);
begin
  PByte(DataPtr + Address)^ := Data;
end;

procedure TMemoryData.LoadFromFile(FileName: string);
var
  FileStream: TFileStream;
begin
  FileStream := TFileStream.Create(FileName, fmOpenRead);
  try
    Size := FileStream.Size;
    FileStream.Read(DataPtr^, FileStream.Size);
  finally
    FreeAndNil(FileStream);
  end;
end;

{ TMemory }

function TMemory.GetSize: Integer;
begin
  Result := 0;
end;

procedure TMemory.SetSize(AValue: Integer);
begin

end;

function TMemory.Read(Address: Word): Byte;
begin
  Result := 0;
end;

procedure TMemory.Write(Address: Word; Data: Byte);
begin
end;

function TMemory.ReadByte: Byte;
begin
  if Position < Size then Result := Read(Position)
    else Result := 0;
  Position := Position + SizeOf(Byte);
end;

function TMemory.ReadWord: Word;
begin
  Result := Read(Position) or (Read(Position + 1) shl 8);
  Position := Position + SizeOf(Word);
end;

procedure TMemory.LoadFromFile(FileName: string);
begin
end;

destructor TMemory.Destroy;
begin
  Size := 0;
  inherited;
end;

end.