source: branches/test1/Client/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, UCoolTranslator, UDebugLog, USystem, Registry,
  USqlDatabase, UFormLoginProfile, URegistry, UPDClient;

type

  { TCore }

  TCore = class(TDataModule)
    CoolTranslator1: TCoolTranslator;
    DebugLog1: TDebugLog;
    procedure CoolTranslator1Translate(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
    procedure SqlDatabase1LogQuery(Sender: TObject; Text: string);
  private
    procedure LoadFromRegistry;
    procedure SaveToRegistry;
    { private declarations }
  public
    LastUserName: string;
    LastProfile: Integer;
    LastPassword: string;
    RememberPassword: Boolean;
    Profiles: TProfileList;
    RegistryKey: string;
    RegistryRootKey: HKEY;
    System: TChronisBase;
  end;

var
  Core: TCore;


implementation

uses
  UModuleSystem, UModuleUser, UApplicationInfo;

{$R *.lfm}

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  Profiles := TProfileList.Create;
  RegistryRootKey := HKEY_CURRENT_USER;
  RegistryKey := '\Software\' + ApplicationInfo.CompanyName + '\' +
    ApplicationInfo.Name;
  LoadFromRegistry;
  System := TChronisBase.Create;
  //TChronisClientMySQL(System.Client).Database := SqlDatabase1;
  System.Modules.RegisterModule(TModuleSystem);
  System.ModuleSystem := TModuleSystem(System.Modules.Last);
  System.Modules.RegisterModule(TModuleUser);

  {$IFDEF DEBUG}
  DebugLog1.WriteToFileEnable := True;
  {$ENDIF}
end;

procedure TCore.CoolTranslator1Translate(Sender: TObject);
begin
  UFormLoginProfile.UpdateTranslation;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  SaveToRegistry;
  FreeAndNil(System);
  FreeAndNil(Profiles);
end;

procedure TCore.SqlDatabase1LogQuery(Sender: TObject; Text: string);
begin
  DebugLog1.Add('', Text);
end;

procedure TCore.LoadFromRegistry;
begin
  with TRegistryEx.Create do
  try
    RootKey := RegistryRootKey;
    OpenKey(RegistryKey, True);
    LastProfile := ReadIntegerWithDefault('LastConnectProfile', -1);
    LastUserName := ReadStringWithDefault('LastUserName', 'admin');
    LastPassword := ReadStringWithDefault('LastPassword', '');
    RememberPassword := ReadBoolWithDefault('RememberPassword', False);
  finally
    Free;
  end;
end;

procedure TCore.SaveToRegistry;
begin
  with TRegistryEx.Create do
  try
    RootKey := RegistryRootKey;
    OpenKey(RegistryKey, True);
    WriteInteger('LastConnectProfile', LastProfile);
    WriteString('LastUserName', LastUserName);
    if RememberPassword then WriteString('LastPassword', LastPassword)
      else WriteString('LastPassword', '');
    WriteBool('RememberPassword', RememberPassword);
  finally
    Free;
  end;
end;


end.