source: trunk/Forms/UFormList.pas

unit UFormList;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  ActnList, Menus, StdCtrls, ExtCtrls, SpecializedList, USqlDatabase,
  UListViewSort, UDataView, URegistry;

type
  TColumnControlType = (ctText, ctReference, ctBoolean);

  TDbColumn = class
    Caption: string;
    Name: string;
    Visible: Boolean;
    Width: Integer;
    ControlType: TColumnControlType;
    ReferencedTable: string;
  end;

  { TListColumns }

  TListDbColumn = class(TListObject)
    function AddItem(Caption, Name: string; Visible: Boolean; Width: Integer): TDbColumn;
  end;

  { TDataViewList }

  TDataViewList = class(TDataView)
    Caption: string;
    Name: string;
    ImageIndex: Integer;
    Columns: TListDbColumn;
    constructor Create;
    destructor Destroy; override;
    procedure LoadFromRegistry(Context: TRegistryContext);
    procedure SaveToRegistry(Context: TRegistryContext);
  end;

  { TFormList }

  TFormList = class(TForm)
    AAdd: TAction;
    APrint: TAction;
    AExport: TAction;
    AReload: TAction;
    AModify: TAction;
    ADelete: TAction;
    ADuplicate: TAction;
    ActionList1: TActionList;
    LabelItemCount: TLabel;
    ListView1: TListView;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    Panel1: TPanel;
    PopupMenu1: TPopupMenu;
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    ToolButton5: TToolButton;
    ToolButton6: TToolButton;
    ToolButton7: TToolButton;
    procedure AAddExecute(Sender: TObject);
    procedure ADeleteExecute(Sender: TObject);
    procedure ADuplicateExecute(Sender: TObject);
    procedure AModifyExecute(Sender: TObject);
    procedure AReloadExecute(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure ListView1Data(Sender: TObject; Item: TListItem);
    procedure ListView1SelectItem(Sender: TObject; Item: TListItem;
      Selected: Boolean);
  private
    FView: TDataViewList;
    procedure SetView(AValue: TDataViewList);
  public
    DbRows: TDbRows;
    property View: TDataViewList read FView write SetView;
    procedure UpdateInterface;
    procedure UpdateData;
  end;

var
  FormList: TFormList;

implementation

{$R *.lfm}

uses
  UCore, UFormEdit, UFormMain;

resourcestring
  SItemDeletion = 'Item deletion';
  SDoYouWantToDeleteItem = 'Do you want to really delete item?';
  SItemCount = 'Item count: %s';
  SModifyItem = 'Modify item';
  SAddItem = 'Add item';

{ TDataViewList }

constructor TDataViewList.Create;
begin
  Columns := TListDbColumn.Create;
end;

destructor TDataViewList.Destroy;
begin
  Columns.Free;
  inherited Destroy;
end;

procedure TDataViewList.LoadFromRegistry(Context: TRegistryContext);
begin

end;

procedure TDataViewList.SaveToRegistry(Context: TRegistryContext);
begin

end;

{ TListColumns }

function TListDbColumn.AddItem(Caption, Name: string; Visible: Boolean;
  Width: Integer): TDbColumn;
begin
  Result := TDbColumn.Create;
  Result.Caption := Caption;
  Result.Name := Name;
  Result.Visible := Visible;
  Result.Width := Width;
  Add(Result);
end;

{ TFormList }

procedure TFormList.FormCreate(Sender: TObject);
begin
  DbRows := TDbRows.Create;
end;

procedure TFormList.AModifyExecute(Sender: TObject);
var
  Index: Integer;
begin
  try
    FormEdit := TFormEdit.Create(FormMain);
    Index := FormMain.DataViewLists.IndexOf(View);
    FormEdit.ItemId := Integer(ListView1.Selected.Data);
    FormEdit.View := TDataViewForm(FormMain.DataViewForms[Index]);
    FormEdit.LoadFromDatabase;
    FormEdit.Caption := SModifyItem;
    Core.CoolTranslator1.TranslateComponentRecursive(FormEdit);
    if FormEdit.ShowModal = mrOk then begin
      FormEdit.SaveToDatabase;
      UpdateData;
    end;
  finally
    FormEdit.Free;
  end;
end;

procedure TFormList.AReloadExecute(Sender: TObject);
begin
  UpdateData;
end;

procedure TFormList.AAddExecute(Sender: TObject);
var
  Index: Integer;
begin
  try
    FormEdit := TFormEdit.Create(FormMain);
    Index := FormMain.DataViewLists.IndexOf(View);
    FormEdit.ItemId := 0;
    FormEdit.View := TDataViewForm(FormMain.DataViewForms[Index]);
    FormEdit.ClearData;
    FormEdit.Caption := SAddItem;
    Core.CoolTranslator1.TranslateComponentRecursive(FormEdit);
    if FormEdit.ShowModal = mrOk then begin
      FormEdit.SaveToDatabase;
      UpdateData;
    end;
  finally
    FormEdit.Free;
  end;
end;

procedure TFormList.ADeleteExecute(Sender: TObject);
begin
  if MessageDlg(SItemDeletion, SDoYouWantToDeleteItem, mtConfirmation,
    [mbYes, mbNo], 0) = mrYes then begin
    Core.Database.Delete(View.Name, '`Id` = ' + IntToStr(Integer(ListView1.Selected.Data)));
    UpdateData;
  end;
end;

procedure TFormList.ADuplicateExecute(Sender: TObject);
begin
  if FormEdit.ShowModal = mrOk then begin
  end;
end;

procedure TFormList.FormDestroy(Sender: TObject);
begin
  ListView1.Items.Count := 0;
  FreeAndNil(DbRows);
end;

procedure TFormList.FormShow(Sender: TObject);
begin
  UpdateInterface;
end;

procedure TFormList.ListView1Data(Sender: TObject; Item: TListItem);
var
  I: Integer;
begin
  if (Item.Index >= 0) and (Item.Index < DbRows.Count) then begin
    for I := 0 to View.Columns.Count - 1 do begin
      Item.Data := Pointer(StrToInt(DbRows[Item.Index].Values['Id']));
      if I = 0 then Item.Caption := DbRows[Item.Index].Values[TDbColumn(View.Columns[I]).Name]
        else Item.SubItems.Add(DbRows[Item.Index].Values[TDbColumn(View.Columns[I]).Name]);
    end;
  end;
end;

procedure TFormList.ListView1SelectItem(Sender: TObject; Item: TListItem;
  Selected: Boolean);
begin
  UpdateInterface;
end;

procedure TFormList.SetView(AValue: TDataViewList);
begin
  if FView = AValue then Exit;
  if Assigned(AValue) then begin
  end else begin
    DbRows.Clear;
    ListView1.Items.Clear;
  end;
  FView := AValue;
end;

procedure TFormList.UpdateInterface;
begin
  AAdd.Enabled := True;
  AModify.Enabled := Assigned(ListView1.Selected);
  ADelete.Enabled := Assigned(ListView1.Selected);
  ADuplicate.Enabled := Assigned(ListView1.Selected);
end;

procedure TFormList.UpdateData;
var
  NewColumn: TListColumn;
  I: Integer;
  Filter: string;
begin
  ListView1.Columns.Clear;
  Filter := 'Id';
  for I := 0 to View.Columns.Count - 1 do
  with TDbColumn(View.Columns[I]) do begin
    NewColumn := ListView1.Columns.Add;
    NewColumn.Caption := Caption;
    NewColumn.Width := Width;
    NewColumn.Visible := Visible;
    Filter := Filter + ', `' + Name + '`';
  end;
  if Core.Database.Connected then
    Core.Database.Query(DbRows, 'SELECT ' + Filter + ' FROM ' + View.Name);

  ListView1.Items.Count := DbRows.Count;
  ListView1.Refresh;

  LabelItemCount.Caption := Format(SItemCount, [IntToStr(DbRows.Count)]);
end;

end.