source: trunk/UFioAPI.pas

unit UFioAPI;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, httpsend, ssl_openssl, dateutils;

type

  TFioDataFormat = (dfXML, dfCVS, dfGPC, dfOFX, dfJSON, dfHTML, dfSTA);

  { TFioAPI }

  TFioAPI = class
  private
    function Download(URL: string; Data: TStrings): Boolean;
  public
    Token: string;
    Format: TFioDataFormat;
    function DownloadInterval(TimeFrom, TimeTo: TDateTime; Data: TStrings): Boolean;
    function DownloadMonthly(Year, Id: Integer; Data: TStrings): Boolean;
    function DownloadLast(Data: TStrings): Boolean;
    function SetLastId(Id: Integer): Boolean;
    function SetLastDate(Date: TDate): Boolean;
  end;

const
  DataFormatText: array[TFioDataFormat] of string = ('XML', 'CSV', 'GPC', 'OFX',
    'JSON', 'HTML', 'STA');
  DataFormatURL: array[TFioDataFormat] of string = ('xml', 'csv', 'gpc', 'ofx',
    'json', 'html', 'sta');

implementation

{ TFioAPI }

function TFioAPI.Download(URL: string; Data: TStrings): Boolean;
var
  HTTPSender: THTTPSend;
begin
  HTTPSender := THTTPSend.Create;
  try
    HTTPSender.HTTPMethod('GET', URL);
    try
    case HTTPSender.Resultcode of
        100..299:
          begin
            if Assigned(Data) then
              Data.LoadFromStream(HTTPSender.Document);
            Result := True;
          end; //informational, success
        300..399: Result := False; //redirection. Not implemented, but could be.
        400..499: Result := False; //client error; 404 not found etc
        500..599: Result := False; //internal server error
        else Result := False; //unknown code
      end;
    except
      // We don't care for the reason for this error; the download failed.
      Result := False;
    end;
  finally
    HTTPSender.Free;
  end;
end;

function TFioAPI.DownloadInterval(TimeFrom, TimeTo: TDateTime; Data: TStrings
  ): Boolean;
begin
  Result := Download('https://www.fio.cz/ib_api/rest/periods/' + Token +
    '/' + FormatDateTime('yyyy-mm-dd', TimeFrom) +
    '/' + FormatDateTime('yyyy-mm-dd', TimeTo) +
    '/transactions.' + DataFormatURL[Format], Data);
end;

function TFioAPI.DownloadMonthly(Year, Id: Integer; Data: TStrings): Boolean;
begin
  Result := Download('https://www.fio.cz/ib_api/rest/by-id/' + Token +
    '/' + IntToStr(Year) + '/' + IntToStr(Id) +
    '/transactions.' + DataFormatURL[Format], Data);
end;

function TFioAPI.DownloadLast(Data: TStrings): Boolean;
begin
  Result := Download('https://www.fio.cz/ib_api/rest/last/' + Token +
    '/transactions.' + DataFormatURL[Format], Data);
end;

function TFioAPI.SetLastId(Id: Integer): Boolean;
begin
  Result := Download('https://www.fio.cz/ib_api/rest/set-last-id/' + Token +
    '/' + IntToStr(Id), nil);
end;

function TFioAPI.SetLastDate(Date: TDate): Boolean;
begin
  Result := Download('https://www.fio.cz/ib_api/rest/set-last-date/' + Token +
    '/' + IntToStr(YearOf(Date)) + '/' + IntToStr(MonthOf(Date)) + '/' +
    IntToStr(DayOf(Date)), nil);
end;

end.