source: trunk/Forms/UFormMain.pas

unit UFormMain;

{$mode delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Menus, ActnList, UFormList, SpecializedList, UFormEdit, UFormModuleList,
  URegistry;

type

  { TFormMain }

  TFormMain = class(TForm)
    AConnect: TAction;
    ADisconnect: TAction;
    AShowToolBar: TAction;
    AModuleList: TAction;
    ASettings: TAction;
    AExit: TAction;
    ActionList1: TActionList;
    ImageList1: TImageList;
    MainMenu1: TMainMenu;
    MenuItem1: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    MenuItem7: TMenuItem;
    MenuItem8: TMenuItem;
    MenuItem9: TMenuItem;
    MenuItemSystem: TMenuItem;
    MenuItem2: TMenuItem;
    PageControl1: TPageControl;
    StatusBar1: TStatusBar;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    procedure AConnectExecute(Sender: TObject);
    procedure ADisconnectExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure AModuleListExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AShowToolBarExecute(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure TabSheetShow(Sender: TObject);
  private
    ShowToolBar: Boolean;
    procedure FormModuleListDestroy(Sender: TObject);
  public
    DataViewLists: TListObject; // TListObject<TDataViewList>
    DataViewForms: TListObject; // TListObject<TDataViewForm>
    procedure RegisterDataViewForm(View: TDataViewForm);
    procedure RegisterDataViewList(View: TDataViewList);
    procedure UnregisterDataViewForm(View: TDataViewForm);
    procedure UnregisterDataViewList(View: TDataViewList);

    procedure ReloadPages;
    procedure UpdateInterface;
    procedure LoadFromRegistry(AContext: TRegistryContext);
    procedure SaveToRegistry(AContext: TRegistryContext);
  end;

var
  FormMain: TFormMain;

implementation

uses
  UCore, UFormSetting, UFormConnection;

{$R *.lfm}

{ TFormMain }

procedure TFormMain.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
end;

procedure TFormMain.FormCreate(Sender: TObject);
begin
  DataViewLists := TListObject.Create;
  DataViewLists.OwnsObjects := False;
  DataViewForms := TListObject.Create;
  DataViewForms.OwnsObjects := False;

  LoadFromRegistry(Core.RegistryContext);
  Core.Init;
  Core.PersistentForm.Load(Self);
  ReloadPages;
end;

procedure TFormMain.FormDestroy(Sender: TObject);
begin
  Core.Done;
  SaveToRegistry(Core.RegistryContext);
  Core.PersistentForm.Save(Self);
  FreeAndNil(DataViewForms);
  FreeAndNil(DataViewLists);
end;

procedure TFormMain.AExitExecute(Sender: TObject);
begin
  Close;
end;

procedure TFormMain.AModuleListExecute(Sender: TObject);
begin
  if not Assigned(Core.FormModuleList) then begin
    Core.FormModuleList := TFormModuleList.Create(FormMain);
    Core.FormModuleList.Manager := Core.ModuleManager;
    Core.FormModuleList.AddHandlerOnBeforeDestruction(FormModuleListDestroy);
    Core.FormModuleList.Options := [mloAllowEnable, mloShowEnable,
      mloAllowInstall,  mloShowDescription, mloShowDependencies, mloShowInfoBar,
      mloShowInstalled];
    Core.CoolTranslator1.TranslateComponentRecursive(Core.FormModuleList)
  end;
  Core.FormModuleList.Show;
end;

procedure TFormMain.AConnectExecute(Sender: TObject);
begin
  FormConnection.LoadFromDatabase(Core.Database);
  if FormConnection.ShowModal = mrOk then begin
    FormConnection.SaveToDatabase(Core.Database);
    Core.Connect;
    UpdateInterface;
  end;
end;

procedure TFormMain.ADisconnectExecute(Sender: TObject);
begin
  Core.Database.Disconnect;
  UpdateInterface;
end;

procedure TFormMain.ASettingsExecute(Sender: TObject);
begin
  FormSetting.ShowModal;
end;

procedure TFormMain.AShowToolBarExecute(Sender: TObject);
begin
  ShowToolBar := not ShowToolBar;
  UpdateInterface;
end;

procedure TFormMain.FormShow(Sender: TObject);
begin
  UpdateInterface;
end;

procedure TFormMain.TabSheetShow(Sender: TObject);
begin
  if Assigned(Core.FormList) then Core.FormList.Free;
  Core.FormList := TFormList.Create(Self);
  Core.CoolTranslator1.TranslateComponentRecursive(Core.FormList);
  with TFormList(Core.FormList) do begin
    ManualDock(TTabSheet(Sender));
    Align := alClient;
    Show;
    if TTabSheet(Sender).Tag < DataViewLists.Count then
      View := TDataViewList(DataViewLists[TTabSheet(Sender).Tag])
      else View := nil;
    UpdateData;
  end;
end;

procedure TFormMain.FormModuleListDestroy(Sender: TObject);
begin
  if Assigned(Core.FormModuleList) then Core.FormModuleList := nil;
end;

procedure TFormMain.ReloadPages;
var
  NewPage: TTabSheet;
  I: Integer;
begin
  if Assigned(Core.FormList) then FreeAndNil(Core.FormList);
  for I := PageControl1.PageCount - 1 downto 0 do
    PageControl1.Pages[I].Free;
  for I := 0 to DataViewLists.Count - 1 do
  with TDataViewList(DataViewLists[I]) do begin
    NewPage := TTabSheet.Create(PageControl1);
    NewPage.Caption := Caption;
    NewPage.Tag := I;
    NewPage.ImageIndex := ImageIndex;
    NewPage.OnShow := TabSheetShow;
    NewPage.PageControl := PageControl1;
    NewPage.Visible := True;
  end;
end;

procedure TFormMain.RegisterDataViewForm(View: TDataViewForm);
begin
  DataViewForms.Add(View);
end;

procedure TFormMain.RegisterDataViewList(View: TDataViewList);
begin
  DataViewLists.Add(View);
end;

procedure TFormMain.UnregisterDataViewForm(View: TDataViewForm);
begin
  DataViewForms.Remove(View);
end;

procedure TFormMain.UnregisterDataViewList(View: TDataViewList);
begin
  DataViewLists.Remove(View);
end;

procedure TFormMain.UpdateInterface;
begin
  ToolBar1.Visible := ShowToolBar;
  AShowToolBar.Checked := ShowToolBar;
  ADisconnect.Enabled := Core.Database.Connected;
end;

procedure TFormMain.LoadFromRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    ShowToolBar := ReadBoolWithDefault('ShowToolBar', False);
  finally
    Free;
  end;
end;

procedure TFormMain.SaveToRegistry(AContext: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    Context := AContext;
    WriteBool('ShowToolBar', ShowToolBar);
  finally
    Free;
  end;
end;

end.