source: trunk/Packages/ChronisPlatform/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Registry, Classes, SysUtils, FileUtil, USqlDatabase, URegistry, Forms,
  UApplicationInfo, UCoolTranslator, UPersistentForm, UModularSystem,
  UFormModuleList;

type
  TChronisPlatform = class;

  { TCore }

  TCore = class(TDataModule)
    CoolTranslator1: TCoolTranslator;
    Database: TSqlDatabase;
    ModuleManager: TModuleManager;
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure ModuleManagerUpdate(Sender: TObject);
  private
    FRegistryContext: TRegistryContext;
    procedure SetRegistryContext(AValue: TRegistryContext);
  public
    Platform: TChronisPlatform;
    FormModuleList: TFormModuleList;
    FormList: TForm;
    PersistentForm: TPersistentForm;
    procedure Init;
    procedure Done;
    procedure InitData;
    procedure Connect;
    procedure LoadFromRegistry(AContext: TRegistryContext);
    procedure SaveToRegistry(AContext: TRegistryContext);
    property RegistryContext: TRegistryContext read FRegistryContext
      write SetRegistryContext;
  end;

  { TChronisPlatform }

  TChronisPlatform = class(TComponent)
  private
    FOnRegisterModules: TNotifyEvent;
    FOnUnregisterModules: TNotifyEvent;
    FRegistryContext: TRegistryContext;
    procedure SetRegistryContext(AValue: TRegistryContext);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    procedure Init;
    procedure Done;
    property RegistryContext: TRegistryContext read FRegistryContext
      write SetRegistryContext;
  published
    property OnRegisterModules: TNotifyEvent read FOnRegisterModules
      write FOnRegisterModules;
    property OnUnregisterModules: TNotifyEvent read FOnUnregisterModules
      write FOnUnregisterModules;
  end;

procedure Register;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  UFormMain, UFormConnection, UFormSetting;

procedure Register;
begin
  RegisterComponents('Chronis', [TChronisPlatform]);
end;

{ TChronisPlatform }

procedure TChronisPlatform.SetRegistryContext(AValue: TRegistryContext);
begin
  if FRegistryContext = AValue then Exit;
  FRegistryContext := AValue;
  if Assigned(Core) then Core.RegistryContext := AValue;
end;

constructor TChronisPlatform.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
end;

destructor TChronisPlatform.Destroy;
begin
  inherited Destroy;
end;

procedure TChronisPlatform.Init;
begin
  Application.CreateForm(TCore, Core);
  Core.Platform := Self;
  Core.RegistryContext := FRegistryContext;
  Application.CreateForm(TFormMain, FormMain); // first form
  Application.CreateForm(TFormConnection, FormConnection);
  Application.CreateForm(TFormSetting, FormSetting);
  //Core := TCore.Create(Application);
  //FormMain := TFormMain.Create(Application);
  //FormConnection := TFormConnection.Create(Application);
end;

procedure TChronisPlatform.Done;
begin
(*  FreeAndNil(FormSetting);
  FreeAndNil(FormConnection);
  FreeAndNil(FormMain);
  FreeAndNil(Core); *)
end;


{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  PersistentForm := TPersistentForm.Create;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(PersistentForm);
end;

procedure TCore.ModuleManagerUpdate(Sender: TObject);
begin
  if Assigned(FormModuleList) then
    FormModuleList.Reload;
  FormMain.ReloadPages;
end;

procedure TCore.SetRegistryContext(AValue: TRegistryContext);
begin
  if (FRegistryContext.RootKey = AValue.RootKey) and
    (FRegistryContext.Key = AValue.Key) then Exit;
  FRegistryContext := AValue;
  PersistentForm.RegistryContext := RegContext(RegistryContext.RootKey,
    RegistryContext.Key + '\Forms');
end;

procedure TCore.Init;
begin
  LoadFromRegistry(RegistryContext);

  try
    ModuleManager.Modules.BeginUpdate;

    // Init modules
    with TRegistryEx.Create do
    try
      Context := RegistryContext;
      if Assigned(Platform.OnRegisterModules) then
        Platform.OnRegisterModules(Self);
      if ReadBoolWithDefault('ModuleManagerInstalled', False) then
        ModuleManager.LoadFromRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'))
        else begin
          ModuleManager.Modules.Perform([maEnable]);
          ModuleManager.SaveToRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'));
          WriteBool('ModuleManagerInstalled', True);
        end;
    finally
      Free;
    end;
    ModuleManager.Modules.Perform([maStart], [mcEnabled]);
  finally
    ModuleManager.Modules.EndUpdate;
  end;
  Connect;
end;

procedure TCore.Done;
begin
  SaveToRegistry(RegistryContext);
  FormMain.Hide; // Speed up undocking with hidden main form
  ModuleManager.SaveToRegistry(RegContext(RegistryContext.RootKey, RegistryContext.Key + '\Modules'));
  if Assigned(FormModuleList) then FreeAndNil(FormModuleList);
  ModuleManager.OnUpdate := nil;
  if Assigned(Platform.OnUnregisterModules) then
    Platform.OnUnregisterModules(Self);
end;

procedure TCore.InitData;
var
  DbRows: TDbRows;
begin
  try
    DbRows := TDbRows.Create;
    Database.Query(DbRows, '');
  finally
    DbRows.Free;
  end;
end;

procedure TCore.Connect;
begin
  Database.Connect;
end;

procedure TCore.LoadFromRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    Database.HostName := ReadStringWithDefault('HostName', 'localhost');
    Database.Database := ReadStringWithDefault('Schema', 'dochazka');
    Database.UserName := ReadStringWithDefault('UserName', 'dochazka');
    Database.Password := ReadStringWithDefault('Password', '');
    CoolTranslator1.Language := CoolTranslator1.Languages.SearchByCode(ReadStringWithDefault('Language', ''));
  finally
    Free;
  end;
end;

procedure TCore.SaveToRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    WriteString('HostName', Database.HostName);
    WriteString('Schema', Database.Database);
    WriteString('UserName', Database.UserName);
    WriteString('Password', Database.Password);
    WriteString('Language', CoolTranslator1.Language.Code);
  finally
    Free;
  end;
end;

end.