source: trunk/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Registry, Classes, SysUtils, FileUtil, USqlDatabase, URegistry, Forms,
  UApplicationInfo, UCoolTranslator, UPersistentForm, UModularSystem,
  UFormModuleList;

type

  { TCore }

  TCore = class(TDataModule)
    ApplicationInfo1: TApplicationInfo;
    CoolTranslator1: TCoolTranslator;
    Database: TSqlDatabase;
    ModuleManager: TModuleManager;
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure ModuleManagerUpdate(Sender: TObject);
  private
  public
    FormModuleList: TFormModuleList;
    FormList: TForm;
    PersistentForm: TPersistentForm;
    RegistryContext: TRegistryContext;
    procedure Init;
    procedure Done;
    procedure InitData;
    procedure Connect;
    procedure LoadFromRegistry(AContext: TRegistryContext);
    procedure SaveToRegistry(AContext: TRegistryContext);
  end;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  URegistredModules, UFormMain;


{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  PersistentForm := TPersistentForm.Create;
  PersistentForm.RegistryContext := RegContext(HKEY(ApplicationInfo1.RegistryRoot),
    ApplicationInfo1.RegistryKey + '\Forms');
  RegistryContext := RegContext(HKEY(ApplicationInfo1.RegistryRoot), ApplicationInfo1.RegistryKey);
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(PersistentForm);
end;

procedure TCore.ModuleManagerUpdate(Sender: TObject);
begin
  if Assigned(FormModuleList) then
    FormModuleList.Reload;
  FormMain.ReloadPages;
end;

procedure TCore.Init;
begin
  LoadFromRegistry(RegistryContext);

  try
    ModuleManager.Modules.BeginUpdate;

    // Init modules
    with TRegistryEx.Create do
    try
      Context := RegistryContext;
      RegisterModules(ModuleManager);
      if ReadBoolWithDefault('ModuleManagerInstalled', False) then
        ModuleManager.LoadFromRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'))
        else begin
          ModuleManager.Modules.Perform([maEnable]);
          ModuleManager.SaveToRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'));
          WriteBool('ModuleManagerInstalled', True);
        end;
    finally
      Free;
    end;
    ModuleManager.Modules.Perform([maStart], [mcEnabled]);
  finally
    ModuleManager.Modules.EndUpdate;
  end;
end;

procedure TCore.Done;
begin
  SaveToRegistry(RegistryContext);
  FormMain.Hide; // Speed up undocking with hidden main form
  ModuleManager.SaveToRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'));
  if Assigned(FormModuleList) then FreeAndNil(FormModuleList);
  ModuleManager.OnUpdate := nil;
  UnregisterModules(ModuleManager);
end;

procedure TCore.InitData;
var
  DbRows: TDbRows;
begin
  try
    DbRows := TDbRows.Create;
    Database.Query(DbRows, '');
  finally
    DbRows.Free;
  end;
end;

procedure TCore.Connect;
begin
  Database.Connect;
end;

procedure TCore.LoadFromRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    Database.HostName := ReadStringWithDefault('HostName', 'localhost');
    Database.Database := ReadStringWithDefault('Schema', 'dochazka');
    Database.UserName := ReadStringWithDefault('UserName', 'dochazka');
    Database.Password := ReadStringWithDefault('Password', '');
    CoolTranslator1.Language := CoolTranslator1.Languages.SearchByCode(ReadStringWithDefault('Language', ''));
  finally
    Free;
  end;
end;

procedure TCore.SaveToRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    WriteString('HostName', Database.HostName);
    WriteString('Schema', Database.Database);
    WriteString('UserName', Database.UserName);
    WriteString('Password', Database.Password);
    WriteString('Language', CoolTranslator1.Language.Code);
  finally
    Free;
  end;
end;

end.