source: trunk/Packages/Common/UPersistentForm.pas

unit UPersistentForm;

{$mode delphi}

// Date: 2010-06-01

interface

uses
  Classes, SysUtils, Forms, URegistry, LCLIntf, Registry;

type

  { TPersistentForm }

  TPersistentForm = class
  public
    RegistryContext: TRegistryContext;
    procedure Load(Form: TForm);
    procedure Save(Form: TForm);
    constructor Create;
  end;

implementation

{ TPersistentForm }

procedure TPersistentForm.Load(Form: TForm);
var
  RestoredLeft, RestoredTop, RestoredWidth, RestoredHeight: Integer;
  NormalLeft, NormalTop, NormalWidth, NormalHeight: Integer;
  RestoredWindowState: TWindowState;
begin
  with TRegistryEx.Create do
    try
      RootKey := RegistryContext.RootKey;
      OpenKey(RegistryContext.Key + '\' + Form.Name, True);

      RestoredWindowState := TWindowState(ReadIntegerWithDefault('WindowState', Integer(Form.WindowState)));
      if RestoredWindowState = wsMinimized then
        RestoredWindowState := wsNormal;
      Form.WindowState := RestoredWindowState;

      if RestoredWindowState = wsNormal then begin
      NormalLeft := ReadIntegerWithDefault('Left', (Screen.Width - Form.Width) div 2);
      NormalTop := ReadIntegerWithDefault('Top', (Screen.Height - Form.Height) div 2);
      NormalWidth := ReadIntegerWithDefault('Width', Form.Width);
      NormalHeight := ReadIntegerWithDefault('Height', Form.Height);

      if NormalLeft < Screen.DesktopLeft then
        NormalLeft := Screen.DesktopLeft;
      if NormalLeft > (Screen.DesktopWidth - 50) then
        NormalLeft := Screen.DesktopWidth - 50;
      if NormalTop < Screen.DesktopTop then
        NormalTop := Screen.DesktopTop;
      if NormalTop > (Screen.DesktopHeight - 50) then
        NormalTop := Screen.DesktopHeight - 50;
      if (NormalLeft <> Form.Left) or (NormalTop <> Form.Top) or
      (NormalHeight <> Form.Height) or (NormalWidth <> Form.Width) then
        Form.SetBounds(NormalLeft, NormalTop, NormalWidth, NormalHeight);
      end;

      if RestoredWindowState = wsMaximized then begin
        RestoredWidth := ReadIntegerWithDefault('RestoredWidth', Form.Width);
        RestoredHeight := ReadIntegerWithDefault('RestoredHeight', Form.Height);
        RestoredTop := ReadIntegerWithDefault('RestoredTop', (Screen.Height - Form.Height) div 2);
        RestoredLeft := ReadIntegerWithDefault('RestoredLeft', (Screen.Width - Form.Width) div 2);
        if (RestoredLeft <> Form.RestoredLeft) or (RestoredTop <> Form.RestoredTop) or
        (RestoredHeight <> Form.RestoredHeight) or (RestoredWidth <> Form.RestoredWidth) then
          Form.SetRestoredBounds(RestoredLeft, RestoredTop, RestoredWidth, RestoredHeight);
      end;

      //if ReadBoolWithDefault('Visible', False) then Form.Show;
    finally
      Free;
    end;
end;

procedure TPersistentForm.Save(Form: TForm);
begin
  with Form, TRegistryEx.Create do
    try
      RootKey := RegistryContext.RootKey;
      OpenKey(RegistryContext.Key + '\' + Form.Name, True);
      WriteInteger('Width', Form.Width);
      WriteInteger('Height', Form.Height);
      WriteInteger('Top', Form.Top);
      WriteInteger('Left', Form.Left);
      WriteInteger('WindowState', Integer(Form.WindowState));
      WriteInteger('RestoredWidth', Form.RestoredWidth);
      WriteInteger('RestoredHeight', Form.RestoredHeight);
      WriteInteger('RestoredTop', Form.RestoredTop);
      WriteInteger('RestoredLeft', Form.RestoredLeft);
      WriteBool('Visible', Form.Visible);
    finally
      Free;
    end;
end;

constructor TPersistentForm.Create;
begin
  RegistryContext.RootKey := HKEY_CURRENT_USER;
end;

end.